[gentoo-commits] gentoo-x86 commit in dev-ruby/aws-sdk: aws-sdk-1.5.5.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-ruby/aws-sdk: aws-sdk-1.5.5.ebuild ChangeLog

[Diego Petteno (flameeyes)]

flameeyes    12/06/27 10:43:38

  Modified:             ChangeLog
  Added:                aws-sdk-1.5.5.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha113/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  dev-ruby/aws-sdk/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/aws-sdk/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/aws-sdk/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/aws-sdk/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-ruby/aws-sdk/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	15 Jun 2012 14:46:52 -0000	1.1
+++ ChangeLog	27 Jun 2012 10:43:37 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for dev-ruby/aws-sdk
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/aws-sdk/ChangeLog,v 1.1 2012/06/15 14:46:52 flameeyes Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/aws-sdk/ChangeLog,v 1.2 2012/06/27 10:43:37 flameeyes Exp $
+
+*aws-sdk-1.5.5 (27 Jun 2012)
+
+  27 Jun 2012; Diego E. Pettenò <flameeyes@gentoo.org> +aws-sdk-1.5.5.ebuild,
+  +files/aws-sdk.gemspec:
+  Version bump.
 
 *aws-sdk-1.5.3 (15 Jun 2012)
 
@@ -9,4 +15,3 @@
   +files/aws-sdk-1.5.3-disabletest.patch, +files/aws-sdk-1.5.3.gemspec,
   +metadata.xml:
   Initial import of Amazon's official SDK for Ruby.
-



1.1                  dev-ruby/aws-sdk/aws-sdk-1.5.5.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/aws-sdk/aws-sdk-1.5.5.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-ruby/aws-sdk/aws-sdk-1.5.5.ebuild?rev=1.1&content-type=text/plain

Index: aws-sdk-1.5.5.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-ruby/aws-sdk/aws-sdk-1.5.5.ebuild,v 1.1 2012/06/27 10:43:37 flameeyes Exp $

EAPI=4

USE_RUBY="ruby18 ruby19 ree18"

RUBY_FAKEGEM_TASK_TEST=""
RUBY_FAKEGEM_TASK_DOC=""
RUBY_FAKEGEM_DOCDIR="doc"
RUBY_FAKEGEM_EXTRADOC="README.rdoc"

RUBY_FAKEGEM_EXTRAINSTALL="ca-bundle.crt"

GITHUB_USER="amazonwebservices"
GITHUB_PROJECT="${PN}-for-ruby"
RUBY_S="${GITHUB_USER}-${GITHUB_PROJECT}-*"

RUBY_FAKEGEM_GEMSPEC="${T}/${P}.gemspec"

inherit ruby-fakegem

DESCRIPTION="Official SDK for Amazon Web Services"
HOMEPAGE="http://aws.amazon.com/sdkforruby"
SRC_URI="https://github.com/${GITHUB_USER}/${GITHUB_PROJECT}/tarball/${PV} -> ${GITHUB_PROJECT}-${PV}.tar.gz"

LICENSE="APSL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE=""

ruby_add_rdepend "virtual/ruby-ssl
	>=dev-ruby/httparty-0.7
	>=dev-ruby/json-1.4
	>=dev-ruby/nokogiri-1.4.4
	>=dev-ruby/uuidtools-2.1"
ruby_add_bdepend "
	test? ( dev-ruby/rspec )"

all_ruby_prepare() {
	rm Gemfile* || die

	epatch "${FILESDIR}"/${PN}-1.5.3-disabletest.patch
}

all_ruby_compile() {
	if use doc; then
		rdoc || die
	fi
}

each_ruby_test() {
	${RUBY} -S rspec -Ilib -raws || die
}

each_ruby_install() {
	sed -e "s:VERSION:${PV}:" "${FILESDIR}"/${PN}.gemspec > "${RUBY_FAKEGEM_GEMSPEC}"
	each_fakegem_install
}

all_ruby_install() {
	all_fakegem_install

	insinto /usr/share/doc/${PF}
	doins -r recipebook samples
}