[gentoo-commits] gentoo-x86 commit in dev-ruby/thor: ChangeLog thor-0.18.1.ebuild

["Hans de Graaff (graaff)" <graaff@gentoo.org>]

graaff      13/09/01 06:05:58

  Modified:             ChangeLog
  Added:                thor-0.18.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.1.12.2/cvs/Linux x86_64, signed Manifest commit with key 0x8883FA56A308A8D7!)

Revision  Changes    Path
1.17                 dev-ruby/thor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/thor/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	15 Jan 2013 07:11:04 -0000	1.16
+++ ChangeLog	1 Sep 2013 06:05:57 -0000	1.17
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/thor
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/thor/ChangeLog,v 1.16 2013/01/15 07:11:04 zerochaos Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/thor/ChangeLog,v 1.17 2013/09/01 06:05:57 graaff Exp $
+
+*thor-0.18.1 (01 Sep 2013)
+
+  01 Sep 2013; Hans de Graaff <graaff@gentoo.org> +thor-0.18.1.ebuild:
+  Version bump.
 
   15 Jan 2013; Rick Farina <zerochaos@gentoo.org> thor-0.14.6.ebuild,
   thor-0.15.2.ebuild:



1.1                  dev-ruby/thor/thor-0.18.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/thor-0.18.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/thor/thor-0.18.1.ebuild?rev=1.1&content-type=text/plain

Index: thor-0.18.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/thor/thor-0.18.1.ebuild,v 1.1 2013/09/01 06:05:57 graaff Exp $

EAPI=4
USE_RUBY="ruby18 ruby19 jruby"

RUBY_FAKEGEM_RECIPE_DOC="rdoc"
RUBY_FAKEGEM_RECIPE_TEST="rspec"
RUBY_FAKEGEM_DOCDIR="rdoc"
RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"
RUBY_FAKEGEM_BINWRAP="thor"

inherit ruby-fakegem

DESCRIPTION="A scripting framework that replaces rake and sake"
HOMEPAGE="http://whatisthor.com/"

SRC_URI="http://github.com/erikhuda/${PN}/archive/v${PV}.tar.gz -> ${PN}-git-${PV}.tgz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm"
IUSE="doc"

ruby_add_bdepend "
	test? (
		>=dev-ruby/fakeweb-1.3
		dev-ruby/childlabor
	)"

all_ruby_prepare() {
	# Remove rspec default options (as we might not have the last
	# rspec).
	rm .rspec || die

	# Remove Bundler
	#rm Gemfile || die
	sed -i -e '/[Bb]undler/d' Thorfile || die

	# Remove mandatory coverage collection using simplecov which is not
	# packaged.
	sed -i -e '/require .simplecov/,/SimpleCov.start/ s:^:#:' spec/helper.rb || die
}

each_ruby_prepare() {
	# Skip two failing specs on thor. Our jruby 1.6 is too old to file
	# bugs against and the next thor version will no longer work with
	# this version altogether.
	case ${RUBY} in
		*jruby)
			sed -i -e '/works with glob characters in the path/,/end/ s:^:#:' \
				spec/actions/directory_spec.rb || die
			;;
	esac
}