* [gentoo-commits] gentoo-x86 commit in net-p2p/transmission: transmission-2.81-r1.ebuild transmission-2.82-r1.ebuild ChangeLog
@ 2013-09-06 18:21 Pacho Ramos (pacho)
0 siblings, 0 replies; only message in thread
From: Pacho Ramos (pacho) @ 2013-09-06 18:21 UTC (permalink / raw
To: gentoo-commits
pacho 13/09/06 18:21:41
Modified: ChangeLog
Added: transmission-2.81-r1.ebuild
transmission-2.82-r1.ebuild
Log:
Install upstream systemd unit file
(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)
Revision Changes Path
1.240 net-p2p/transmission/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.240&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?rev=1.240&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/ChangeLog?r1=1.239&r2=1.240
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v
retrieving revision 1.239
retrieving revision 1.240
diff -u -r1.239 -r1.240
--- ChangeLog 6 Sep 2013 11:49:29 -0000 1.239
+++ ChangeLog 6 Sep 2013 18:21:41 -0000 1.240
@@ -1,6 +1,13 @@
# ChangeLog for net-p2p/transmission
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.239 2013/09/06 11:49:29 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/ChangeLog,v 1.240 2013/09/06 18:21:41 pacho Exp $
+
+*transmission-2.81-r1 (06 Sep 2013)
+*transmission-2.82-r1 (06 Sep 2013)
+
+ 06 Sep 2013; Pacho Ramos <pacho@gentoo.org> +transmission-2.81-r1.ebuild,
+ +transmission-2.82-r1.ebuild:
+ Install upstream systemd unit file
*transmission-2.82 (06 Sep 2013)
1.1 net-p2p/transmission/transmission-2.81-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/transmission-2.81-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/transmission-2.81-r1.ebuild?rev=1.1&content-type=text/plain
Index: transmission-2.81-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-2.81-r1.ebuild,v 1.1 2013/09/06 18:21:41 pacho Exp $
EAPI=5
inherit autotools eutils fdo-mime gnome2-utils qt4-r2 systemd user
DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com/"
SRC_URI="http://download.transmissionbt.com/${PN}/files/${P}.tar.xz"
LICENSE="GPL-2 MIT"
SLOT=0
IUSE="ayatana gtk lightweight systemd qt4 xfs"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux"
RDEPEND="
>=dev-libs/libevent-2.0.10:=
dev-libs/openssl:0=
net-libs/libnatpmp:=
>=net-libs/miniupnpc-1.6.20120509:=
>=net-misc/curl-7.16.3:=[ssl]
sys-libs/zlib:=
gtk? (
>=dev-libs/dbus-glib-0.100:=
>=dev-libs/glib-2.36:2=
>=x11-libs/gtk+-3.4:3=
ayatana? ( >=dev-libs/libappindicator-0.4.90:3= )
)
systemd? ( sys-apps/systemd )
qt4? (
dev-qt/qtcore:4=
dev-qt/qtgui:4=
dev-qt/qtdbus:4=
)"
DEPEND="${RDEPEND}
dev-libs/glib:2
dev-util/intltool
sys-devel/gettext
virtual/os-headers
virtual/pkgconfig
xfs? ( sys-fs/xfsprogs )"
REQUIRED_USE="ayatana? ( gtk )"
DOCS="AUTHORS NEWS qt/README.txt"
pkg_setup() {
enewgroup ${PN}
enewuser ${PN} -1 -1 -1 ${PN}
}
src_prepare() {
sed -i -e '/CFLAGS/s:-ggdb3::' configure.ac || die
use ayatana || { sed -i -e '/^LIBAPPINDICATOR_MINIMUM/s:=.*:=9999:' configure.ac || die; }
# Pass our configuration dir to systemd unit file
sed -i '/ExecStart/ s|$| -g /var/transmission/config|' daemon/transmission-daemon.service || die
# http://trac.transmissionbt.com/ticket/4324
sed -i -e 's|noinst\(_PROGRAMS = $(TESTS)\)|check\1|' lib${PN}/Makefile.am || die
# fix for broken translations path
epatch "${FILESDIR}"/${PN}-2.80-translations-path-fix.patch
eautoreconf
}
src_configure() {
export ac_cv_header_xfs_xfs_h=$(usex xfs)
econf \
--enable-external-natpmp \
$(use_enable lightweight) \
$(use_with systemd systemd-daemon) \
$(use_with gtk)
if use qt4; then
pushd qt >/dev/null
eqmake4 qtr.pro
popd >/dev/null
fi
}
src_compile() {
emake
if use qt4; then
pushd qt >/dev/null
emake
lrelease translations/*.ts
popd >/dev/null
fi
}
src_install() {
default
rm -f "${ED}"/usr/share/${PN}/web/LICENSE
newinitd "${FILESDIR}"/${PN}-daemon.initd.8 ${PN}-daemon
newconfd "${FILESDIR}"/${PN}-daemon.confd.3 ${PN}-daemon
systemd_dounit "${S}/daemon/transmission-daemon.service"
keepdir /var/{${PN}/{config,downloads},log/${PN}}
fowners -R ${PN}:${PN} /var/{${PN}/{,config,downloads},log/${PN}}
if use qt4; then
pushd qt >/dev/null
emake INSTALL_ROOT="${ED}"/usr install
domenu ${PN}-qt.desktop
local res
for res in 16 22 24 32 48 64 72 96 128 192 256; do
doicon -s ${res} icons/hicolor/${res}x${res}/${PN}-qt.png
done
doicon -s scalable icons/hicolor/scalable/${PN}-qt.svg
insinto /usr/share/qt4/translations
doins translations/*.qm
popd >/dev/null
fi
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
elog "If you use ${PN}-daemon, please, set 'rpc-username' and"
elog "'rpc-password' (in plain text, ${PN}-daemon will hash it on"
elog "start) in settings.json file located at /var/${PN}/config or"
elog "any other appropriate config directory."
elog
elog "Since µTP is enabled by default, ${PN} needs large kernel buffers for"
elog "the UDP socket. You can append following lines into /etc/sysctl.conf:"
elog " net.core.rmem_max = 4194304"
elog " net.core.wmem_max = 1048576"
elog "and run sysctl -p"
}
pkg_postrm() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
}
1.1 net-p2p/transmission/transmission-2.82-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/transmission-2.82-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-p2p/transmission/transmission-2.82-r1.ebuild?rev=1.1&content-type=text/plain
Index: transmission-2.82-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-p2p/transmission/transmission-2.82-r1.ebuild,v 1.1 2013/09/06 18:21:41 pacho Exp $
EAPI=5
inherit autotools eutils fdo-mime gnome2-utils systemd user
DESCRIPTION="A Fast, Easy and Free BitTorrent client"
HOMEPAGE="http://www.transmissionbt.com/"
SRC_URI="http://download.transmissionbt.com/${PN}/files/${P}.tar.xz"
LICENSE="GPL-2 MIT"
SLOT=0
IUSE="ayatana gtk lightweight systemd xfs"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux"
RDEPEND=">=dev-libs/libevent-2.0.10:=
dev-libs/openssl:0=
net-libs/libnatpmp:=
>=net-libs/miniupnpc-1.6.20120509:=
>=net-misc/curl-7.16.3:=[ssl]
sys-libs/zlib:=
gtk? (
>=dev-libs/dbus-glib-0.100:=
>=dev-libs/glib-2.32:2=
>=x11-libs/gtk+-3.4:3=
ayatana? ( >=dev-libs/libappindicator-0.4.90:3= )
)
systemd? ( sys-apps/systemd )"
DEPEND="${RDEPEND}
dev-libs/glib:2
dev-util/intltool
sys-devel/gettext
virtual/os-headers
virtual/pkgconfig
xfs? ( sys-fs/xfsprogs )"
REQUIRED_USE="ayatana? ( gtk )"
DOCS="AUTHORS NEWS"
pkg_setup() {
enewgroup ${PN}
enewuser ${PN} -1 -1 -1 ${PN}
}
src_prepare() {
sed -i -e '/CFLAGS/s:-ggdb3::' configure.ac || die
use ayatana || { sed -i -e '/^LIBAPPINDICATOR_MINIMUM/s:=.*:=9999:' configure.ac || die; }
# Pass our configuration dir to systemd unit file
sed -i '/ExecStart/ s|$| -g /var/transmission/config|' daemon/transmission-daemon.service || die
# http://trac.transmissionbt.com/ticket/4324
sed -i -e 's|noinst\(_PROGRAMS = $(TESTS)\)|check\1|' lib${PN}/Makefile.am || die
eautoreconf
}
src_configure() {
export ac_cv_header_xfs_xfs_h=$(usex xfs)
econf \
--enable-external-natpmp \
$(use_enable lightweight) \
$(use_with systemd systemd-daemon) \
$(use_with gtk)
}
src_install() {
default
rm -f "${ED}"/usr/share/${PN}/web/LICENSE
newinitd "${FILESDIR}"/${PN}-daemon.initd.8 ${PN}-daemon
newconfd "${FILESDIR}"/${PN}-daemon.confd.3 ${PN}-daemon
systemd_dounit "${S}/daemon/transmission-daemon.service"
keepdir /var/{${PN}/{config,downloads},log/${PN}}
fowners -R ${PN}:${PN} /var/{${PN}/{,config,downloads},log/${PN}}
}
pkg_preinst() {
gnome2_icon_savelist
}
pkg_postinst() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
elog "If you use ${PN}-daemon, please, set 'rpc-username' and"
elog "'rpc-password' (in plain text, ${PN}-daemon will hash it on"
elog "start) in settings.json file located at /var/${PN}/config or"
elog "any other appropriate config directory."
elog
elog "Since µTP is enabled by default, ${PN} needs large kernel buffers for"
elog "the UDP socket. You can append following lines into /etc/sysctl.conf:"
elog " net.core.rmem_max = 4194304"
elog " net.core.wmem_max = 1048576"
elog "and run sysctl -p"
}
pkg_postrm() {
fdo-mime_desktop_database_update
gnome2_icon_cache_update
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-09-06 18:21 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-09-06 18:21 [gentoo-commits] gentoo-x86 commit in net-p2p/transmission: transmission-2.81-r1.ebuild transmission-2.82-r1.ebuild ChangeLog Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox