[gentoo-commits] gentoo-x86 commit in dev-util/global: global-6.2.8.ebuild ChangeLog

["Mike Gilbert (floppym)" <floppym@gentoo.org>]

floppym     13/03/05 02:38:24

  Modified:             ChangeLog
  Added:                global-6.2.8.ebuild
  Log:
  Version bump. Ebuild by Arfrever.
  
  (Portage version: 2.2.0_alpha165/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

Revision  Changes    Path
1.107                dev-util/global/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?rev=1.107&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?rev=1.107&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/ChangeLog?r1=1.106&r2=1.107

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v
retrieving revision 1.106
retrieving revision 1.107
diff -u -r1.106 -r1.107
--- ChangeLog	18 Feb 2013 08:32:53 -0000	1.106
+++ ChangeLog	5 Mar 2013 02:38:24 -0000	1.107
@@ -1,10 +1,15 @@
 # ChangeLog for dev-util/global
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.106 2013/02/18 08:32:53 naota Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/global/ChangeLog,v 1.107 2013/03/05 02:38:24 floppym Exp $
+
+*global-6.2.8 (05 Mar 2013)
+
+  05 Mar 2013; Mike Gilbert <floppym@gentoo.org> +global-6.2.8.ebuild:
+  Version bump. Ebuild by Arfrever.
 
 *global-6.2.7-r1 (18 Feb 2013)
 
-  18 Feb 2013; Naohiro Aota +global-6.2.7-r1.ebuild:
+  18 Feb 2013; Naohiro Aota <naota@gentoo.org> +global-6.2.7-r1.ebuild:
   Do not drop all .la files. #457856
 
 *global-6.2.7 (20 Jan 2013)



1.1                  dev-util/global/global-6.2.8.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/global-6.2.8.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/global/global-6.2.8.ebuild?rev=1.1&content-type=text/plain

Index: global-6.2.8.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/global/global-6.2.8.ebuild,v 1.1 2013/03/05 02:38:24 floppym Exp $

EAPI="5"

inherit elisp-common eutils

DESCRIPTION="GNU Global is a tag system to find the locations of a specified object in various sources."
HOMEPAGE="http://www.gnu.org/software/global/global.html"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"

LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~x86-fbsd"
IUSE="doc emacs vim"

RDEPEND="sys-devel/libtool
	sys-libs/ncurses
	emacs? ( virtual/emacs )
	vim? ( || ( app-editors/vim app-editors/gvim ) )"
DEPEND="${DEPEND}
	doc? ( app-text/texi2html sys-apps/texinfo )"

SITEFILE="50gtags-gentoo.el"

src_configure() {
	econf "$(use_with emacs lispdir "${SITELISP}/${PN}")"
}

src_compile() {
	if use doc; then
		texi2pdf -q -o doc/global.pdf doc/global.texi
		texi2html -o doc/global.html doc/global.texi
	fi

	if use emacs; then
		elisp-compile *.el || die "elisp-compile failed"
	fi

	emake
}

src_install() {
	emake DESTDIR="${D}" install

	if use doc; then
		dohtml doc/global.html
		[[ -f doc/global.pdf ]] && dodoc doc/global.pdf
	fi

	dodoc AUTHORS FAQ NEWS README THANKS

	insinto /etc
	doins gtags.conf

	if use vim; then
		insinto /usr/share/vim/vimfiles/plugin
		doins gtags.vim
	fi

	if use emacs; then
		elisp-install ${PN} *.{el,elc} || die "elisp-install failed"
		elisp-site-file-install "${FILESDIR}/${SITEFILE}" || die "elisp-site-file-install failed"
	fi

	prune_libtool_files
}

pkg_postinst() {
	use emacs && elisp-site-regen
}

pkg_postrm() {
	use emacs && elisp-site-regen
}