[gentoo-commits] gentoo-x86 commit in app-text/poppler: poppler-0.20.4.ebuild ChangeLog

["Johannes Huber (johu)" <johu@gentoo.org>]

johu        12/09/17 14:24:38

  Modified:             ChangeLog
  Added:                poppler-0.20.4.ebuild
  Log:
  Version bump wrt bug #434960.
  
  (Portage version: 2.2.0_alpha128/cvs/Linux x86_64)

Revision  Changes    Path
1.333                app-text/poppler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?rev=1.333&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?rev=1.333&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?r1=1.332&r2=1.333

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v
retrieving revision 1.332
retrieving revision 1.333
diff -u -r1.332 -r1.333
--- ChangeLog	12 Aug 2012 23:28:56 -0000	1.332
+++ ChangeLog	17 Sep 2012 14:24:37 -0000	1.333
@@ -1,6 +1,11 @@
 # ChangeLog for app-text/poppler
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.332 2012/08/12 23:28:56 reavertm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.333 2012/09/17 14:24:37 johu Exp $
+
+*poppler-0.20.4 (17 Sep 2012)
+
+  17 Sep 2012; Johannes Huber <johu@gentoo.org> +poppler-0.20.4.ebuild:
+  Version bump wrt bug #434960.
 
 *poppler-0.20.3 (12 Aug 2012)
 



1.1                  app-text/poppler/poppler-0.20.4.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.20.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.20.4.ebuild?rev=1.1&content-type=text/plain

Index: poppler-0.20.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.20.4.ebuild,v 1.1 2012/09/17 14:24:37 johu Exp $

EAPI=4

inherit cmake-utils

DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
HOMEPAGE="http://poppler.freedesktop.org/"
SRC_URI="http://poppler.freedesktop.org/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
SLOT="0"
IUSE="cairo cjk curl cxx debug doc +introspection jpeg jpeg2k +lcms png qt4 tiff +utils"

# No test data provided
RESTRICT="test"

COMMON_DEPEND="
	>=media-libs/fontconfig-2.6.0
	>=media-libs/freetype-2.3.9
	sys-libs/zlib
	cairo? (
		dev-libs/glib:2
		>=x11-libs/cairo-1.10.0
		introspection? ( >=dev-libs/gobject-introspection-1.32.1 )
	)
	curl? ( net-misc/curl )
	jpeg? ( virtual/jpeg )
	jpeg2k? ( media-libs/openjpeg )
	lcms? ( media-libs/lcms:2 )
	png? ( >=media-libs/libpng-1.4:0 )
	qt4? (
		x11-libs/qt-core:4
		x11-libs/qt-gui:4
	)
	tiff? ( media-libs/tiff:0 )
"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
"
RDEPEND="${COMMON_DEPEND}
	!dev-libs/poppler
	!dev-libs/poppler-glib
	!dev-libs/poppler-qt3
	!dev-libs/poppler-qt4
	!app-text/poppler-utils
	cjk? ( >=app-text/poppler-data-0.4.4 )
"

PATCHES=(
	"${FILESDIR}/${PN}-0.20.1-lcms-automagic.patch"
)

DOCS=(AUTHORS ChangeLog NEWS README README-XPDF TODO)

src_configure() {
	mycmakeargs=(
		-DBUILD_GTK_TESTS=OFF
		-DBUILD_QT4_TESTS=OFF
		-DBUILD_CPP_TESTS=OFF
		-DENABLE_SPLASH=ON
		-DENABLE_ZLIB=ON
		-DENABLE_XPDF_HEADERS=ON
		$(cmake-utils_use_enable curl LIBCURL)
		$(cmake-utils_use_enable cxx CPP)
		$(cmake-utils_use_enable jpeg2k LIBOPENJPEG)
		$(cmake-utils_use_enable utils)
		$(cmake-utils_use_with cairo)
		$(cmake-utils_use_with introspection GObjectIntrospection)
		$(cmake-utils_use_with jpeg)
		$(cmake-utils_use_with png)
		$(cmake-utils_use_with qt4)
		$(cmake-utils_use_with tiff)
	)
	if use lcms; then
		mycmakeargs+=(-DENABLE_CMS=lcms2)
	else
		mycmakeargs+=(-DENABLE_CMS=)
	fi

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use cairo && use doc; then
		# For now install gtk-doc there
		insinto /usr/share/gtk-doc/html/poppler
		doins -r "${S}"/glib/reference/html/* || die 'failed to install API documentation'
	fi
}

pkg_postinst() {
	ewarn "After upgrading app-text/poppler you may need to reinstall packages"
	ewarn "linking to it. If you're not a portage-2.2_rc user, you're advised"
	ewarn "to run revdep-rebuild"
}