[gentoo-commits] gentoo-x86 commit in www-misc/monitorix: monitorix-3.1.0.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in www-misc/monitorix: monitorix-3.1.0.ebuild ChangeLog

[Tom Wijsman (tomwij)]

tomwij      13/04/24 19:58:53

  Modified:             ChangeLog
  Added:                monitorix-3.1.0.ebuild
  Log:
  Version bump to 3.1.0, thanks to Matt for reporting this on IRC.
  
  (Portage version: 2.1.11.62/cvs/Linux x86_64, signed Manifest commit with key 6D34E57D)

Revision  Changes    Path
1.3                  www-misc/monitorix/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/monitorix/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/monitorix/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/monitorix/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-misc/monitorix/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	13 Mar 2013 19:28:45 -0000	1.2
+++ ChangeLog	24 Apr 2013 19:58:53 -0000	1.3
@@ -1,6 +1,11 @@
 # ChangeLog for www-misc/monitorix
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-misc/monitorix/ChangeLog,v 1.2 2013/03/13 19:28:45 tomwij Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-misc/monitorix/ChangeLog,v 1.3 2013/04/24 19:58:53 tomwij Exp $
+
+*monitorix-3.1.0 (24 Apr 2013)
+
+  24 Apr 2013; Tom Wijsman <TomWij@gentoo.org> +monitorix-3.1.0.ebuild:
+  Version bump to 3.1.0, thanks to Matt for reporting this on IRC.
 
 *monitorix-3.0.0-r1 (13 Mar 2013)
 



1.1                  www-misc/monitorix/monitorix-3.1.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/monitorix/monitorix-3.1.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-misc/monitorix/monitorix-3.1.0.ebuild?rev=1.1&content-type=text/plain

Index: monitorix-3.1.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-misc/monitorix/monitorix-3.1.0.ebuild,v 1.1 2013/04/24 19:58:52 tomwij Exp $

EAPI="5"

inherit eutils

DESCRIPTION="A lightweight system monitoring tool"
HOMEPAGE="http://www.${PN}.org/"
SRC_URI="http://www.${PN}.org/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="evms hddtemp httpd lm_sensors postfix"

DEPEND="sys-apps/sed"
RDEPEND="net-analyzer/rrdtool[perl]
	dev-perl/DBI
	dev-perl/libwww-perl
	dev-perl/XML-Simple
	dev-perl/config-general
	dev-perl/HTTP-Server-Simple
	evms? ( sys-fs/evms )
	hddtemp? ( app-admin/hddtemp )
	httpd? ( virtual/httpd-cgi )
	lm_sensors? ( sys-apps/lm_sensors )
	postfix? ( net-mail/pflogsumm )"

pkg_setup() {
	enewgroup ${PN}
	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
}

src_prepare() {
	# Put better Gentoo defaults in the configuration file.
	sed -i "s|\(base_dir.*\)/usr/share/${PN}|\1/usr/share/${PN}/htdocs|" ${PN}.conf
	sed -i "s|\(secure_log.*\)/var/log/secure|\1/var/log/auth.log|" ${PN}.conf
	sed -i "s|nobody|${PN}|g" ${PN}.conf
}

src_install() {
	dosbin ${PN}

	newinitd "${FILESDIR}"/${PN}-3.0.0.init ${PN}

	insinto /etc
	doins ${PN}.conf

	insinto /etc/logrotate.d
	newins docs/${PN}.logrotate ${PN}

	dodoc Changes README{,.nginx} docs/${PN}.service docs/${PN}-{alert.sh,apache.conf,lighttpd.conf}
	doman man/man5/${PN}.conf.5
	doman man/man8/${PN}.8

	insinto /usr/share/${PN}/htdocs
	doins logo_bot.png logo_top.png ${PN}ico.png

	dodir /var/lib/${PN}/imgs
	dosym /var/lib/${PN}/imgs /usr/share/${PN}/htdocs/imgs

	exeinto /usr/share/${PN}/htdocs/cgi
	doexe ${PN}.cgi

	dodir /usr/lib/${PN}
	exeinto /usr/lib/${PN}
	doexe lib/*.pm

	dodir /var/lib/${PN}/usage
	insinto /var/lib/${PN}/reports
	doins -r reports/*
}

pkg_postinst() {
	chown monitorix:monitorix /var/lib/${PN}/imgs

	elog "WARNING: ${PN} includes a brand new config format since version"
	elog "3.0.0, that may be incompatible with your existing config"
	elog "file. Please take care if upgrading from an old version."
	elog ""
	elog "${PN} includes its own web server as of version 3.0.0."
	elog "For this reason, the dependency on the webapp framework"
	elog "has been removed. If you wish to use your own web server,"
	elog "the ${PN} web data can be found at:"
	elog "/usr/share/${PN}/htdocs/"
}