[gentoo-commits] gentoo-x86 commit in sys-power/powertop: powertop-9999.ebuild powertop-2.3.ebuild ChangeLog

["Richard Farina (zerochaos)" <zerochaos@gentoo.org>]

zerochaos    13/04/07 15:14:40

  Modified:             powertop-9999.ebuild ChangeLog
  Added:                powertop-2.3.ebuild
  Log:
  version bump for 2.3
  
  (Portage version: 2.1.11.55/cvs/Linux x86_64, signed Manifest commit with key DD11F94A)

Revision  Changes    Path
1.18                 sys-power/powertop/powertop-9999.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/powertop/powertop-9999.ebuild?rev=1.18&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/powertop/powertop-9999.ebuild?rev=1.18&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/powertop/powertop-9999.ebuild?r1=1.17&r2=1.18

Index: powertop-9999.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/powertop/powertop-9999.ebuild,v
retrieving revision 1.17
retrieving revision 1.18
diff -u -r1.17 -r1.18
--- powertop-9999.ebuild	8 Mar 2013 06:16:03 -0000	1.17
+++ powertop-9999.ebuild	7 Apr 2013 15:14:40 -0000	1.18
@@ -1,8 +1,8 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/powertop/powertop-9999.ebuild,v 1.17 2013/03/08 06:16:03 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/powertop/powertop-9999.ebuild,v 1.18 2013/04/07 15:14:40 zerochaos Exp $
 
-EAPI="4"
+EAPI="5"
 
 inherit eutils linux-info
 if [[ ${PV} == "9999" ]] ; then
@@ -24,16 +24,17 @@
 COMMON_DEPEND="
 	dev-libs/libnl:3
 	sys-apps/pciutils
-	sys-devel/gettext
 	sys-libs/ncurses[unicode?]
 "
 
 DEPEND="${COMMON_DEPEND}
 	virtual/pkgconfig
+	sys-devel/gettext
 "
 RDEPEND="
 	${COMMON_DEPEND}
 	X? ( x11-apps/xset )
+	virtual/libintl
 "
 
 DOCS=( TODO README )



1.77                 sys-power/powertop/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/powertop/ChangeLog?rev=1.77&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/powertop/ChangeLog?rev=1.77&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/powertop/ChangeLog?r1=1.76&r2=1.77

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-power/powertop/ChangeLog,v
retrieving revision 1.76
retrieving revision 1.77
diff -u -r1.76 -r1.77
--- ChangeLog	25 Mar 2013 16:30:32 -0000	1.76
+++ ChangeLog	7 Apr 2013 15:14:40 -0000	1.77
@@ -1,6 +1,12 @@
 # ChangeLog for sys-power/powertop
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-power/powertop/ChangeLog,v 1.76 2013/03/25 16:30:32 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-power/powertop/ChangeLog,v 1.77 2013/04/07 15:14:40 zerochaos Exp $
+
+*powertop-2.3 (07 Apr 2013)
+
+  07 Apr 2013; Rick Farina <zerochaos@gentoo.org> +powertop-2.3.ebuild,
+  powertop-9999.ebuild:
+  version bump for 2.3
 
 *powertop-2.2-r2 (25 Mar 2013)
 



1.1                  sys-power/powertop/powertop-2.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/powertop/powertop-2.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-power/powertop/powertop-2.3.ebuild?rev=1.1&content-type=text/plain

Index: powertop-2.3.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-power/powertop/powertop-2.3.ebuild,v 1.1 2013/04/07 15:14:40 zerochaos Exp $

EAPI="5"

inherit eutils linux-info
if [[ ${PV} == "9999" ]] ; then
	EGIT_REPO_URI="git://github.com/fenrus75/powertop.git"
	inherit git-2 autotools
	SRC_URI=""
else
	SRC_URI="https://01.org/powertop/sites/default/files/downloads/${P}.tar.gz"
	KEYWORDS="~amd64 ~arm ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux"
fi

DESCRIPTION="tool that helps you find what software is using the most power"
HOMEPAGE="https://01.org/powertop/ http://www.lesswatts.org/projects/powertop/"

LICENSE="GPL-2"
SLOT="0"
IUSE="unicode X"

COMMON_DEPEND="
	dev-libs/libnl:3
	sys-apps/pciutils
	sys-libs/ncurses[unicode?]
"

DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
	sys-devel/gettext
"
RDEPEND="
	${COMMON_DEPEND}
	X? ( x11-apps/xset )
	virtual/libintl
"

DOCS=( TODO README )

pkg_setup() {
	if linux_config_exists; then
		CONFIG_CHECK="
			~X86_MSR
			~DEBUG_FS
			~PERF_EVENTS
			~TRACEPOINTS
			~NO_HZ
			~HIGH_RES_TIMERS
			~HPET_TIMER
			~CPU_FREQ_STAT
			~CPU_FREQ_GOV_ONDEMAND
			~USB_SUSPEND
			~FTRACE
			~BLK_DEV_IO_TRACE
			~TIMER_STATS
			~EVENT_POWER_TRACING_DEPRECATED
			~TRACING
		"
		if kernel_is -lt 3 7 0; then
			linux_chkconfig_present SND_HDA_INTEL && CONFIG_CHECK+="~SND_HDA_POWER_SAVE"
			linux_chkconfig_present SND_HDA_INTEL && ERROR_KERNEL_SND_HDA_POWER_SAVE="SND_HDA_POWER_SAVE should be enabled in the kernel for full powertop function"
		fi
		ERROR_KERNEL_X86_MSR="X86_MSR is not enabled in the kernel, you almost certainly need it"
		ERROR_KERNEL_DEBUG_FS="DEBUG_FS is not enabled in the kernel, you almost certainly need it"
		ERROR_KERNEL_PERF_EVENTS="PERF_EVENTS should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_TRACEPOINTS="TRACEPOINTS should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_NO_HZ="NO_HZ should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_HIGH_RES_TIMERS="HIGH_RES_TIMERS should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_HPET_TIMER="HPET_TIMER should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_CPU_FREQ_STAT="CPU_FREQ_STAT should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_CPU_FREQ_GOV_ONDEMAND="CPU_FREQ_GOV_ONDEMAND should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_USB_SUSPEND="USB_SUSPEND should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_FTRACE="FTRACE needs to be turned on to enable BLK_DEV_IO_TRACE"
		ERROR_KERNEL_BLK_DEV_IO_TRACE="BLK_DEV_IO_TRACE needs to be turned on to enable TIMER_STATS, TRACING and EVENT_POWER_TRACING_DEPRECATED"
		ERROR_KERNEL_TIMER_STATS="TIMER_STATS should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_EVENT_POWER_TRACING_DEPRECATED="EVENT_POWER_TRACING_DEPRECATED should be enabled in the kernel for full powertop function"
		ERROR_KERNEL_TRACING="TRACING should be enabled in the kernel for full powertop function"
		linux-info_pkg_setup
	else
		ewarn "unable to find kernel config, all checks disabled"
	fi
}

src_prepare() {
	if [[ ${PV} == "9999" ]] ; then
		eautoreconf
	fi
}

src_configure() {
	export ac_cv_search_delwin=$(usex unicode -lncursesw -lncurses)
	default
}

src_compile() {
	#maintainer note: there is no csstoh dir in this version, any needed changes for cross are permitted
	# This fixes cross-compiling.  Please verify before deleting.
	#emake -C src csstoh
	#cp "${FILESDIR}"/csstoh src/ || die
	emake
}

src_install() {
	default
	keepdir /var/cache/powertop
}