[gentoo-commits] gentoo-x86 commit in www-apps/tt-rss: tt-rss-1.7.9.ebuild tt-rss-1.7.6.ebuild

["Tomas Chvatal (scarabeus)" <scarabeus@gentoo.org>]

scarabeus    13/05/14 18:32:25

  Added:                tt-rss-1.7.9.ebuild
  Removed:              tt-rss-1.7.6.ebuild
  Log:
  Version bump to 1.7.9 wrt bug#469702. Also include translations patches. Altho upstream broke it even somewhere else so first page will be always in english.
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 8EEE3BE8)

Revision  Changes    Path
1.1                  www-apps/tt-rss/tt-rss-1.7.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/tt-rss/tt-rss-1.7.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-apps/tt-rss/tt-rss-1.7.9.ebuild?rev=1.1&content-type=text/plain

Index: tt-rss-1.7.9.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-apps/tt-rss/tt-rss-1.7.9.ebuild,v 1.1 2013/05/14 18:32:25 scarabeus Exp $

EAPI=5

inherit user eutils webapp depend.php depend.apache vcs-snapshot

DESCRIPTION="Tiny Tiny RSS - A web-based news feed (RSS/Atom) aggregator using AJAX"
HOMEPAGE="http://tt-rss.org/"
SRC_URI="https://github.com/gothfox/Tiny-Tiny-RSS/archive/${PV}.tar.gz -> ${P}.tar.gz
	http://dev.gentooexperimental.org/~scarabeus/ttrss-${PV}-patches.tar.xz
"

LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE="daemon +mysql postgres"

DEPEND="
	daemon? ( dev-lang/php[mysql?,postgres?,pcntl,curl] )
	!daemon? ( dev-lang/php[mysql?,postgres?,curl] )
"
RDEPEND="${DEPEND}"

REQUIRED_USE="|| ( mysql postgres )"

need_httpd_cgi
need_php_httpd

pkg_setup() {
	webapp_pkg_setup

	if use daemon; then
			enewgroup ttrssd
			enewuser ttrssd -1 /bin/sh /dev/null ttrssd
	fi
}

src_prepare() {
	# Customize config.php so that the right 'DB_TYPE' is already set (according to the USE flag)
	einfo "Customizing config.php..."
	mv config.php{-dist,} || die "Could not rename config.php-dist to config.php."

	if use mysql && ! use postgres; then
			sed -i \
				-e "/define('DB_TYPE',/{s:pgsql:mysql:}" \
				config.php || die
	fi

	sed -i \
		-e "/define('DB_TYPE',/{s:// \(or mysql\):// pgsql \1:}" \
		config.php || die

	# broken release fixed in git
	EPATCH_FORCE="yes" \
	EPATCH_SOURCE="${WORKDIR}/ttrss-1.7.9-patches" \
	EPATCH_SUFFIX="patch" \
	epatch

	# per 462578
	epatch_user
}

src_install() {
	webapp_src_preinst

	insinto "/${MY_HTDOCSDIR}"
	doins -r .
	keepdir "/${MY_HTDOCSDIR}"/feed-icons

	for DIR in cache lock feed-icons; do
			webapp_serverowned -R "${MY_HTDOCSDIR}/${DIR}"
	done

	webapp_configfile "${MY_HTDOCSDIR}"/config.php
	if use daemon; then
			webapp_postinst_txt en "${FILESDIR}"/postinstall-en-with-daemon.txt
			newinitd "${FILESDIR}"/ttrssd.initd-r1 ttrssd
			newconfd "${FILESDIR}"/ttrssd.confd-r1 ttrssd
			insinto /etc/logrotate.d/
			newins "${FILESDIR}"/ttrssd.logrotated ttrssd
	else
			webapp_postinst_txt en "${FILESDIR}"/postinstall-en.txt
	fi

	webapp_src_install
}