[gentoo-commits] gentoo-x86 commit in sys-apps/memtest86: memtest86-4.3.3-r1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in sys-apps/memtest86: memtest86-4.3.3-r1.ebuild ChangeLog

[Anthony G. Basile (blueness)]

blueness    13/10/10 20:53:29

  Modified:             ChangeLog
  Added:                memtest86-4.3.3-r1.ebuild
  Log:
  Expand the build patch to include -nopie, bug #206726
  
  (Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key 0xF52D4BBA)

Revision  Changes    Path
1.43                 sys-apps/memtest86/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/ChangeLog?rev=1.43&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/ChangeLog?rev=1.43&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/ChangeLog?r1=1.42&r2=1.43

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/memtest86/ChangeLog,v
retrieving revision 1.42
retrieving revision 1.43
diff -u -r1.42 -r1.43
--- ChangeLog	10 Oct 2013 18:38:37 -0000	1.42
+++ ChangeLog	10 Oct 2013 20:53:29 -0000	1.43
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/memtest86
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/memtest86/ChangeLog,v 1.42 2013/10/10 18:38:37 chainsaw Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/memtest86/ChangeLog,v 1.43 2013/10/10 20:53:29 blueness Exp $
+
+*memtest86-4.3.3-r1 (10 Oct 2013)
+
+  10 Oct 2013; Anthony G. Basile <blueness@gentoo.org>
+  +files/memtest86-4.3.3-build-nopie.patch, +memtest86-4.3.3-r1.ebuild:
+  Expand the build patch to include -nopie, bug #206726
 
 *memtest86-4.3.3 (10 Oct 2013)
 



1.1                  sys-apps/memtest86/memtest86-4.3.3-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/memtest86-4.3.3-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/memtest86/memtest86-4.3.3-r1.ebuild?rev=1.1&content-type=text/plain

Index: memtest86-4.3.3-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/memtest86/memtest86-4.3.3-r1.ebuild,v 1.1 2013/10/10 20:53:29 blueness Exp $

EAPI=5

inherit mount-boot eutils toolchain-funcs

DESCRIPTION="A stand alone memory test for x86 computers"
HOMEPAGE="http://www.memtest86.com/"
SRC_URI="http://www.memtest86.com/downloads/${P}-src.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~x86"
IUSE="serial"
S="${WORKDIR}/src"

BOOTDIR=/boot/memtest86

src_prepare() {
	epatch "${FILESDIR}"/${P}-build-nopie.patch #66630 + #206726

	sed -i -e 's,0x10000,0x100000,' memtest.lds || die

	if use serial ; then
		sed -i \
			-e '/^#define SERIAL_CONSOLE_DEFAULT/s:0:1:' \
			config.h \
			|| die "sed failed"
	fi

	cat - > "${T}"/39_${PN} <<EOF
#!/bin/sh
exec tail -n +3 \$0

menuentry "${PN} ${PV}" {
	linux16 ${BOOTDIR}/memtest
}
EOF

	tc-export AS CC LD
}

src_test() { :; }

src_install() {
	insinto ${BOOTDIR}
	newins memtest.bin memtest
	dosym memtest ${BOOTDIR}/memtest.bin

	exeinto /etc/grub.d
	doexe "${T}"/39_${PN}

	dodoc README README.build-process README.background
}

pkg_postinst() {
	mount-boot_pkg_postinst
	elog
	elog "memtest has been installed in ${BOOTDIR}/"
	elog "You may wish to update your bootloader configs"
	elog "by adding these lines:"
	elog " - For grub2 just run grub-mkconfig, a configuration file is installed"
	elog "   as /etc/grub/39_${PN}"
	elog " - For grub legacy: (replace '?' with correct numbers for your boot partition)"
	elog "    > title=${PN}"
	elog "    > root (hd?,?)"
	elog "    > kernel ${BOOTDIR}/memtest"
	elog " - For lilo:"
	elog "    > image  = ${BOOTDIR}/memtest"
	elog "    > label  = ${PN}"
	elog
}