[gentoo-commits] gentoo-x86 commit in net-irc/hexchat: metadata.xml ChangeLog hexchat-2.9.5_p20130525.ebuild

["Julian Ospald (hasufell)" <hasufell@gentoo.org>]

hasufell    13/06/13 11:46:57

  Modified:             metadata.xml ChangeLog
  Added:                hexchat-2.9.5_p20130525.ebuild
  Log:
  patchlevel bump as requested by Zero_Chaos
  
  (Portage version: 2.2.0_alpha179/cvs/Linux x86_64, signed Manifest commit with key E73C35B3)

Revision  Changes    Path
1.5                  net-irc/hexchat/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/hexchat/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	31 Mar 2013 14:29:27 -0000	1.4
+++ metadata.xml	13 Jun 2013 11:46:57 -0000	1.5
@@ -15,6 +15,7 @@
 		<flag name='fastscroll'>Make scrolling of large text buffers faster by
 		circumventing some of pango's overhead</flag>
 		<flag name='ntlm'>Enable NTLM authentication</flag>
+		<flag name='libcanberra'>Enable sound event support using <pkg>media-libs/libcanberra</pkg></flag>
 		<flag name='libproxy'>Enable proxy support.</flag>
 		<flag name='plugins'>Enable plugin support and installs some built-in plugins</flag>
 		<flag name='plugin-checksum'>Build Checksum plugin (needs plugins)</flag>



1.53                 net-irc/hexchat/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?rev=1.53&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?rev=1.53&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/ChangeLog?r1=1.52&r2=1.53

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v
retrieving revision 1.52
retrieving revision 1.53
diff -u -r1.52 -r1.53
--- ChangeLog	7 Jun 2013 14:18:24 -0000	1.52
+++ ChangeLog	13 Jun 2013 11:46:57 -0000	1.53
@@ -1,6 +1,12 @@
 # ChangeLog for net-irc/hexchat
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v 1.52 2013/06/07 14:18:24 hasufell Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/ChangeLog,v 1.53 2013/06/13 11:46:57 hasufell Exp $
+
+*hexchat-2.9.5_p20130525 (13 Jun 2013)
+
+  13 Jun 2013; Julian Ospald <hasufell@gentoo.org>
+  +hexchat-2.9.5_p20130525.ebuild:
+  patchlevel bump as requested by Zero_Chaos
 
 *hexchat-2.9.5-r1 (07 Jun 2013)
 



1.1                  net-irc/hexchat/hexchat-2.9.5_p20130525.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-2.9.5_p20130525.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-irc/hexchat/hexchat-2.9.5_p20130525.ebuild?rev=1.1&content-type=text/plain

Index: hexchat-2.9.5_p20130525.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-irc/hexchat/hexchat-2.9.5_p20130525.ebuild,v 1.1 2013/06/13 11:46:57 hasufell Exp $

EAPI=5

PYTHON_COMPAT=( python2_6 python2_7 )
inherit autotools eutils gnome2-utils mono-env multilib python-single-r1

DESCRIPTION="Graphical IRC client based on XChat"
SRC_URI="https://dev.gentoo.org/~hasufell/distfiles/${P}.tar.xz"
HOMEPAGE="http://www.hexchat.org/"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
IUSE="dbus fastscroll +gtk ipv6 libcanberra libnotify libproxy nls ntlm perl +plugins plugin-checksum plugin-doat plugin-fishlim plugin-sysinfo python spell ssl theme-manager"
REQUIRED_USE="plugin-checksum? ( plugins )
	plugin-doat? ( plugins )
	plugin-fishlim? ( plugins )
	plugin-sysinfo? ( plugins )
	python? ( ${PYTHON_REQUIRED_USE} )"

