* [gentoo-commits] gentoo-x86 commit in sys-auth/consolekit: consolekit-0.4.5_p20120320-r2.ebuild ChangeLog consolekit-0.4.5_p20120320-r1.ebuild
@ 2013-03-16 17:11 Samuli Suominen (ssuominen)
0 siblings, 0 replies; only message in thread
From: Samuli Suominen (ssuominen) @ 2013-03-16 17:11 UTC (permalink / raw
To: gentoo-commits
ssuominen 13/03/16 17:11:50
Modified: ChangeLog consolekit-0.4.5_p20120320-r1.ebuild
Added: consolekit-0.4.5_p20120320-r2.ebuild
Log:
revbump fox bug 461866
(Portage version: 2.2.0_alpha166/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)
Revision Changes Path
1.153 sys-auth/consolekit/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/ChangeLog?rev=1.153&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/ChangeLog?rev=1.153&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/ChangeLog?r1=1.152&r2=1.153
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/consolekit/ChangeLog,v
retrieving revision 1.152
retrieving revision 1.153
diff -u -r1.152 -r1.153
--- ChangeLog 14 Mar 2013 02:56:28 -0000 1.152
+++ ChangeLog 16 Mar 2013 17:11:49 -0000 1.153
@@ -1,6 +1,13 @@
# ChangeLog for sys-auth/consolekit
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/consolekit/ChangeLog,v 1.152 2013/03/14 02:56:28 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/consolekit/ChangeLog,v 1.153 2013/03/16 17:11:49 ssuominen Exp $
+
+*consolekit-0.4.5_p20120320-r2 (16 Mar 2013)
+
+ 16 Mar 2013; Samuli Suominen <ssuominen@gentoo.org>
+ consolekit-0.4.5_p20120320-r1.ebuild, +consolekit-0.4.5_p20120320-r2.ebuild:
+ Fix use of QA_MULTILIB_PATHS and revision bump because the helpers are also
+ used by gnome-base/gdm moved wrt #461866 by Alphat-PC
14 Mar 2013; Samuli Suominen <ssuominen@gentoo.org>
consolekit-0.4.5_p20120320-r1.ebuild:
1.19 sys-auth/consolekit/consolekit-0.4.5_p20120320-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r1.ebuild?rev=1.19&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r1.ebuild?rev=1.19&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r1.ebuild?r1=1.18&r2=1.19
Index: consolekit-0.4.5_p20120320-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r1.ebuild,v
retrieving revision 1.18
retrieving revision 1.19
diff -u -r1.18 -r1.19
--- consolekit-0.4.5_p20120320-r1.ebuild 14 Mar 2013 02:56:28 -0000 1.18
+++ consolekit-0.4.5_p20120320-r1.ebuild 16 Mar 2013 17:11:49 -0000 1.19
@@ -1,6 +1,6 @@
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r1.ebuild,v 1.18 2013/03/14 02:56:28 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r1.ebuild,v 1.19 2013/03/16 17:11:49 ssuominen Exp $
EAPI=5
inherit autotools eutils linux-info pam systemd
@@ -46,8 +46,6 @@
S=${WORKDIR}/${MY_P}
-QA_MULTILIB_PATHS="usr/lib/ConsoleKit/udev-acl"
-
pkg_setup() {
if use kernel_linux; then
# This is from http://bugs.gentoo.org/376939
@@ -74,7 +72,6 @@
econf \
XMLTO_FLAGS='--skip-validation' \
- --libexecdir="${EPREFIX}"/usr/lib/${MY_PN} \
--localstatedir="${EPREFIX}"/var \
$(use_enable pam pam-module) \
$(use_enable doc docbook-docs) \
1.1 sys-auth/consolekit/consolekit-0.4.5_p20120320-r2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r2.ebuild?rev=1.1&content-type=text/plain
Index: consolekit-0.4.5_p20120320-r2.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-auth/consolekit/consolekit-0.4.5_p20120320-r2.ebuild,v 1.1 2013/03/16 17:11:49 ssuominen Exp $
EAPI=5
inherit autotools eutils linux-info pam systemd
MY_PN=ConsoleKit
MY_P=${MY_PN}-${PV}
DESCRIPTION="Framework for defining and tracking users, login sessions and seats."
HOMEPAGE="http://www.freedesktop.org/wiki/Software/ConsoleKit"
if [[ ${PV} = *p20* ]]; then
SRC_URI="mirror://gentoo/${MY_P}.tar.xz"
else
SRC_URI="http://www.freedesktop.org/software/${MY_PN}/dist/${MY_P}.tar.bz2"
fi
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux"
IUSE="acl debug doc kernel_linux pam policykit selinux test"
COMMON_DEPEND=">=dev-libs/dbus-glib-0.100:=
>=dev-libs/glib-2.22:2=
sys-libs/zlib:=
x11-libs/libX11:=
acl? (
sys-apps/acl:=
>=virtual/udev-171
)
pam? ( virtual/pam )
policykit? ( >=sys-auth/polkit-0.110 )"
RDEPEND="${COMMON_DEPEND}
kernel_linux? ( sys-apps/coreutils[acl?] )
selinux? ( sec-policy/selinux-consolekit )"
DEPEND="${COMMON_DEPEND}
dev-libs/libxslt
virtual/pkgconfig
doc? ( app-text/xmlto )
test? (
app-text/docbook-xml-dtd:4.1.2
app-text/xmlto
)"
S=${WORKDIR}/${MY_P}
QA_MULTILIB_PATHS="usr/lib/ConsoleKit/.*"
pkg_setup() {
if use kernel_linux; then
# This is from http://bugs.gentoo.org/376939
use acl && CONFIG_CHECK="~TMPFS_POSIX_ACL"
# This is required to get login-session-id string with pam_ck_connector.so
use pam && CONFIG_CHECK+=" ~AUDITSYSCALL"
linux-info_pkg_setup
fi
}
src_prepare() {
epatch \
"${FILESDIR}"/${PN}-cleanup_console_tags.patch \
"${FILESDIR}"/${PN}-shutdown-reboot-without-policies.patch \
"${FILESDIR}"/${PN}-udev-acl-install_to_usr.patch \
"${FILESDIR}"/${PN}-0.4.5-polkit-automagic.patch
eautoreconf
}
src_configure() {
local myconf
[[ ${PV} = *p20* ]] && myconf='--enable-maintainer-mode'
econf \
XMLTO_FLAGS='--skip-validation' \
--libexecdir="${EPREFIX}"/usr/lib/${MY_PN} \
--localstatedir="${EPREFIX}"/var \
$(use_enable pam pam-module) \
$(use_enable doc docbook-docs) \
$(use_enable test docbook-docs) \
$(use_enable debug) \
$(use_enable policykit polkit) \
$(use_enable acl udev-acl) \
--with-dbus-services="${EPREFIX}"/usr/share/dbus-1/services \
--with-pam-module-dir="$(getpam_mod_dir)" \
"$(systemd_with_unitdir)" \
${myconf}
}
src_install() {
emake \
DESTDIR="${D}" \
htmldocdir="${EPREFIX}"/usr/share/doc/${PF}/html \
install
dodoc AUTHORS HACKING NEWS README TODO
newinitd "${FILESDIR}"/${PN}-0.2.rc consolekit
keepdir /usr/lib/ConsoleKit/run-seat.d
keepdir /usr/lib/ConsoleKit/run-session.d
keepdir /etc/ConsoleKit/run-session.d
keepdir /var/log/ConsoleKit
exeinto /etc/X11/xinit/xinitrc.d
newexe "${FILESDIR}"/90-consolekit-3 90-consolekit
exeinto /usr/lib/ConsoleKit/run-session.d
doexe "${FILESDIR}"/pam-foreground-compat.ck
prune_libtool_files --all # --all for pam_ck_connector.la
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-03-16 17:11 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-03-16 17:11 [gentoo-commits] gentoo-x86 commit in sys-auth/consolekit: consolekit-0.4.5_p20120320-r2.ebuild ChangeLog consolekit-0.4.5_p20120320-r1.ebuild Samuli Suominen (ssuominen)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox