* [gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: lightdm-1.6.0.ebuild ChangeLog
@ 2013-08-22 21:48 Markos Chandras (hwoarang)
0 siblings, 0 replies; only message in thread
From: Markos Chandras (hwoarang) @ 2013-08-22 21:48 UTC (permalink / raw
To: gentoo-commits
hwoarang 13/08/22 21:48:55
Modified: ChangeLog
Added: lightdm-1.6.0.ebuild
Log:
Bring 1.6.0 to the tree as a temporary solution for the 1.7.X problems in bug #479660. This version should restore the consolekit problems for non-systemd users
(Portage version: 2.2.1/cvs/Linux x86_64, signed Manifest commit with key C2BA7F3C!)
Revision Changes Path
1.70 x11-misc/lightdm/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.70&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?rev=1.70&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/ChangeLog?r1=1.69&r2=1.70
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v
retrieving revision 1.69
retrieving revision 1.70
diff -u -r1.69 -r1.70
--- ChangeLog 18 Aug 2013 13:43:54 -0000 1.69
+++ ChangeLog 22 Aug 2013 21:48:55 -0000 1.70
@@ -1,6 +1,13 @@
# ChangeLog for x11-misc/lightdm
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.69 2013/08/18 13:43:54 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/ChangeLog,v 1.70 2013/08/22 21:48:55 hwoarang Exp $
+
+*lightdm-1.6.0 (22 Aug 2013)
+
+ 22 Aug 2013; Markos Chandras <hwoarang@gentoo.org> +lightdm-1.6.0.ebuild:
+ Bring 1.6.0 to the tree as a temporary solution for the 1.7.X problems in bug
+ #479660. This version should restore the consolekit problems for non-systemd
+ users
18 Aug 2013; Agostino Sarubbo <ago@gentoo.org> lightdm-1.4.0-r2.ebuild:
Stable for x86, wrt bug #480132
1.1 x11-misc/lightdm/lightdm-1.6.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-1.6.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/x11-misc/lightdm/lightdm-1.6.0.ebuild?rev=1.1&content-type=text/plain
Index: lightdm-1.6.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/x11-misc/lightdm/lightdm-1.6.0.ebuild,v 1.1 2013/08/22 21:48:55 hwoarang Exp $
EAPI=5
inherit autotools eutils pam readme.gentoo systemd
TRUNK_VERSION="1.6"
DESCRIPTION="A lightweight display manager"
HOMEPAGE="http://www.freedesktop.org/wiki/Software/LightDM"
SRC_URI="http://launchpad.net/${PN}/${TRUNK_VERSION}/${PV}/+download/${P}.tar.xz
mirror://gentoo/introspection-20110205.m4.tar.bz2"
LICENSE="GPL-3 LGPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~x86"
IUSE="+gtk +introspection kde qt4 razor"
REQUIRED_USE="|| ( gtk kde razor )"
COMMON_DEPEND=">=dev-libs/glib-2.32.3:2
dev-libs/libxml2
sys-apps/accountsservice
virtual/pam
x11-libs/libX11
>=x11-libs/libxklavier-5
introspection? ( >=dev-libs/gobject-introspection-1 )
qt4? (
dev-qt/qtcore:4
dev-qt/qtdbus:4
dev-qt/qtgui:4
)"
RDEPEND="${COMMON_DEPEND}
>=sys-auth/pambase-20101024-r2"
DEPEND="${COMMON_DEPEND}
dev-util/gtk-doc-am
dev-util/intltool
gnome-base/gnome-common
sys-devel/gettext
virtual/pkgconfig"
PDEPEND="gtk? ( x11-misc/lightdm-gtk-greeter )
kde? ( x11-misc/lightdm-kde )
razor? ( razorqt-base/razorqt-lightdm-greeter )"
DOCS=( NEWS )
src_prepare() {
sed -i -e 's:getgroups:lightdm_&:' tests/src/libsystem.c || die #412369
sed -i -e '/minimum-uid/s:500:1000:' data/users.conf || die
epatch "${FILESDIR}"/session-wrapper-lightdm.patch
epatch_user
# Remove bogus Makefile statement. This needs to go upstream
sed -i /"@YELP_HELP_RULES@"/d help/Makefile.am || die
if has_version dev-libs/gobject-introspection; then
eautoreconf
else
AT_M4DIR=${WORKDIR} eautoreconf
fi
}
src_configure() {
# Set default values if global vars unset
local _greeter _session _user
_greeter=${LIGHTDM_GREETER:=lightdm-gtk-greeter}
_session=${LIGHTDM_SESSION:=gnome}
_user=${LIGHTDM_USER:=root}
# Let user know how lightdm is configured
einfo "Gentoo configuration"
einfo "Default greeter: ${_greeter}"
einfo "Default session: ${_session}"
einfo "Greeter user: ${_user}"
econf \
--localstatedir=/var \
--disable-static \
$(use_enable introspection) \
$(use_enable qt4 liblightdm-qt) \
--with-user-session=${_session} \
--with-greeter-session=${_greeter} \
--with-greeter-user=${_user} \
--with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
}
src_install() {
default
insinto /etc/${PN}
doins data/{${PN},keys}.conf
doins "${FILESDIR}"/Xsession
fperms +x /etc/${PN}/Xsession
prune_libtool_files --all
rm -rf "${ED}"/etc/init
pamd_mimic system-local-login ${PN} auth account session #372229
dopamd "${FILESDIR}"/${PN}-autologin #390863, #423163
readme.gentoo_create_doc
systemd_dounit "${FILESDIR}/${PN}.service"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-08-22 21:49 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-08-22 21:48 [gentoo-commits] gentoo-x86 commit in x11-misc/lightdm: lightdm-1.6.0.ebuild ChangeLog Markos Chandras (hwoarang)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox