[gentoo-commits] gentoo-x86 commit in net-mail/fetchmail: fetchmail-6.3.22.ebuild ChangeLog

["Tim Harder (radhermit)" <radhermit@gentoo.org>]

radhermit    12/08/30 17:27:23

  Modified:             ChangeLog
  Added:                fetchmail-6.3.22.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha123/cvs/Linux x86_64)

Revision  Changes    Path
1.226                net-mail/fetchmail/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/fetchmail/ChangeLog?rev=1.226&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/fetchmail/ChangeLog?rev=1.226&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/fetchmail/ChangeLog?r1=1.225&r2=1.226

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-mail/fetchmail/ChangeLog,v
retrieving revision 1.225
retrieving revision 1.226
diff -u -r1.225 -r1.226
--- ChangeLog	16 Jun 2012 11:06:27 -0000	1.225
+++ ChangeLog	30 Aug 2012 17:27:23 -0000	1.226
@@ -1,6 +1,11 @@
 # ChangeLog for net-mail/fetchmail
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-mail/fetchmail/ChangeLog,v 1.225 2012/06/16 11:06:27 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-mail/fetchmail/ChangeLog,v 1.226 2012/08/30 17:27:23 radhermit Exp $
+
+*fetchmail-6.3.22 (30 Aug 2012)
+
+  30 Aug 2012; Tim Harder <radhermit@gentoo.org> +fetchmail-6.3.22.ebuild:
+  Version bump.
 
   16 Jun 2012; Fabian Groffen <grobian@gentoo.org> fetchmail-6.3.21.ebuild:
   Added Prefix keywords, fixed for Prefix



1.1                  net-mail/fetchmail/fetchmail-6.3.22.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/fetchmail/fetchmail-6.3.22.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-mail/fetchmail/fetchmail-6.3.22.ebuild?rev=1.1&content-type=text/plain

Index: fetchmail-6.3.22.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-mail/fetchmail/fetchmail-6.3.22.ebuild,v 1.1 2012/08/30 17:27:23 radhermit Exp $

EAPI=4

PYTHON_DEPEND="tk? 2"
PYTHON_USE_WITH_OPT="tk"
PYTHON_USE_WITH="tk"

inherit python user

DESCRIPTION="the legendary remote-mail retrieval and forwarding utility"
HOMEPAGE="http://fetchmail.berlios.de"
SRC_URI="mirror://berlios/${PN}/${P}.tar.bz2"

LICENSE="GPL-2 public-domain"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
IUSE="ssl nls kerberos hesiod tk socks"

RDEPEND="hesiod? ( net-dns/hesiod )
	ssl? ( >=dev-libs/openssl-0.9.6 )
	kerberos? ( virtual/krb5 >=dev-libs/openssl-0.9.6 )
	nls? ( virtual/libintl )
	!elibc_glibc? ( sys-libs/e2fsprogs-libs )
	socks? ( net-proxy/dante )"
DEPEND="${RDEPEND}
	sys-devel/flex
	nls? ( sys-devel/gettext )"

pkg_setup() {
	enewgroup ${PN}
	enewuser ${PN} -1 -1 /var/lib/${PN} ${PN}
	if use tk; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	# don't compile during src_install
	: > "${S}"/py-compile
}

src_configure() {
	if use tk ; then
		export PYTHON=$(PYTHON -a)
	else
		export PYTHON=:
	fi
	econf \
		--enable-RPA \
		--enable-NTLM \
		--enable-SDPS \
		$(use_enable nls) \
		$(use_with ssl ssl "${EPREFIX}/usr") \
		$(use kerberos && echo "--with-ssl=${EPREFIX}/usr") \
		$(use_with kerberos gssapi) \
		$(use_with kerberos kerberos5) \
		$(use_with hesiod) \
		$(use_with socks)
}

src_install() {
	# fetchmail's homedir (holds fetchmail's .fetchids)
	keepdir /var/lib/${PN}
	fowners ${PN}:${PN} /var/lib/${PN}
	fperms 700 /var/lib/${PN}

	emake DESTDIR="${D}" install

	dohtml *.html

	dodoc FAQ FEATURES NEWS NOTES README README.NTLM README.SSL* TODO

	newinitd "${FILESDIR}"/fetchmail.initd fetchmail
	newconfd "${FILESDIR}"/fetchmail.confd fetchmail

	docinto contrib
	local f
	for f in contrib/* ; do
		[ -f "${f}" ] && dodoc "${f}"
	done
}

pkg_postinst() {
	use tk && python_mod_optimize fetchmailconf.py

	elog "Please see /etc/conf.d/fetchmail if you want to adjust"
	elog "the polling delay used by the fetchmail init script."
}

pkg_postrm() {
	use tk && python_mod_cleanup fetchmailconf.py
}