[gentoo-commits] gentoo-x86 commit in media-video/transcode: transcode-1.1.7-r2.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-video/transcode: transcode-1.1.7-r2.ebuild ChangeLog

[Ian Whyman (thev00d00)]

thev00d00    13/05/27 09:09:58

  Modified:             ChangeLog
  Added:                transcode-1.1.7-r2.ebuild
  Log:
  Add patch to make it build with newer libav/ffmpeg, thanks to Ji?� Moravec for the patch #443214
  
  (Portage version: 2.2.0_alpha177/cvs/Linux x86_64, unsigned Manifest commit)

Revision  Changes    Path
1.313                media-video/transcode/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/ChangeLog?rev=1.313&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/ChangeLog?rev=1.313&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/ChangeLog?r1=1.312&r2=1.313

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/transcode/ChangeLog,v
retrieving revision 1.312
retrieving revision 1.313
diff -u -r1.312 -r1.313
--- ChangeLog	10 Mar 2013 10:12:19 -0000	1.312
+++ ChangeLog	27 May 2013 09:09:58 -0000	1.313
@@ -1,6 +1,13 @@
 # ChangeLog for media-video/transcode
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/ChangeLog,v 1.312 2013/03/10 10:12:19 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/ChangeLog,v 1.313 2013/05/27 09:09:58 thev00d00 Exp $
+
+*transcode-1.1.7-r2 (27 May 2013)
+
+  27 May 2013; Ian Whyman <thev00d00@gentoo.org>
+  +files/transcode-1.1.7-libav-9.patch, +transcode-1.1.7-r2.ebuild:
+  Add patch to make it build with newer libav/ffmpeg, thanks to Ji?� Moravec for
+  the patch #443214
 
   10 Mar 2013; Alexis Ballier <aballier@gentoo.org> -transcode-1.1.7.ebuild:
   remove old



1.1                  media-video/transcode/transcode-1.1.7-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/transcode-1.1.7-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/transcode/transcode-1.1.7-r2.ebuild?rev=1.1&content-type=text/plain

Index: transcode-1.1.7-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/transcode/transcode-1.1.7-r2.ebuild,v 1.1 2013/05/27 09:09:58 thev00d00 Exp $

EAPI=5
inherit eutils libtool multilib

DESCRIPTION="A suite of utilities for transcoding video and audio codecs in different containers"
HOMEPAGE="http://tcforge.berlios.de/"
SRC_URI="mirror://bitbucket/france/${PN}-tcforge/downloads/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="3dnow a52 aac alsa altivec dv dvd +iconv imagemagick jpeg lzo mjpeg mmx mp3 mpeg nuv ogg oss pic postproc quicktime sdl sse sse2 theora truetype v4l vorbis X x264 xml xvid"

RDEPEND="
	>=virtual/ffmpeg-0.10
	a52? ( media-libs/a52dec )
	aac? ( media-libs/faac )
	alsa? ( media-libs/alsa-lib )
	dv? ( media-libs/libdv )
	dvd? ( media-libs/libdvdread )
	iconv? ( virtual/libiconv )
	imagemagick? ( media-gfx/imagemagick )
	jpeg? ( virtual/jpeg )
	lzo? ( >=dev-libs/lzo-2 )
	mjpeg? ( media-video/mjpegtools )
	mp3? ( media-sound/lame )
	mpeg? ( media-libs/libmpeg2 )
	ogg? ( media-libs/libogg )
	postproc? ( >=virtual/ffmpeg-0.10 )
	quicktime? ( >=media-libs/libquicktime-1 )
	sdl? ( >=media-libs/libsdl-1.2.5[X?] )
	theora? ( media-libs/libtheora )
	truetype? ( >=media-libs/freetype-2 )
	v4l? ( media-libs/libv4l )
	vorbis? ( media-libs/libvorbis )
	X? ( x11-libs/libXpm x11-libs/libXaw x11-libs/libXv )
	x264? ( media-libs/x264 )
	xml? ( dev-libs/libxml2 )
	xvid? ( media-libs/xvid )
	"

DEPEND="
	${RDEPEND}
	virtual/pkgconfig
	v4l? ( >=sys-kernel/linux-headers-2.6.11 )
	"

REQUIRED_USE="
	sse? ( mmx )
	sse2? ( mmx sse )
	3dnow? ( mmx )
	nuv? ( lzo )
	"

src_prepare() {
	epatch \
		"${FILESDIR}"/${P}-ffmpeg.patch \
		"${FILESDIR}"/${P}-ffmpeg-0.10.patch \
		"${FILESDIR}"/${P}-ffmpeg-0.11.patch \
		"${FILESDIR}"/${P}-preset-free.patch \
		"${FILESDIR}"/${P}-libav-9.patch

	elibtoolize
}

src_configure() {
	local myconf
	use x86 && myconf="$(use_enable !pic x86-textrels)" #271476

	econf \
		$(use_enable mmx) \
		$(use_enable 3dnow) \
		$(use_enable sse) \
		$(use_enable sse2) \
		$(use_enable altivec) \
		$(use_enable v4l libv4l2) \
		$(use_enable v4l libv4lconvert) \
		$(use_enable mpeg libmpeg2) \
		$(use_enable mpeg libmpeg2convert) \
		--enable-experimental \
		--enable-deprecated \
		$(use_enable v4l) \
		$(use_enable oss) \
		$(use_enable alsa) \
		$(use_enable postproc libpostproc) \
		$(use_enable truetype freetype2) \
		$(use_enable mp3 lame) \
		$(use_enable xvid) \
		$(use_enable x264) \
		$(use_enable ogg) \
		$(use_enable vorbis) \
		$(use_enable theora) \
		$(use_enable dvd libdvdread) \
		$(use_enable dv libdv) \
		$(use_enable quicktime libquicktime) \
		$(use_enable lzo) \
		$(use_enable a52) \
		$(use_enable aac faac) \
		$(use_enable xml libxml2) \
		$(use_enable mjpeg mjpegtools) \
		$(use_enable sdl) \
		$(use_enable imagemagick) \
		$(use_enable jpeg libjpeg) \
		$(use_enable iconv) \
		$(use_enable nuv) \
		$(use_with X x) \
		--with-mod-path=/usr/$(get_libdir)/transcode \
		${myconf}
}

src_install() {
	emake DESTDIR="${D}" docsdir=/usr/share/doc/${PF} install
	dodoc AUTHORS ChangeLog README STYLE TODO
	find "${ED}"usr -name '*.la' -exec rm -f {} +
}