public inbox for gentoo-commits@lists.gentoo.org
 help / color / mirror / Atom feed
* [gentoo-commits] gentoo-x86 commit in net-analyzer/wireshark: ChangeLog wireshark-1.10.0_rc1.ebuild
@ 2013-04-27 17:05 Jeroen Roovers (jer)
  0 siblings, 0 replies; 5+ messages in thread
From: Jeroen Roovers (jer) @ 2013-04-27 17:05 UTC (permalink / raw
  To: gentoo-commits

jer         13/04/27 17:05:37

  Modified:             ChangeLog
  Added:                wireshark-1.10.0_rc1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.475                net-analyzer/wireshark/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.475&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.475&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?r1=1.474&r2=1.475

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v
retrieving revision 1.474
retrieving revision 1.475
diff -u -r1.474 -r1.475
--- ChangeLog	24 Apr 2013 14:50:58 -0000	1.474
+++ ChangeLog	27 Apr 2013 17:05:37 -0000	1.475
@@ -1,6 +1,11 @@
 # ChangeLog for net-analyzer/wireshark
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.474 2013/04/24 14:50:58 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.475 2013/04/27 17:05:37 jer Exp $
+
+*wireshark-1.10.0_rc1 (27 Apr 2013)
+
+  27 Apr 2013; Jeroen Roovers <jer@gentoo.org> +wireshark-1.10.0_rc1.ebuild:
+  Version bump.
 
   24 Apr 2013; Jeroen Roovers <jer@gentoo.org> wireshark-1.6.14.ebuild,
   wireshark-1.6.14-r1.ebuild, wireshark-1.8.6.ebuild,



1.1                  net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.1&content-type=text/plain

Index: wireshark-1.10.0_rc1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.1 2013/04/27 17:05:37 jer Exp $

EAPI=5
PYTHON_COMPAT=( python2_5 python2_6 python2_7 )
inherit autotools eutils fcaps flag-o-matic python-single-r1 user

[[ -n ${PV#*_rc} && ${PV#*_rc} != ${PV} ]] && MY_P=${PN}-${PV/_} || MY_P=${P}
DESCRIPTION="A network protocol analyzer formerly known as ethereal"
HOMEPAGE="http://www.wireshark.org/"
SRC_URI="http://www.wireshark.org/download/src/all-versions/${MY_P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0/${PV}"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="
	adns +caps crypt doc doc-pdf geoip gtk ipv6 kerberos libadns lua
	+netlink +pcap portaudio profile python selinux smi ssl zlib
"
RDEPEND="
	>=dev-libs/glib-2.14:2
	netlink? ( dev-libs/libnl )
	adns? ( !libadns? ( >=net-dns/c-ares-1.5 ) )
	crypt? ( dev-libs/libgcrypt )
	caps? ( sys-libs/libcap )
	geoip? ( dev-libs/geoip )
	gtk? (
		>=x11-libs/gtk+-2.4.0:2
		dev-libs/atk
		x11-libs/pango
		x11-misc/xdg-utils
	)
	kerberos? ( virtual/krb5 )
	libadns? ( net-libs/adns )
	lua? ( >=dev-lang/lua-5.1 )
	pcap? ( net-libs/libpcap[-netlink] )
	portaudio? ( media-libs/portaudio )
	python? ( ${PYTHON_DEPS} )
	selinux? ( sec-policy/selinux-wireshark )
	smi? ( net-libs/libsmi )
	ssl? ( net-libs/gnutls dev-libs/libgcrypt )
	zlib? ( sys-libs/zlib !=sys-libs/zlib-1.2.4 )
"

DEPEND="
	${RDEPEND}
	dev-lang/perl
	doc? (
		app-doc/doxygen
		dev-libs/libxml2
		dev-libs/libxslt
		doc-pdf? ( dev-java/fop )
	)
	sys-apps/sed
	sys-devel/bison
	sys-devel/flex
	virtual/pkgconfig
"

S=${WORKDIR}/${MY_P}

pkg_setup() {
	if ! use gtk; then
		ewarn "USE=-gtk disables gtk-based gui called wireshark."
		ewarn "Only command line utils will be built available"
	fi

	if use python; then
		python-single-r1_pkg_setup
	fi
}

src_prepare() {
	epatch \
		"${FILESDIR}"/${PN}-1.6.13-ldflags.patch

	sed -i \
		-e '/^Icon/s|.png||g' \
		-e '/^MimeType.*[[:alnum:]]$/s|$|;|g' \
		${PN}.desktop || die
	sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:g' configure.ac || die

	eautoreconf
}

src_configure() {
	local myconf

	# profile and pie are incompatible #215806, #292991
	if use profile; then
		ewarn "You've enabled the 'profile' USE flag, building PIE binaries is disabled."
		ewarn "Also ignore \"unrecognized option '-nopie'\" gcc warning #358101."
		append-flags $(test-flags-CC -nopie)
	fi

	if use adns; then
		if use libadns; then
			myconf+=( "--with-adns --without-c-ares" )
		else
			myconf+=( "--without-adns --with-c-ares" )
		fi
	else
		if use libadns; then
			myconf+=( "--with-adns --without-c-ares" )
		else
			myconf+=( "--without-adns --without-c-ares" )
		fi
	fi

	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
	if use kerberos; then
		case `krb5-config --libs` in
			*-lcrypto*)
				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
				ewarn "license and the GPL, so do your check before distributing such package."
				myconf+=( "--with-ssl" )
				;;
		esac
	fi

	# Hack around inability to disable doxygen/fop doc generation
	use doc || export ac_cv_prog_HAVE_DOXYGEN=false
	use doc-pdf || export ac_cv_prog_HAVE_FOP=false

	# dumpcap requires libcap, setuid-install requires dumpcap
	econf \
		$(use pcap && use_enable !caps setuid-install) \
		$(use pcap && use_enable caps setcap-install) \
		$(use_enable gtk wireshark) \
		$(use_enable ipv6) \
		$(use_enable profile profile-build) \
		$(use_with netlink libnl) \
		$(use_with crypt gcrypt) \
		$(use_with caps libcap) \
		$(use_with geoip) \
		$(use_with kerberos krb5) \
		$(use_with lua) \
		$(use_with pcap dumpcap-group wireshark) \
		$(use_with pcap) \
		$(use_with portaudio) \
		$(use_with python) \
		$(use_with smi libsmi) \
		$(use_with ssl gnutls) \
		$(use_with zlib) \
		--disable-extra-gcc-checks \
		--disable-usr-local \
		--sysconfdir="${EPREFIX}"/etc/wireshark \
		${myconf[@]}
}

src_compile() {
	default
	use doc && emake -C docbook
}

src_install() {
	default
	if use doc; then
		dohtml -r docbook/{release-notes.html,ws{d,u}g_html{,_chunked}}
		if use doc-pdf; then
			insinto /usr/share/doc/${PF}/pdf/
			doins docbook/{{developer,user}-guide,release-notes}-{a4,us}.pdf
		fi
	fi

	# FAQ is not required as is installed from help/faq.txt
	dodoc AUTHORS ChangeLog NEWS README{,.bsd,.linux,.macos,.vmware} \
		doc/{randpkt.txt,README*}

	# install headers
	local wsheader
	for wsheader in $( echo $(< debian/wireshark-dev.header-files ) ); do
		insinto /usr/include/wireshark/$( dirname ${wsheader} )
		doins ${wsheader}
	done

	#with the above this really shouldn't be needed, but things may be looking in wiretap/ instead of wireshark/wiretap/
	insinto /usr/include/wiretap
	doins wiretap/wtap.h

	if use gtk; then
		for c in hi lo; do
			for d in 16 32 48; do
				insinto /usr/share/icons/${c}color/${d}x${d}/apps
				newins image/${c}${d}-app-wireshark.png wireshark.png
			done
		done
		domenu wireshark.desktop
	fi

	use pcap && chmod o-x "${ED}"/usr/bin/dumpcap #357237

	if use python; then
		python_optimize "${ED}"/usr/lib*/wireshark/python
	fi
}

pkg_postinst() {
	# Add group for users allowed to sniff.
	enewgroup wireshark

	if use pcap; then
		fcaps -o 0 -g wireshark -m 4550 -M 0750 \
			cap_dac_read_search,cap_net_raw,cap_net_admin \
			"${EROOT}"/usr/bin/dumpcap
	fi

	ewarn "NOTE: To run wireshark as normal user you have to add yourself to"
	ewarn "the wireshark group. This security measure ensures that only trusted"
	ewarn "users are allowed to sniff your traffic."
}





^ permalink raw reply	[flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-analyzer/wireshark: ChangeLog wireshark-1.10.0_rc1.ebuild
@ 2013-05-07 14:14 Jeroen Roovers (jer)
  0 siblings, 0 replies; 5+ messages in thread
From: Jeroen Roovers (jer) @ 2013-05-07 14:14 UTC (permalink / raw
  To: gentoo-commits

jer         13/05/07 14:14:04

  Modified:             ChangeLog wireshark-1.10.0_rc1.ebuild
  Log:
  Work around parallel make issue in documentation generation (bug #468490).
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.478                net-analyzer/wireshark/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.478&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.478&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?r1=1.477&r2=1.478

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v
retrieving revision 1.477
retrieving revision 1.478
diff -u -r1.477 -r1.478
--- ChangeLog	2 May 2013 13:38:31 -0000	1.477
+++ ChangeLog	7 May 2013 14:14:04 -0000	1.478
@@ -1,6 +1,9 @@
 # ChangeLog for net-analyzer/wireshark
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.477 2013/05/02 13:38:31 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.478 2013/05/07 14:14:04 jer Exp $
+
+  07 May 2013; Jeroen Roovers <jer@gentoo.org> wireshark-1.10.0_rc1.ebuild:
+  Work around parallel make issue in documentation generation (bug #468490).
 
   02 May 2013; Jeroen Roovers <jer@gentoo.org> -wireshark-1.9.2.ebuild:
   Obsolete.



1.2                  net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?r1=1.1&r2=1.2

Index: wireshark-1.10.0_rc1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- wireshark-1.10.0_rc1.ebuild	27 Apr 2013 17:05:37 -0000	1.1
+++ wireshark-1.10.0_rc1.ebuild	7 May 2013 14:14:04 -0000	1.2
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.1 2013/04/27 17:05:37 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.2 2013/05/07 14:14:04 jer Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_5 python2_6 python2_7 )
@@ -111,7 +111,7 @@
 	# Workaround bug #213705. If krb5-config --libs has -lcrypto then pass
 	# --with-ssl to ./configure. (Mimics code from acinclude.m4).
 	if use kerberos; then
-		case `krb5-config --libs` in
+		case $(krb5-config --libs) in
 			*-lcrypto*)
 				ewarn "Kerberos was built with ssl support: linkage with openssl is enabled."
 				ewarn "Note there are annoying license incompatibilities between the OpenSSL"
@@ -153,7 +153,7 @@
 
 src_compile() {
 	default
-	use doc && emake -C docbook
+	use doc && emake -j1 -C docbook
 }
 
 src_install() {





^ permalink raw reply	[flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-analyzer/wireshark: ChangeLog wireshark-1.10.0_rc1.ebuild
@ 2013-05-07 22:06 Jeroen Roovers (jer)
  0 siblings, 0 replies; 5+ messages in thread
From: Jeroen Roovers (jer) @ 2013-05-07 22:06 UTC (permalink / raw
  To: gentoo-commits

jer         13/05/07 22:06:44

  Modified:             ChangeLog wireshark-1.10.0_rc1.ebuild
  Log:
  No need to replace AM_CONFIG_HEADER.
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.480                net-analyzer/wireshark/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.480&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.480&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?r1=1.479&r2=1.480

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v
retrieving revision 1.479
retrieving revision 1.480
diff -u -r1.479 -r1.480
--- ChangeLog	7 May 2013 14:16:13 -0000	1.479
+++ ChangeLog	7 May 2013 22:06:44 -0000	1.480
@@ -1,6 +1,9 @@
 # ChangeLog for net-analyzer/wireshark
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.479 2013/05/07 14:16:13 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.480 2013/05/07 22:06:44 jer Exp $
+
+  07 May 2013; Jeroen Roovers <jer@gentoo.org> wireshark-1.10.0_rc1.ebuild:
+  No need to replace AM_CONFIG_HEADER.
 
   07 May 2013; Jeroen Roovers <jer@gentoo.org> wireshark-1.10.0_rc1.ebuild:
   Work around parallel make issue in documentation generation (bug #468356).



1.3                  net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?r1=1.2&r2=1.3

Index: wireshark-1.10.0_rc1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- wireshark-1.10.0_rc1.ebuild	7 May 2013 14:14:04 -0000	1.2
+++ wireshark-1.10.0_rc1.ebuild	7 May 2013 22:06:44 -0000	1.3
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.2 2013/05/07 14:14:04 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.3 2013/05/07 22:06:44 jer Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_5 python2_6 python2_7 )
@@ -79,7 +79,6 @@
 		-e '/^Icon/s|.png||g' \
 		-e '/^MimeType.*[[:alnum:]]$/s|$|;|g' \
 		${PN}.desktop || die
-	sed -i -e 's:AM_CONFIG_HEADER:AC_CONFIG_HEADERS:g' configure.ac || die
 
 	eautoreconf
 }





^ permalink raw reply	[flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-analyzer/wireshark: ChangeLog wireshark-1.10.0_rc1.ebuild
@ 2013-05-08  1:02 Jeroen Roovers (jer)
  0 siblings, 0 replies; 5+ messages in thread
From: Jeroen Roovers (jer) @ 2013-05-08  1:02 UTC (permalink / raw
  To: gentoo-commits

jer         13/05/08 01:02:08

  Modified:             ChangeLog wireshark-1.10.0_rc1.ebuild
  Log:
  Fix pkg-config use (bug #468490 by Chris Smith).
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.481                net-analyzer/wireshark/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.481&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.481&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?r1=1.480&r2=1.481

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v
retrieving revision 1.480
retrieving revision 1.481
diff -u -r1.480 -r1.481
--- ChangeLog	7 May 2013 22:06:44 -0000	1.480
+++ ChangeLog	8 May 2013 01:02:08 -0000	1.481
@@ -1,6 +1,10 @@
 # ChangeLog for net-analyzer/wireshark
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.480 2013/05/07 22:06:44 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.481 2013/05/08 01:02:08 jer Exp $
+
+  08 May 2013; Jeroen Roovers <jer@gentoo.org> wireshark-1.10.0_rc1.ebuild,
+  +files/wireshark-1.10.0-pkg-config.patch:
+  Fix pkg-config use (bug #468490 by Chris Smith).
 
   07 May 2013; Jeroen Roovers <jer@gentoo.org> wireshark-1.10.0_rc1.ebuild:
   No need to replace AM_CONFIG_HEADER.



1.4                  net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.4&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.4&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?r1=1.3&r2=1.4

Index: wireshark-1.10.0_rc1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v
retrieving revision 1.3
retrieving revision 1.4
diff -u -r1.3 -r1.4
--- wireshark-1.10.0_rc1.ebuild	7 May 2013 22:06:44 -0000	1.3
+++ wireshark-1.10.0_rc1.ebuild	8 May 2013 01:02:08 -0000	1.4
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.3 2013/05/07 22:06:44 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.4 2013/05/08 01:02:08 jer Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_5 python2_6 python2_7 )
@@ -73,7 +73,8 @@
 
 src_prepare() {
 	epatch \
-		"${FILESDIR}"/${PN}-1.6.13-ldflags.patch
+		"${FILESDIR}"/${PN}-1.6.13-ldflags.patch \
+		"${FILESDIR}"/${PN}-1.10.0-pkg-config.patch
 
 	sed -i \
 		-e '/^Icon/s|.png||g' \





^ permalink raw reply	[flat|nested] 5+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-analyzer/wireshark: ChangeLog wireshark-1.10.0_rc1.ebuild
@ 2013-05-08 13:30 Jeroen Roovers (jer)
  0 siblings, 0 replies; 5+ messages in thread
From: Jeroen Roovers (jer) @ 2013-05-08 13:30 UTC (permalink / raw
  To: gentoo-commits

jer         13/05/08 13:30:13

  Modified:             ChangeLog wireshark-1.10.0_rc1.ebuild
  Log:
  Add more documentation dependencies (bug #468356).
  
  (Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key A792A613)

Revision  Changes    Path
1.485                net-analyzer/wireshark/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.485&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?rev=1.485&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/ChangeLog?r1=1.484&r2=1.485

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v
retrieving revision 1.484
retrieving revision 1.485
diff -u -r1.484 -r1.485
--- ChangeLog	8 May 2013 02:38:56 -0000	1.484
+++ ChangeLog	8 May 2013 13:30:13 -0000	1.485
@@ -1,6 +1,9 @@
 # ChangeLog for net-analyzer/wireshark
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.484 2013/05/08 02:38:56 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/ChangeLog,v 1.485 2013/05/08 13:30:13 jer Exp $
+
+  08 May 2013; Jeroen Roovers <jer@gentoo.org> wireshark-1.10.0_rc1.ebuild:
+  Add more documentation dependencies (bug #468356).
 
   08 May 2013; Jeroen Roovers <jer@gentoo.org> wireshark-1.8.6-r1.ebuild,
   wireshark-1.10.0_rc1.ebuild:



1.8                  net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.8&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?rev=1.8&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild?r1=1.7&r2=1.8

Index: wireshark-1.10.0_rc1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v
retrieving revision 1.7
retrieving revision 1.8
diff -u -r1.7 -r1.8
--- wireshark-1.10.0_rc1.ebuild	8 May 2013 02:38:56 -0000	1.7
+++ wireshark-1.10.0_rc1.ebuild	8 May 2013 13:30:13 -0000	1.8
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.7 2013/05/08 02:38:56 jer Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-analyzer/wireshark/wireshark-1.10.0_rc1.ebuild,v 1.8 2013/05/08 13:30:13 jer Exp $
 
 EAPI=5
 PYTHON_COMPAT=( python2_5 python2_6 python2_7 )
@@ -51,9 +51,11 @@
 	${RDEPEND}
 	doc? (
 		app-doc/doxygen
+		app-text/asciidoc
 		dev-libs/libxml2
 		dev-libs/libxslt
 		doc-pdf? ( dev-java/fop )
+		www-client/lynx
 	)
 	>=virtual/perl-Pod-Simple-3.170.0
 	sys-apps/sed





^ permalink raw reply	[flat|nested] 5+ messages in thread
end of thread, other threads:[~2013-05-08 13:30 UTC | newest]

Thread overview: 5+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-04-27 17:05 [gentoo-commits] gentoo-x86 commit in net-analyzer/wireshark: ChangeLog wireshark-1.10.0_rc1.ebuild Jeroen Roovers (jer)
  -- strict thread matches above, loose matches on Subject: below --
2013-05-07 14:14 Jeroen Roovers (jer)
2013-05-07 22:06 Jeroen Roovers (jer)
2013-05-08  1:02 Jeroen Roovers (jer)
2013-05-08 13:30 Jeroen Roovers (jer)

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox