[gentoo-commits] gentoo-x86 commit in media-gfx/eog-plugins: eog-plugins-3.8.1.ebuild ChangeLog eog-plugins-3.4.1.ebuild

[gentoo-commits] gentoo-x86 commit in media-gfx/eog-plugins: eog-plugins-3.8.1.ebuild ChangeLog eog-plugins-3.4.1.ebuild

[Pacho Ramos (pacho)]

pacho       13/05/14 18:28:07

  Modified:             ChangeLog
  Added:                eog-plugins-3.8.1.ebuild
  Removed:              eog-plugins-3.4.1.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.1.11.63/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.5                  media-gfx/eog-plugins/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/eog-plugins/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/eog-plugins/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/eog-plugins/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/eog-plugins/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	28 Mar 2013 17:36:19 -0000	1.4
+++ ChangeLog	14 May 2013 18:28:07 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for media-gfx/eog-plugins
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog-plugins/ChangeLog,v 1.4 2013/03/28 17:36:19 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog-plugins/ChangeLog,v 1.5 2013/05/14 18:28:07 pacho Exp $
+
+*eog-plugins-3.8.1 (14 May 2013)
+
+  14 May 2013; Pacho Ramos <pacho@gentoo.org> +eog-plugins-3.8.1.ebuild,
+  -eog-plugins-3.4.1.ebuild:
+  Version bump, drop old
 
 *eog-plugins-3.8.0 (28 Mar 2013)
 



1.1                  media-gfx/eog-plugins/eog-plugins-3.8.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/eog-plugins/eog-plugins-3.8.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/eog-plugins/eog-plugins-3.8.1.ebuild?rev=1.1&content-type=text/plain

Index: eog-plugins-3.8.1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/eog-plugins/eog-plugins-3.8.1.ebuild,v 1.1 2013/05/14 18:28:07 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_COMPAT=( python2_{6,7} )

inherit gnome2 python-single-r1

DESCRIPTION="Eye of GNOME plugins"
HOMEPAGE="https://live.gnome.org/EyeOfGnome/Plugins"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+exif +flickr map +picasa +python"
REQUIRED_USE="map? ( exif )"

RDEPEND="
	>=dev-libs/glib-2.32:2
	>=dev-libs/libpeas-0.7.4:=
	>=media-gfx/eog-3.5.5
	>=x11-libs/gtk+-3.3.8:3
	exif? ( >=media-libs/libexif-0.6.16 )
	flickr? ( media-gfx/postr )
	map? (
		media-libs/libchamplain:0.12[gtk]
		>=media-libs/clutter-1.9.4:1.0
		>=media-libs/clutter-gtk-1.1.2:1.0 )
	picasa? ( >=dev-libs/libgdata-0.9.1:= )
	python? (
		${PYTHON_DEPS}
		dev-libs/libpeas:=[gtk,python,${PYTHON_USEDEP}]
		dev-python/pygobject:3[${PYTHON_USEDEP}]
		gnome-base/gsettings-desktop-schemas
		media-gfx/eog[introspection]
		x11-libs/gtk+:3[introspection]
		x11-libs/pango[introspection] )
"
DEPEND="${RDEPEND}
	>=dev-util/intltool-0.40
	sys-devel/gettext
	virtual/pkgconfig
"

pkg_setup() {
	use python && python-single-r1_pkg_setup
}

src_configure() {
	local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
	use exif && plugins="${plugins},exif-display"
	use flickr && plugins="${plugins},postr"
	use map && plugins="${plugins},map"
	use picasa && plugins="${plugins},postasa"
	use python && plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder"
	gnome2_src_configure \
		$(use_enable python) \
		--with-plugins=${plugins}
}