[gentoo-commits] gentoo-x86 commit in sci-chemistry/relax: ChangeLog relax-2.2.5.ebuild

["Justin Lecher (jlec)" <jlec@gentoo.org>]

jlec        13/05/13 08:42:19

  Modified:             ChangeLog
  Added:                relax-2.2.5.ebuild
  Log:
  sci-chemistry/relax: Version Bump
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

Revision  Changes    Path
1.3                  sci-chemistry/relax/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/relax/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/relax/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/relax/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-chemistry/relax/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	4 Feb 2013 07:57:56 -0000	1.2
+++ ChangeLog	13 May 2013 08:42:18 -0000	1.3
@@ -1,6 +1,11 @@
 # ChangeLog for sci-chemistry/relax
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/ChangeLog,v 1.2 2013/02/04 07:57:56 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/ChangeLog,v 1.3 2013/05/13 08:42:18 jlec Exp $
+
+*relax-2.2.5 (13 May 2013)
+
+  13 May 2013; Justin Lecher <jlec@gentoo.org> +relax-2.2.5.ebuild:
+  Version Bump
 
 *relax-2.2.1 (04 Feb 2013)
 



1.1                  sci-chemistry/relax/relax-2.2.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/relax/relax-2.2.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-chemistry/relax/relax-2.2.5.ebuild?rev=1.1&content-type=text/plain

Index: relax-2.2.5.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-chemistry/relax/relax-2.2.5.ebuild,v 1.1 2013/05/13 08:42:18 jlec Exp $

EAPI=5

PYTHON_COMPAT=( python{2_5,2_6,2_7} )

WX_GTK_VER="2.8"

inherit eutils python-single-r1 scons-utils toolchain-funcs wxwidgets

DESCRIPTION="Molecular dynamics by NMR data analysis"
HOMEPAGE="http://www.nmr-relax.com/"
SRC_URI="http://download.gna.org/relax/${P}.src.tar.bz2"

SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE=""

RDEPEND="
	dev-python/numpy[${PYTHON_USEDEP}]
	sci-chemistry/molmol
	sci-chemistry/pymol
	>=sci-libs/bmrblib-1.0.1_pre198[${PYTHON_USEDEP}]
	>=sci-libs/minfx-1.0.4_pre98[${PYTHON_USEDEP}]
	sci-libs/scipy[${PYTHON_USEDEP}]
	sci-visualization/grace
	sci-visualization/opendx
	x11-libs/wxGTK:2.8[X]"
DEPEND="${RDEPEND}"

pkg_setup() {
	wxwidgets_pkg_setup
	python-single-r1_pkg_setup
}

src_prepare() {
	rm -rf minfx bmrblib || die
	epatch "${FILESDIR}"/${PN}-2.2.1-gentoo.patch
	tc-export CC
}

src_compile() {
	escons
}

src_test() {
	${EPYTHON} ./${PN}.py -s || die
	${EPYTHON} ./${PN}.py -x || die
}

src_install() {
	dodoc README docs/{CHANGES,COMMITTERS,JOBS,relax.pdf,prompt_screenshot.txt}

	python_moduleinto ${PN}
	python_domodule *

	rm ${PN} README || die

	make_wrapper ${PN}-nmr "${EPYTHON} $(python_get_sitedir)/${PN}/${PN}.py $@"
}