[gentoo-commits] gentoo-x86 commit in media-libs/ladspa-sdk: ChangeLog ladspa-sdk-1.13-r2.ebuild

["Alexis Ballier (aballier)" <aballier@gentoo.org>]

aballier    13/06/27 14:57:20

  Modified:             ChangeLog
  Added:                ladspa-sdk-1.13-r2.ebuild
  Log:
  go multilib
  
  (Portage version: 2.2.0_alpha185/cvs/Linux x86_64, signed Manifest commit with key 160F534A)

Revision  Changes    Path
1.56                 media-libs/ladspa-sdk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-sdk/ChangeLog?rev=1.56&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-sdk/ChangeLog?rev=1.56&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-sdk/ChangeLog?r1=1.55&r2=1.56

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/ladspa-sdk/ChangeLog,v
retrieving revision 1.55
retrieving revision 1.56
diff -u -r1.55 -r1.56
--- ChangeLog	27 Jun 2013 14:36:15 -0000	1.55
+++ ChangeLog	27 Jun 2013 14:57:20 -0000	1.56
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/ladspa-sdk
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/ladspa-sdk/ChangeLog,v 1.55 2013/06/27 14:36:15 aballier Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/ladspa-sdk/ChangeLog,v 1.56 2013/06/27 14:57:20 aballier Exp $
+
+*ladspa-sdk-1.13-r2 (27 Jun 2013)
+
+  27 Jun 2013; Alexis Ballier <aballier@gentoo.org> +ladspa-sdk-1.13-r2.ebuild:
+  go multilib
 
   27 Jun 2013; Alexis Ballier <aballier@gentoo.org> -ladspa-sdk-1.12-r2.ebuild,
   -ladspa-sdk-1.13.ebuild, -files/ladspa-sdk-1.12-fbsd.patch,



1.1                  media-libs/ladspa-sdk/ladspa-sdk-1.13-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-sdk/ladspa-sdk-1.13-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/ladspa-sdk/ladspa-sdk-1.13-r2.ebuild?rev=1.1&content-type=text/plain

Index: ladspa-sdk-1.13-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/ladspa-sdk/ladspa-sdk-1.13-r2.ebuild,v 1.1 2013/06/27 14:57:20 aballier Exp $

EAPI=5

inherit eutils multilib toolchain-funcs portability flag-o-matic multilib-minimal

MY_PN=${PN/-/_}
MY_P=${MY_PN}_${PV}

DESCRIPTION="The Linux Audio Developer's Simple Plugin API"
HOMEPAGE="http://www.ladspa.org/"
SRC_URI="http://www.ladspa.org/download/${MY_P}.tgz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE=""

RDEPEND="abi_x86_32? ( !<=app-emulation/emul-linux-x86-soundlibs-20130224-r2
	!app-emulation/emul-linux-x86-soundlibs[-abi_x86_32(-)] )"
DEPEND=">=sys-apps/sed-4"

S="${WORKDIR}/${MY_PN}"

src_prepare() {
	cd "${WORKDIR}/${MY_PN}/src"
	epatch "${FILESDIR}"/${P}-properbuild.patch \
		"${FILESDIR}"/${P}-asneeded.patch \
		"${FILESDIR}"/${P}-fbsd.patch \
		"${FILESDIR}"/${P}-no-LD.patch

	sed -i -e 's:-sndfile-play*:@echo Disabled \0:' \
		makefile || die "sed makefile failed (sound playing tests)"

	cd "${S}"
	multilib_copy_sources
}

multilib_src_compile() {
	cd src
	emake CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}" \
		DYNAMIC_LD_LIBS="$(dlopen_lib)" \
		CC="$(tc-getCC)" CXX="$(tc-getCXX)" \
		targets
}

multilib_src_test() {
	cd src
	emake test
}

multilib_src_install() {
	cd src
	emake INSTALL_PLUGINS_DIR="/usr/$(get_libdir)/ladspa" \
		DESTDIR="${D}" \
		MKDIR_P="mkdir -p" \
		install
}

multilib_src_install_all() {
	dohtml doc/*.html

	# Needed for apps like rezound
	# emul-linux-soundlibs doesnt seem to install this, so keep it only for the
	# default abi.
	dodir /etc/env.d
	echo "LADSPA_PATH=/usr/$(get_libdir)/ladspa" > "${D}/etc/env.d/60ladspa"
}