[gentoo-commits] gentoo-x86 commit in net-misc/suite3270: suite3270-3.3.12_p10.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in net-misc/suite3270: suite3270-3.3.12_p10.ebuild ChangeLog

[Mike Frysinger (vapier)]

vapier      12/12/06 07:00:43

  Modified:             ChangeLog
  Added:                suite3270-3.3.12_p10.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha142/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

Revision  Changes    Path
1.42                 net-misc/suite3270/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/ChangeLog?rev=1.42&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/ChangeLog?rev=1.42&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/ChangeLog?r1=1.41&r2=1.42

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v
retrieving revision 1.41
retrieving revision 1.42
diff -u -r1.41 -r1.42
--- ChangeLog	16 Oct 2010 18:13:12 -0000	1.41
+++ ChangeLog	6 Dec 2012 07:00:43 -0000	1.42
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/suite3270
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v 1.41 2010/10/16 18:13:12 ranger Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/ChangeLog,v 1.42 2012/12/06 07:00:43 vapier Exp $
+
+*suite3270-3.3.12_p10 (06 Dec 2012)
+
+  06 Dec 2012; Mike Frysinger <vapier@gentoo.org> +suite3270-3.3.12_p10.ebuild:
+  Version bump.
 
   16 Oct 2010; Brent Baude <ranger@gentoo.org>
   suite3270-3.3.10_p3-r1.ebuild:
@@ -185,4 +190,3 @@
 
   27 Jul 2003; Robin H. Johnson <robbat2@gentoo.org> suite3270-3.2.20.ebuild:
   Initial Commit.
-



1.1                  net-misc/suite3270/suite3270-3.3.12_p10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/suite3270-3.3.12_p10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/suite3270/suite3270-3.3.12_p10.ebuild?rev=1.1&content-type=text/plain

Index: suite3270-3.3.12_p10.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/suite3270/suite3270-3.3.12_p10.ebuild,v 1.1 2012/12/06 07:00:43 vapier Exp $

EAPI="4"

MY_PV=${PV/_p/ga}
MY_P=${PN}-${MY_PV}
SUB_PV=${PV:0:3}

S=${WORKDIR}

# only the x3270 package installs fonts
FONT_PN="x3270"
FONT_S=${WORKDIR}/${FONT_PN}-${SUB_PV}

inherit eutils font multiprocessing

DESCRIPTION="Complete 3270 access package"
HOMEPAGE="http://x3270.bgp.nu/"
SRC_URI="mirror://sourceforge/x3270/${MY_P}-src.tgz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~s390 ~sparc ~x86"
IUSE="cjk doc ncurses ssl tcl X"

RDEPEND="ssl? ( dev-libs/openssl )
	X? (
		x11-libs/libX11
		x11-libs/libXaw
		x11-libs/libXmu
		x11-libs/libXt
	)
	ncurses? ( sys-libs/ncurses sys-libs/readline )
	tcl? ( dev-lang/tcl )"
DEPEND="${RDEPEND}
	X? (
		x11-misc/imake
		x11-misc/xbitmaps
		x11-proto/xproto
		app-text/rman
		x11-apps/mkfontdir
		x11-apps/bdftopcf
	)"

suite3270_makelist() {
	echo pr3287 s3270 \
		$(usex ncurses c3270 '') \
		$(usex tcl tcl3270 '') \
		$(usex X x3270 '')
}

src_configure() {
	local p myconf
	# Run configures in parallel!
	multijob_init
	for p in $(suite3270_makelist) ; do
		cd "${S}/${p}-${SUB_PV}"
		if [[ ${p} == "x3270" ]] ; then
			myconf=(
				$(use_with X x)
				$(use_with X fontdir "${FONTDIR}")
			)
		else
			myconf=()
		fi
		multijob_child_init econf \
			--cache-file="${S}"/config.cache \
			$(use_enable cjk dbcs) \
			$(use_enable ssl) \
			"${myconf[@]}"
	done
	multijob_finish
}

src_compile() {
	local p
	for p in $(suite3270_makelist) ; do
		emake -C "${S}/${p}-${SUB_PV}"
	done
}

src_install() {
	use X && dodir "${FONTDIR}"
	local p
	for p in $(suite3270_makelist) ; do
		cd "${S}/${p}-${SUB_PV}"
		emake DESTDIR="${D}" install install.man
		docinto ${p}
		local d=$(echo README*)
		[[ -n ${d} ]] && dodoc ${d}
		use doc && dohtml html/*
	done
	chmod a-x "${D}"/usr/share/man/*/*

	use X && font_src_install
}

pkg_postinst() { use X && font_pkg_postinst ; }
pkg_postrm() { use X && font_pkg_postrm ; }