[gentoo-commits] gentoo-x86 commit in dev-qt/qdbusviewer: metadata.xml qdbusviewer-4.8.5.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-qt/qdbusviewer: metadata.xml qdbusviewer-4.8.5.ebuild ChangeLog

[Davide Pesavento (pesa)]

pesa        13/07/09 11:04:29

  Added:                metadata.xml qdbusviewer-4.8.5.ebuild ChangeLog
  Log:
  New ebuild for qdbusviewer application, split off from dev-qt/qtgui.
  
  (Portage version: 2.2.0_alpha186/cvs/Linux x86_64, signed Manifest commit with key 17A85C72)

Revision  Changes    Path
1.1                  dev-qt/qdbusviewer/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qdbusviewer/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qdbusviewer/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
	<herd>qt</herd>
	<use>
		<flag name="c++0x">Build Qt using the C++11 standard</flag>
		<flag name="exceptions">Add support for exceptions - like catching them
			inside the event loop (recommended by Nokia)</flag>
	</use>
	<upstream>
		<bugs-to>https://bugreports.qt-project.org/</bugs-to>
		<doc>http://qt-project.org/doc/</doc>
	</upstream>
</pkgmetadata>



1.1                  dev-qt/qdbusviewer/qdbusviewer-4.8.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qdbusviewer/qdbusviewer-4.8.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qdbusviewer/qdbusviewer-4.8.5.ebuild?rev=1.1&content-type=text/plain

Index: qdbusviewer-4.8.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qdbusviewer/qdbusviewer-4.8.5.ebuild,v 1.1 2013/07/09 11:04:29 pesa Exp $

EAPI=5

inherit eutils qt4-build

DESCRIPTION="Graphical tool that lets you introspect D-Bus objects and messages"
SLOT="4"
if [[ ${QT4_BUILD_TYPE} == live ]]; then
	KEYWORDS=""
else
	KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
fi

IUSE=""

DEPEND="
	~dev-qt/qtcore-${PV}[aqua=,debug=]
	~dev-qt/qtdbus-${PV}[aqua=,debug=]
	~dev-qt/qtgui-${PV}[aqua=,debug=]
"
RDEPEND="${DEPEND}"

pkg_setup() {
	QT4_TARGET_DIRECTORIES="tools/qdbus/qdbusviewer"
	QT4_EXTRACT_DIRECTORIES="
		include
		src
		tools/qdbus"

	qt4-build_pkg_setup
}

src_configure() {
	myconf+="
		-system-libpng -system-libjpeg -system-zlib
		-no-sql-mysql -no-sql-psql -no-sql-ibase -no-sql-sqlite -no-sql-sqlite2 -no-sql-odbc
		-sm -xshape -xsync -xcursor -xfixes -xrandr -xrender -mitshm -xinput -xkb
		-fontconfig -no-svg -no-webkit -no-phonon -no-opengl"

	qt4-build_src_configure
}

src_install() {
	qt4-build_src_install

	newicon tools/qdbus/qdbusviewer/images/qdbusviewer-128.png qdbusviewer.png
	make_desktop_entry qdbusviewer QDBusViewer qdbusviewer 'Qt;Development'
}



1.1                  dev-qt/qdbusviewer/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qdbusviewer/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-qt/qdbusviewer/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for dev-qt/qdbusviewer
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/dev-qt/qdbusviewer/ChangeLog,v 1.1 2013/07/09 11:04:29 pesa Exp $

*qdbusviewer-4.8.5 (09 Jul 2013)

  09 Jul 2013; Davide Pesavento <pesa@gentoo.org> +metadata.xml,
  +qdbusviewer-4.8.5.ebuild:
  New ebuild for qdbusviewer application, split off from dev-qt/qtgui.