* [gentoo-commits] gentoo-x86 commit in www-client/qupzilla: qupzilla-1.4.0.ebuild ChangeLog
@ 2013-03-12 12:34 Ben de Groot (yngwin)
0 siblings, 0 replies; only message in thread
From: Ben de Groot (yngwin) @ 2013-03-12 12:34 UTC (permalink / raw
To: gentoo-commits
yngwin 13/03/12 12:34:34
Modified: ChangeLog
Added: qupzilla-1.4.0.ebuild
Log:
Version bump. Drop patches, which have been applied upstream. Add Catalan localization.
(Portage version: 2.2.0_alpha166/cvs/Linux x86_64, signed Manifest commit with key 0x2B2474AD43CE296E!)
Revision Changes Path
1.24 www-client/qupzilla/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qupzilla/ChangeLog?rev=1.24&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qupzilla/ChangeLog?rev=1.24&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qupzilla/ChangeLog?r1=1.23&r2=1.24
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/www-client/qupzilla/ChangeLog,v
retrieving revision 1.23
retrieving revision 1.24
diff -u -r1.23 -r1.24
--- ChangeLog 2 Mar 2013 23:41:08 -0000 1.23
+++ ChangeLog 12 Mar 2013 12:34:34 -0000 1.24
@@ -1,6 +1,12 @@
# ChangeLog for www-client/qupzilla
# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/qupzilla/ChangeLog,v 1.23 2013/03/02 23:41:08 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/qupzilla/ChangeLog,v 1.24 2013/03/12 12:34:34 yngwin Exp $
+
+*qupzilla-1.4.0 (12 Mar 2013)
+
+ 12 Mar 2013; Ben de Groot <yngwin@gentoo.org> +qupzilla-1.4.0.ebuild:
+ Version bump. Drop patches, which have been applied upstream. Add Catalan
+ localization.
02 Mar 2013; Markos Chandras <hwoarang@gentoo.org> qupzilla-1.3.5-r1.ebuild:
Move Qt dependencies to the new category
1.1 www-client/qupzilla/qupzilla-1.4.0.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qupzilla/qupzilla-1.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/www-client/qupzilla/qupzilla-1.4.0.ebuild?rev=1.1&content-type=text/plain
Index: qupzilla-1.4.0.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/www-client/qupzilla/qupzilla-1.4.0.ebuild,v 1.1 2013/03/12 12:34:34 yngwin Exp $
EAPI=5
PLOCALES="ca_ES cs_CZ de_DE el_GR es_ES es_VE fa_IR fr_FR hu_HU id_ID it_IT
ja_JP ka_GE nl_NL pl_PL pt_BR pt_PT ro_RO ru_RU sk_SK sr_BA sr_RS sv_SE uk_UA
zh_CN zh_TW"
inherit l10n multilib qt4-r2 vcs-snapshot
MY_P="QupZilla-${PV}"
DESCRIPTION="Qt WebKit web browser"
HOMEPAGE="http://www.qupzilla.com/"
SRC_URI="http://www.qupzilla.com/uploads/${MY_P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="dbus debug kde nonblockdialogs"
DEPEND="
>=dev-qt/qtcore-4.7:4
>=dev-qt/qtgui-4.7:4
>=dev-qt/qtscript-4.7:4
>=dev-qt/qtsql-4.7:4
>=dev-qt/qtwebkit-4.7:4
dbus? ( >=dev-qt/qtdbus-4.7:4 )"
RDEPEND="${DEPEND}"
S=${WORKDIR}/${MY_P}
DOCS="AUTHORS BUILDING CHANGELOG FAQ README.md"
src_prepare() {
# remove outdated copies of localizations:
rm -rf bin/locale || die
epatch_user
}
src_configure() {
# see BUILDING document for explanation of options
export QUPZILLA_PREFIX=${EPREFIX}/usr/
export USE_LIBPATH=${QUPZILLA_PREFIX}$(get_libdir)
export DISABLE_DBUS=$(use dbus && echo false || echo true)
export KDE=$(use kde && echo true || echo false) # in future this will enable nepomuk integration
export NONBLOCK_JS_DIALOGS=$(use nonblockdialogs && echo true || echo false)
has_version '>=dev-qt/qtwebkit-4.8.0:4' && export USE_QTWEBKIT_2_2=true
eqmake4
}
src_install() {
qt4-r2_src_install
l10n_for_each_disabled_locale_do rm_loc
}
rm_loc() {
rm "${D}"/usr/share/${PN}/locale/${1}.qm || die
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2013-03-12 12:34 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2013-03-12 12:34 [gentoo-commits] gentoo-x86 commit in www-client/qupzilla: qupzilla-1.4.0.ebuild ChangeLog Ben de Groot (yngwin)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox