[gentoo-commits] gentoo-x86 commit in sci-libs/openmm: metadata.xml openmm-4.1.1-r1.ebuild ChangeLog openmm-4.1.1.ebuild

[gentoo-commits] gentoo-x86 commit in sci-libs/openmm: metadata.xml openmm-4.1.1-r1.ebuild ChangeLog openmm-4.1.1.ebuild

[Christoph Junghans (ottxor)]

ottxor      13/02/05 05:44:25

  Modified:             metadata.xml ChangeLog
  Added:                openmm-4.1.1-r1.ebuild
  Removed:              openmm-4.1.1.ebuild
  Log:
  clean up install locations
  
  (Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key C2000586)

Revision  Changes    Path
1.2                  sci-libs/openmm/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/openmm/metadata.xml?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/openmm/metadata.xml?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/openmm/metadata.xml?r1=1.1&r2=1.2

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/openmm/metadata.xml,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- metadata.xml	30 Nov 2012 20:45:20 -0000	1.1
+++ metadata.xml	5 Feb 2013 05:44:25 -0000	1.2
@@ -9,5 +9,6 @@
 	<use>
 		<flag name="cuda">enable cuda back-end</flag>
 		<flag name="opencl">enable opencl back-end</flag>
+		<flag name="wrappers">build wrappers for C and Fortran</flag>
 	</use>
 </pkgmetadata>



1.5                  sci-libs/openmm/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/openmm/ChangeLog?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/openmm/ChangeLog?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/openmm/ChangeLog?r1=1.4&r2=1.5

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sci-libs/openmm/ChangeLog,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- ChangeLog	8 Jan 2013 19:22:39 -0000	1.4
+++ ChangeLog	5 Feb 2013 05:44:25 -0000	1.5
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/openmm
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/openmm/ChangeLog,v 1.4 2013/01/08 19:22:39 ottxor Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/openmm/ChangeLog,v 1.5 2013/02/05 05:44:25 ottxor Exp $
+
+*openmm-4.1.1-r1 (05 Feb 2013)
+
+  05 Feb 2013; Christoph Junghans <ottxor@gentoo.org> +openmm-4.1.1-r1.ebuild,
+  -openmm-4.1.1.ebuild, metadata.xml:
+  clean up install locations
 
   08 Jan 2013; Christoph Junghans <ottxor@gentoo.org> openmm-4.1.1.ebuild:
   removed fetch restriction as license allows redistribution



1.1                  sci-libs/openmm/openmm-4.1.1-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/openmm/openmm-4.1.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-libs/openmm/openmm-4.1.1-r1.ebuild?rev=1.1&content-type=text/plain

Index: openmm-4.1.1-r1.ebuild
===================================================================
# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-libs/openmm/openmm-4.1.1-r1.ebuild,v 1.1 2013/02/05 05:44:25 ottxor Exp $

EAPI="5"

PYTHON_DEPEND="2:2.6"

inherit cmake-utils cuda python

MY_P="${PN^^[om]}${PV}-Source"
DESCRIPTION="provides tools for modern molecular modeling simulation"
HOMEPAGE="https://simtk.org/home/openmm"
SRC_URI="mirror://gentoo/${MY_P}.zip"

LICENSE="MIT LGPL-2.1+ BSD RU-BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cuda doc examples opencl wrappers"

RDEPEND="
	cuda? ( >=dev-util/nvidia-cuda-toolkit-4.2.9-r1 )
	opencl? ( virtual/opencl )"
DEPEND="${RDEPEND}
	doc? ( app-doc/doxygen )
	wrappers? ( dev-cpp/gccxml virtual/jre )"

S="${WORKDIR}/${MY_P}"

pkg_setup() {
	python_set_active_version 2
}

src_prepare() {
	use cuda && cuda_src_prepare
	default
}

src_configure() {
	mycmakeargs=(
		$(cmake-utils_use cuda OPENMM_BUILD_CUDA_LIB)
		$(cmake-utils_use opencl OPENMM_BUILD_OPENCL_LIB)
		$(cmake-utils_use doc OPENMM_GENERATE_API_DOCS)
		$(cmake-utils_use wrappers OPENMM_BUILD_C_AND_FORTRAN_WRAPPERS)
		$(cmake-utils_use !cuda CUDA_BUILD_CUBIN)
		$(cmake-utils_use opencl OPENMM_BUILD_RPMD_PLUGIN)
		$(cmake-utils_use opencl OPENMM_BUILD_PYTHON_WRAPPERS)
	) # last 3 options are workarounds for broken build system

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use doc; then
		dodoc "${ED}"/usr/docs/*.pdf
		dohtml -r "${ED}"/usr/docs/*.html "${ED}"/usr/docs/api-*
	fi
	rm -f "${ED}"/usr/docs/*.pdf
	rm -rf "${ED}"/usr/docs/*.html "${ED}"/usr/docs/api-*
	rmdir "${ED}"/usr/docs || die

	if use examples; then
		insinto /usr/share/"${PN}"
		doins -r "${ED}"/usr/examples
	fi
	rm -rf "${ED}"/usr/examples

	rm -rf "${ED}"/usr/licenses
}