[gentoo-commits] gentoo-x86 commit in sci-mathematics/twelf: twelf-1.7.1.ebuild metadata.xml ChangeLog

[gentoo-commits] gentoo-x86 commit in sci-mathematics/twelf: twelf-1.7.1.ebuild metadata.xml ChangeLog

[Mark Wright (gienah)]

gienah      12/12/09 23:02:17

  Added:                twelf-1.7.1.ebuild metadata.xml ChangeLog
  Log:
  Add twelf, ebuild by me
  
  (Portage version: 2.1.11.34/cvs/Linux x86_64, signed Manifest commit with key 618E971F)

Revision  Changes    Path
1.1                  sci-mathematics/twelf/twelf-1.7.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/twelf/twelf-1.7.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/twelf/twelf-1.7.1.ebuild?rev=1.1&content-type=text/plain

Index: twelf-1.7.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/twelf/twelf-1.7.1.ebuild,v 1.1 2012/12/09 23:02:17 gienah Exp $

EAPI="5"

inherit base elisp-common multilib

MY_PN="${PN}-src"
MY_P="${MY_PN}-${PV}"

DESCRIPTION="Twelf is an implementation of the logical framework LF."
HOMEPAGE="http://twelf.org/"
SRC_URI="http://twelf.plparty.org/releases/${MY_P}.tar.gz"

SLOT="0"
KEYWORDS="~amd64 ~x86"
LICENSE="BSD-2"
IUSE="doc emacs examples"
# tests reference non-existing directory TEST
RESTRICT="test"

RDEPEND="dev-lang/mlton
	doc? (
		virtual/latex-base
	)
	emacs? (
		virtual/emacs
	)"
DEPEND="${RDEPEND}
	dev-util/omake"

S=${WORKDIR}/${PN}

SITEFILE=50${PN}-gentoo.el

PATCHES=("${FILESDIR}/${PN}-1.7.1-doc-guide-twelf-dot-texi.patch"
	"${FILESDIR}/${PN}-1.7.1-doc-guide-Makefile.patch"
	"${FILESDIR}/${PN}-1.7.1-emacs-twelf.patch"
	"${FILESDIR}/${PN}-1.7.1-emacs-twelf-init.patch"
	"${FILESDIR}/${PN}-1.7.1-Makefile.patch")

src_prepare() {
	base_src_prepare
	sed -e "s@/usr/bin@${ROOT}usr/bin@g" \
		-e "s@/usr/share@${ROOT}usr/share@" \
		-i "${S}"/emacs/twelf-init.el \
		|| die "Could not set ROOT in ${S}/emacs/twelf-init.el"
}

src_compile() {
	emake mlton CFLAGS="${CFLAGS}" LDFLAGS="${LDFLAGS}"
	if use emacs ; then
		pushd "${S}/emacs" || die "Could change directory to emacs"
		elisp-compile \
			auc-menu.el \
			twelf-font.el \
			twelf-init.el \
			twelf.el \
			|| die "emacs elisp compile failed"
		popd
	fi
	if use doc; then
		pushd doc/guide
		emake all
		popd
	fi
}

ins_example_dir() {
	dodir "/usr/share/${PN}/examples/${1}"
	insinto "/usr/share/${PN}/examples/${1}"
	pushd "${S}/${1}"
	doins -r *
	popd
}

src_install() {
	if use emacs ; then
		elisp-install ${PN} emacs/*.{el,elc}
		cp "${FILESDIR}"/${SITEFILE} "${S}"
		elisp-site-file-install ${SITEFILE}
	fi
	if use examples; then
		ins_example_dir examples
		ins_example_dir examples-clp
		ins_example_dir examples-delphin
	fi
	exeinto /usr/bin
	doexe bin/twelf-server
	dohtml doc/html/index.html
	doinfo doc/guide/twelf.info
	dodoc doc/guide/twelf.dvi doc/guide/twelf.ps doc/guide/twelf.pdf
	dohtml doc/guide/twelf/*
}

pkg_postinst() {
	if use emacs; then
		elisp-site-regen
		ewarn "For twelf emacs, add this line to ~/.emacs"
		ewarn ""
		ewarn '(load (concat twelf-root "/twelf-init.el"))'
	fi
}

pkg_postrm() {
	use emacs && elisp-site-regen
}



1.1                  sci-mathematics/twelf/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/twelf/metadata.xml?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/twelf/metadata.xml?rev=1.1&content-type=text/plain

Index: metadata.xml
===================================================================
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer>
  <email>gienah@gentoo.org></email>
</maintainer>
<longdescription lang='en'>
Twelf is an implementation of the logical framework LF. It is used for
logic programming and for the formalization of programming language
theory.
</longdescription>
</pkgmetadata>



1.1                  sci-mathematics/twelf/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/twelf/ChangeLog?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sci-mathematics/twelf/ChangeLog?rev=1.1&content-type=text/plain

Index: ChangeLog
===================================================================
# ChangeLog for sci-mathematics/twelf
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
# $Header: /var/cvsroot/gentoo-x86/sci-mathematics/twelf/ChangeLog,v 1.1 2012/12/09 23:02:17 gienah Exp $

*twelf-1.7.1 (09 Dec 2012)

  09 Dec 2012; Mark Wright <gienah@gentoo.org> +files/50twelf-gentoo.el,
  +files/twelf-1.7.1-Makefile.patch,
  +files/twelf-1.7.1-doc-guide-Makefile.patch,
  +files/twelf-1.7.1-doc-guide-twelf-dot-texi.patch,
  +files/twelf-1.7.1-emacs-twelf-init.patch,
  +files/twelf-1.7.1-emacs-twelf.patch, +metadata.xml, +twelf-1.7.1.ebuild:
  Add twelf, ebuild by me