[gentoo-commits] gentoo-x86 commit in dev-python/docutils: docutils-0.10.ebuild ChangeLog

["Michal Gorny (mgorny)" <mgorny@gentoo.org>]

mgorny      12/12/31 12:16:18

  Modified:             ChangeLog
  Added:                docutils-0.10.ebuild
  Log:
  Version bump with a patch for buildhtml.py. Move GLEP support to dev-python/docutils-glep.
  
  (Portage version: 2.2.0_alpha149/cvs/Linux x86_64, signed Manifest commit with key 42B9401D)

Revision  Changes    Path
1.164                dev-python/docutils/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/docutils/ChangeLog?rev=1.164&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/docutils/ChangeLog?rev=1.164&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/docutils/ChangeLog?r1=1.163&r2=1.164

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/docutils/ChangeLog,v
retrieving revision 1.163
retrieving revision 1.164
diff -u -r1.163 -r1.164
--- ChangeLog	17 Dec 2012 19:56:00 -0000	1.163
+++ ChangeLog	31 Dec 2012 12:16:18 -0000	1.164
@@ -1,6 +1,13 @@
 # ChangeLog for dev-python/docutils
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/docutils/ChangeLog,v 1.163 2012/12/17 19:56:00 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/docutils/ChangeLog,v 1.164 2012/12/31 12:16:18 mgorny Exp $
+
+*docutils-0.10 (31 Dec 2012)
+
+  31 Dec 2012; Michał Górny <mgorny@gentoo.org> +docutils-0.10.ebuild,
+  +files/docutils-0.10-optparser.patch:
+  Version bump with a patch for buildhtml.py. Move GLEP support to dev-python
+  /docutils-glep.
 
   17 Dec 2012; Michał Górny <mgorny@gentoo.org> docutils-0.9.1-r1.ebuild:
   Bump to EAPI=5 to make Paludis happy, bug #447524.



1.1                  dev-python/docutils/docutils-0.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/docutils/docutils-0.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/docutils/docutils-0.10.ebuild?rev=1.1&content-type=text/plain

Index: docutils-0.10.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/docutils/docutils-0.10.ebuild,v 1.1 2012/12/31 12:16:18 mgorny Exp $

EAPI="5"
PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2} pypy{1_8,1_9} )

inherit distutils-r1

DESCRIPTION="Python Documentation Utilities"
HOMEPAGE="http://docutils.sourceforge.net/ http://pypi.python.org/pypi/docutils"
SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"

LICENSE="BSD-2 GPL-3 public-domain"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
IUSE="glep"

DEPEND="dev-python/pygments[${PYTHON_USEDEP}]"
RDEPEND="${DEPEND}
	dev-python/docutils-glep[${PYTHON_USEDEP}]"

PATCHES=(
	# fix buildhtml.py option parsing
	"${FILESDIR}"/${P}-optparser.patch
)

python_compile_all() {
	# Generate html docs from reStructured text sources.

	# Place html4css1.css in base directory to ensure that the generated reference to it is correct.
	cp docutils/writers/html4css1/html4css1.css . || die

	cd tools || die
	"${PYTHON}" buildhtml.py --input-encoding=utf-8 \
		--stylesheet-path=../html4css1.css, --traceback ../docs || die
}

python_test() {
	local tests=test
	[[ ${EPYTHON} == python3* ]] && tests=test3

	cp -r -l ${tests} "${BUILD_DIR}"/test || die
	ln -s "${S}"/docs "${BUILD_DIR}"/ || die
	"${PYTHON}" "${BUILD_DIR}"/test/alltests.py || die "Tests fail with ${EPYTHON}"
}

python_install() {
	distutils-r1_python_install

	# Install tools.
	python_doscript tools/{buildhtml,quicktest}.py
}

install_txt_doc() {
	local doc="${1}"
	local dir="txt/$(dirname ${doc})"
	docinto "${dir}"
	dodoc "${doc}"
}

python_install_all() {
	local DOCS=( *.txt )
	local HTML_DOCS=( docs tools docutils/writers/html4css1/html4css1.css )

	distutils-r1_python_install_all

	local doc
	while IFS= read -r -d '' doc; do
		install_txt_doc "${doc}"
	done < <(find docs tools -name '*.txt' -print0)
}