[gentoo-commits] gentoo-x86 commit in media-video/cheese: cheese-3.8.2.ebuild ChangeLog cheese-3.8.0.ebuild cheese-3.4.2.ebuild

[gentoo-commits] gentoo-x86 commit in media-video/cheese: cheese-3.8.2.ebuild ChangeLog cheese-3.8.0.ebuild cheese-3.4.2.ebuild

[Pacho Ramos (pacho)]

pacho       13/05/14 18:23:12

  Modified:             ChangeLog
  Added:                cheese-3.8.2.ebuild
  Removed:              cheese-3.8.0.ebuild cheese-3.4.2.ebuild
  Log:
  Version bump, drop old
  
  (Portage version: 2.1.11.63/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

Revision  Changes    Path
1.71                 media-video/cheese/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cheese/ChangeLog?rev=1.71&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cheese/ChangeLog?rev=1.71&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cheese/ChangeLog?r1=1.70&r2=1.71

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-video/cheese/ChangeLog,v
retrieving revision 1.70
retrieving revision 1.71
diff -u -r1.70 -r1.71
--- ChangeLog	16 Apr 2013 19:32:17 -0000	1.70
+++ ChangeLog	14 May 2013 18:23:12 -0000	1.71
@@ -1,6 +1,12 @@
 # ChangeLog for media-video/cheese
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-video/cheese/ChangeLog,v 1.70 2013/04/16 19:32:17 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-video/cheese/ChangeLog,v 1.71 2013/05/14 18:23:12 pacho Exp $
+
+*cheese-3.8.2 (14 May 2013)
+
+  14 May 2013; Pacho Ramos <pacho@gentoo.org> +cheese-3.8.2.ebuild,
+  -cheese-3.4.2.ebuild, -cheese-3.8.0.ebuild:
+  Version bump, drop old
 
 *cheese-3.8.1 (16 Apr 2013)
 



1.1                  media-video/cheese/cheese-3.8.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cheese/cheese-3.8.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-video/cheese/cheese-3.8.2.ebuild?rev=1.1&content-type=text/plain

Index: cheese-3.8.2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-video/cheese/cheese-3.8.2.ebuild,v 1.1 2013/05/14 18:23:12 pacho Exp $

EAPI="5"
GCONF_DEBUG="no"
VALA_MIN_API_VERSION="0.18"

inherit eutils gnome2 multilib vala virtualx

DESCRIPTION="A cheesy program to take pictures and videos from your webcam"
HOMEPAGE="http://projects.gnome.org/cheese/"

LICENSE="GPL-2+"
SLOT="0/7" # subslot = libcheese soname version
IUSE="+introspection sendto test"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"

COMMON_DEPEND="
	>=dev-libs/glib-2.28:2
	>=x11-libs/gtk+-3.4.4:3[introspection?]
	>=x11-libs/cairo-1.10:=
	>=x11-libs/pango-1.28.0
	>=gnome-base/gnome-desktop-2.91.6:3=
	>=gnome-base/librsvg-2.32.0:2
	>=media-libs/libcanberra-0.26[gtk3]
	>=media-libs/clutter-1.10:1.0[introspection?]
	>=media-libs/clutter-gtk-0.91.8:1.0
	>=media-libs/clutter-gst-1.9:2.0
	media-libs/cogl:1.0=[introspection?]

	media-video/gnome-video-effects
	x11-libs/gdk-pixbuf:2[jpeg,introspection?]
	x11-libs/libX11
	x11-libs/libXtst

	media-libs/gstreamer:1.0[introspection?]
	media-libs/gst-plugins-base:1.0[introspection?,ogg,pango,theora,vorbis,X]

	>=virtual/udev-171:=[gudev]
	introspection? ( >=dev-libs/gobject-introspection-0.6.7 )
"
RDEPEND="${COMMON_DEPEND}
	media-libs/gst-plugins-bad:1.0
	media-libs/gst-plugins-good:1.0

	media-plugins/gst-plugins-jpeg:1.0
	media-plugins/gst-plugins-v4l2:1.0
	media-plugins/gst-plugins-vpx:1.0

	sendto? ( >=gnome-extra/nautilus-sendto-2.91 )
"
DEPEND="${COMMON_DEPEND}
	app-text/docbook-xml-dtd:4.3
	dev-libs/libxml2:2
	>=dev-util/gtk-doc-1.14
	>=dev-util/intltool-0.50
	dev-util/itstool
	virtual/pkgconfig
	x11-proto/xf86vidmodeproto
	test? ( dev-libs/glib:2[utils] )
"

src_configure() {
	gnome2_src_configure \
		GST_INSPECT=$(type -P true) \
		$(use_enable introspection) \
		--disable-lcov \
		--disable-static \
		ITSTOOL=$(type -P true)
}

src_compile() {
	# Clutter-related sandbox violations when USE="doc introspection" and
	# FEATURES="-userpriv" (see bug #385917).
	unset DISPLAY
	gnome2_src_compile
}

src_test() {
	Xemake check
}