[gentoo-commits] gentoo-x86 commit in app-editors/scite: scite-3.3.4.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in app-editors/scite: scite-3.3.4.ebuild ChangeLog

[Agostino Sarubbo (ago)]

ago         13/07/22 13:11:25

  Modified:             ChangeLog
  Added:                scite-3.3.4.ebuild
  Log:
  Version bump to 3.3.4
  
  (Portage version: 2.1.12.2/cvs/Linux ppc64, signed Manifest commit with key 7194459F)

Revision  Changes    Path
1.163                app-editors/scite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/ChangeLog?rev=1.163&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/ChangeLog?rev=1.163&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/ChangeLog?r1=1.162&r2=1.163

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v
retrieving revision 1.162
retrieving revision 1.163
diff -u -r1.162 -r1.163
--- ChangeLog	2 Jul 2013 11:00:15 -0000	1.162
+++ ChangeLog	22 Jul 2013 13:11:25 -0000	1.163
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/scite
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v 1.162 2013/07/02 11:00:15 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/ChangeLog,v 1.163 2013/07/22 13:11:25 ago Exp $
+
+*scite-3.3.4 (22 Jul 2013)
+
+  22 Jul 2013; Agostino Sarubbo <ago@gentoo.org> +scite-3.3.4.ebuild:
+  Version bump to 3.3.4
 
   02 Jul 2013; Agostino Sarubbo <ago@gentoo.org> -scite-3.2.5.ebuild,
   -scite-3.3.1.ebuild:



1.1                  app-editors/scite/scite-3.3.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/scite-3.3.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-editors/scite/scite-3.3.4.ebuild?rev=1.1&content-type=text/plain

Index: scite-3.3.4.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/scite-3.3.4.ebuild,v 1.1 2013/07/22 13:11:25 ago Exp $

EAPI="4"

inherit toolchain-funcs eutils

MY_PV=${PV//./}
DESCRIPTION="A very powerful editor for programmers"
HOMEPAGE="http://www.scintilla.org/SciTE.html"
SRC_URI="mirror://sourceforge/scintilla/${PN}${MY_PV}.tgz"

LICENSE="HPND lua? ( MIT )"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~arm-linux ~x86-linux"
IUSE="lua"

RDEPEND="dev-libs/glib
	x11-libs/cairo
	x11-libs/gtk+:2
	x11-libs/gdk-pixbuf
	x11-libs/pango
	lua? ( >=dev-lang/lua-5 )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	>=sys-apps/sed-4"

S="${WORKDIR}/${PN}/gtk"

src_prepare() {
	cd "${WORKDIR}/scintilla/gtk"
	sed -i makefile \
		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
		-e "s#^CCOMP =\(.*\)#CCOMP = $(tc-getCC)#" \
		-e "s#-Os##" \
		|| die "error patching makefile"

	cd "${WORKDIR}/scite/gtk"
	sed -i makefile \
		-e "s#-rdynamic#-rdynamic ${LDFLAGS}#" \
		|| die "error patching makefile"

	cd "${S}"
	sed -i makefile \
		-e 's#usr/local#usr#g' \
		-e 's#/gnome/apps/Applications#/applications#' \
		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
		-e "s#^CCOMP =\(.*\)#CCOMP = $(tc-getCC)#" \
		-e 's#${D}##' \
		-e 's#-g root#-g 0#' \
		-e "s#-Os##" \
		|| die "error patching makefile"
	cd "${WORKDIR}"
	epatch "${FILESDIR}/${PN}-3.0.1-no-lua.patch"
}

src_compile() {
	emake -C ../../scintilla/gtk AR="$(tc-getAR)"
	if use lua; then
		emake
	else
		emake NO_LUA=1
	fi
}

src_install() {
	dodir /usr/bin
	dodir /usr/share/{pixmaps,applications}

	emake prefix="${ED}/usr" install

	# we have to keep this because otherwise it'll break upgrading
	mv "${ED}/usr/bin/SciTE" "${ED}/usr/bin/scite" || die
	dosym /usr/bin/scite /usr/bin/SciTE

	# replace .desktop file with our own working version
	rm -f "${ED}/usr/share/applications/SciTE.desktop"
	domenu "${FILESDIR}/scite.desktop"

	doman ../doc/scite.1
	dodoc ../README
}