RDEPEND="dev-libs/glib:2
	dbus? ( >=dev-libs/dbus-glib-0.98 )
	fastscroll? ( x11-libs/libXft )
	gtk? ( x11-libs/gtk+:2 )
	libcanberra? ( media-libs/libcanberra )
	libproxy? ( net-libs/libproxy )
	libnotify? ( x11-libs/libnotify )
	nls? ( virtual/libintl )
	ntlm? ( net-libs/libntlm )
	perl? ( >=dev-lang/perl-5.8.0 )
	plugin-sysinfo? ( sys-apps/pciutils )
	python? ( ${PYTHON_DEPS} )
	spell? (
		app-text/enchant
		dev-libs/libxml2
	)
	ssl? ( >=dev-libs/openssl-0.9.8u )
	theme-manager? ( dev-lang/mono )"
DEPEND="${RDEPEND}
	virtual/pkgconfig
	nls? ( sys-devel/gettext )
	theme-manager? ( dev-util/monodevelop )"

DOCS=""

pkg_setup() {
	use python && python-single-r1_pkg_setup
	use theme-manager && mono-env_pkg_setup
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-2.9.1-input-box.patch \
		"${FILESDIR}"/${PN}-2.9.5-cflags.patch \
		"${FILESDIR}"/${PN}-2.9.5-gettextize.patch

	cp $(type -p gettextize) "${T}"/ || die
	sed -i -e 's:read dummy < /dev/tty::' "${T}/gettextize" || die
	einfo "Running gettextize -f --no-changelog..."
	"${T}"/gettextize -f --no-changelog > /dev/null || die "gettexize failed"
	eautoreconf
}

src_configure() {
	econf \
		$(use_enable nls) \
		$(use_enable libproxy socks) \
		$(use_enable ipv6) \
		$(use_enable fastscroll xft) \
		$(use_enable ssl openssl) \
		$(use_enable gtk gtkfe) \
		$(use_enable !gtk textfe) \
		$(usex python "--enable-python=${EPYTHON}" "--disable-python") \
		$(use_enable perl) \
		$(use_enable plugins plugin) \
		$(use_enable plugin-checksum checksum) \
		$(use_enable plugin-doat doat) \
		$(use_enable plugin-fishlim fishlim) \
		$(use_enable plugin-sysinfo sysinfo) \
		$(use_enable dbus) \
		$(use_enable libnotify) \
		$(use_enable libcanberra) \
		--enable-shm \
		$(use_enable spell spell static) \
		$(use_enable ntlm) \
		$(use_enable libproxy)
}

src_compile() {
	default
	if use theme-manager ; then
		export XDG_CACHE_HOME="${T}/.cache"
		cd src/htm || die
		mdtool --verbose build htm-mono.csproj || die
	fi
}

src_install() {
	emake DESTDIR="${D}" UPDATE_ICON_CACHE=true install
	dodoc share/doc/{readme,hacking}.md
	use plugin-fishlim && dodoc share/doc/fishlim.md
	if use theme-manager ; then
		dobin src/htm/thememan.exe
		make_wrapper thememan "mono /usr/bin/thememan.exe"
	fi
	prune_libtool_files --all
}

pkg_preinst() {
	if use gtk ; then
		gnome2_icon_savelist
	fi
}

pkg_postinst() {
	if use !gtk ; then
		einfo
		elog "You have disabled the gtk USE flag. This means you don't have"
		elog "the GTK-GUI for HexChat but only a text interface called \"hexchat-text\"."
	else
		gnome2_icon_cache_update
	fi

	if use theme-manager ; then
		einfo
		elog "Themes are available at:"
		elog "  http://hexchat.org/themes.html"
	fi

	ewarn
	ewarn "If you're upgrading from hexchat <=2.9.3 remember to rename"
	ewarn "the xchat.conf file found in ~/.config/hexchat/ to hexchat.conf"
	ewarn
	ewarn "If you're upgrading from hexchat <=2.9.5 you will have to adjust"
	ewarn "your auto-join channel settings."
}

pkg_postrm() {
	if use gtk ; then
		gnome2_icon_cache_update
	fi
}