* [gentoo-commits] gentoo-x86 commit in net-wireless/gnuradio: gnuradio-3.6.1-r1.ebuild ChangeLog
@ 2012-06-12 22:31 Chi-Thanh Christopher Nguyen (chithanh)
0 siblings, 0 replies; 2+ messages in thread
From: Chi-Thanh Christopher Nguyen (chithanh) @ 2012-06-12 22:31 UTC (permalink / raw
To: gentoo-commits
chithanh 12/06/12 22:31:38
Modified: ChangeLog
Added: gnuradio-3.6.1-r1.ebuild
Log:
Always enable gr-audio and make the individual output modules non-automagic.
(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)
Revision Changes Path
1.12 net-wireless/gnuradio/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?r1=1.11&r2=1.12
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- ChangeLog 11 Jun 2012 22:03:05 -0000 1.11
+++ ChangeLog 12 Jun 2012 22:31:38 -0000 1.12
@@ -1,6 +1,12 @@
# ChangeLog for net-wireless/gnuradio
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v 1.11 2012/06/11 22:03:05 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v 1.12 2012/06/12 22:31:38 chithanh Exp $
+
+*gnuradio-3.6.1-r1 (12 Jun 2012)
+
+ 12 Jun 2012; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+ +files/gnuradio-3.6.1-automagic-audio.patch, +gnuradio-3.6.1-r1.ebuild:
+ Always enable gr-audio and make the individual output modules non-automagic.
*gnuradio-3.6.1 (11 Jun 2012)
1.1 net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild?rev=1.1&content-type=text/plain
Index: gnuradio-3.6.1-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild,v 1.1 2012/06/12 22:31:38 chithanh Exp $
EAPI=4
PYTHON_DEPEND="2"
inherit base cmake-utils fdo-mime python
DESCRIPTION="Toolkit that provides signal processing blocks to implement software radios"
HOMEPAGE="http://gnuradio.org/"
SRC_URI="http://gnuradio.org/redmine/attachments/download/389/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa doc examples fcd grc jack oss portaudio qt4 sdl utils wavelet wxwidgets"
# bug #348206
# comedi? ( >=sci-electronics/comedilib-0.7 )
# uhd? ( dev-libs/uhd )
RDEPEND=">=dev-lang/orc-0.4.12
dev-libs/boost
dev-util/cppunit
sci-libs/fftw:3.0
fcd? ( virtual/libusb:1 )
alsa? (
media-libs/alsa-lib
)
grc? (
dev-python/cheetah
dev-python/lxml
dev-python/numpy
dev-python/pygtk:2
)
jack? (
media-sound/jack-audio-connection-kit
)
portaudio? (
>=media-libs/portaudio-19_pre
)
qt4? (
dev-python/PyQt4[X,opengl]
dev-python/pyqwt:5
x11-libs/qt-gui
)
sdl? ( media-libs/libsdl )
wavelet? (
sci-libs/gsl
)
wxwidgets? (
dev-python/wxpython:2.8
dev-python/numpy
)
"
DEPEND="${RDEPEND}
dev-lang/swig
virtual/pkgconfig
doc? (
>=app-doc/doxygen-1.5.7.1
dev-python/sphinx
)
grc? (
x11-misc/xdg-utils
)
oss? (
virtual/os-headers
)
"
# Add support for custom SYSCONFDIR, upstream bug #492
PATCHES=(
"${FILESDIR}"/${PN}-3.6.0-cmake-sysconfdir.patch
"${FILESDIR}"/${PN}-3.6.1-automagic-audio.patch
)
pkg_setup() {
python_set_active_version 2
python_pkg_setup
}
src_prepare() {
python_convert_shebangs -q -r 2 "${S}"
# Useless UI element would require qt3support, bug #365019
sed -i '/qPixmapFromMimeSource/d' "${S}"/gr-qtgui/lib/spectrumdisplayform.ui || die
base_src_prepare
}
src_configure() {
# TODO: docs are installed to /usr/share/doc/${PN} not /usr/share/doc/${PF}
# SYSCONFDIR/GR_PREFSDIR default to install below CMAKE_INSTALL_PREFIX
mycmakeargs=(
$(cmake-utils_use_enable alsa GR_AUDIO_ALSA)
$(cmake-utils_use_enable doc DOXYGEN) \
$(cmake-utils_use_enable doc SPHINX) \
$(cmake-utils_use_enable fcd GR_FCD) \
$(cmake-utils_use_enable grc GRC) \
$(cmake-utils_use_enable jack GR_AUDIO_JACK)
$(cmake-utils_use_enable oss GR_AUDIO_OSS)
$(cmake-utils_use_enable portaudio GR_AUDIO_PORTAUDIO)
$(cmake-utils_use_enable utils GR_UTILS) \
$(cmake-utils_use_enable wavelet GR_WAVELET) \
$(cmake-utils_use_enable wxwidgets GR_WXGUI) \
$(cmake-utils_use_enable qt4 GR_QTGUI) \
$(cmake-utils_use_enable sdl GR_VIDEO_SDL) \
-DENABLE_GR_CORE=ON
-DQWT_INCLUDE_DIRS="${EPREFIX}"/usr/include/qwt5
-DSYSCONFDIR="${EPREFIX}"/etc
)
cmake-utils_src_configure
}
src_install() {
cmake-utils_src_install
python_clean_installation_image -q
# Remove bad shebangs that creep back in during install
sed -i '\|#!/usr/bin/python|d' "${ED}"/usr/bin/* || die
# Install examples to /usr/share/doc/$PF
if use examples ; then
dodir /usr/share/doc/${PF}/
mv "${ED}"/usr/share/${PN}/examples "${ED}"/usr/share/doc/${PF}/ || die
else
# It seems that the examples are always installed
rm -rf "${ED}"/usr/share/${PN}/examples || die
fi
# We install the mimetypes to the correct locations from the ebuild
rm -rf "${ED}"/usr/share/${PN}/grc/freedesktop || die
rm -f "${ED}"/usr/libexec/${PN}/grc_setup_freedesktop || die
# Install icons, menu items and mime-types for GRC
if use grc ; then
local fd_path="${S}/grc/freedesktop"
insinto /usr/share/mime/packages
doins "${fd_path}/${PN}-grc.xml"
domenu "${fd_path}/"*.desktop
doicon "${fd_path}/"*.png
fi
}
pkg_postinst()
{
local GRC_ICON_SIZES="32 48 64 128 256"
python_mod_optimize gnuradio
if use grc ; then
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
for size in ${GRC_ICON_SIZES} ; do
xdg-icon-resource install --noupdate --context mimetypes --size ${size} \
"${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" application-gnuradio-grc \
|| die "icon resource installation failed"
xdg-icon-resource install --noupdate --context apps --size ${size} \
"${EROOT}/usr/share/pixmaps/grc-icon-${size}.png" gnuradio-grc \
|| die "icon resource installation failed"
done
xdg-icon-resource forceupdate
fi
}
pkg_postrm()
{
local GRC_ICON_SIZES="32 48 64 128 256"
python_mod_cleanup gnuradio
if use grc ; then
fdo-mime_desktop_database_update
fdo-mime_mime_database_update
for size in ${GRC_ICON_SIZES} ; do
xdg-icon-resource uninstall --noupdate --context mimetypes --size ${size} \
application-gnuradio-grc || ewarn "icon uninstall failed"
xdg-icon-resource uninstall --noupdate --context apps --size ${size} \
gnuradio-grc || ewarn "icon uninstall failed"
done
xdg-icon-resource forceupdate
fi
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in net-wireless/gnuradio: gnuradio-3.6.1-r1.ebuild ChangeLog
@ 2012-06-18 19:37 Chi-Thanh Christopher Nguyen (chithanh)
0 siblings, 0 replies; 2+ messages in thread
From: Chi-Thanh Christopher Nguyen (chithanh) @ 2012-06-18 19:37 UTC (permalink / raw
To: gentoo-commits
chithanh 12/06/18 19:37:01
Modified: gnuradio-3.6.1-r1.ebuild ChangeLog
Log:
Depend on cheetah unconditionally, bug #421823.
(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)
Revision Changes Path
1.2 net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild?r1=1.1&r2=1.2
Index: gnuradio-3.6.1-r1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- gnuradio-3.6.1-r1.ebuild 12 Jun 2012 22:31:38 -0000 1.1
+++ gnuradio-3.6.1-r1.ebuild 18 Jun 2012 19:37:01 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild,v 1.1 2012/06/12 22:31:38 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/gnuradio-3.6.1-r1.ebuild,v 1.2 2012/06/18 19:37:01 chithanh Exp $
EAPI=4
PYTHON_DEPEND="2"
@@ -21,6 +21,7 @@
# uhd? ( dev-libs/uhd )
RDEPEND=">=dev-lang/orc-0.4.12
dev-libs/boost
+ dev-python/cheetah
dev-util/cppunit
sci-libs/fftw:3.0
fcd? ( virtual/libusb:1 )
@@ -28,7 +29,6 @@
media-libs/alsa-lib
)
grc? (
- dev-python/cheetah
dev-python/lxml
dev-python/numpy
dev-python/pygtk:2
1.13 net-wireless/gnuradio/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?rev=1.13&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?rev=1.13&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-wireless/gnuradio/ChangeLog?r1=1.12&r2=1.13
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v
retrieving revision 1.12
retrieving revision 1.13
diff -u -r1.12 -r1.13
--- ChangeLog 12 Jun 2012 22:31:38 -0000 1.12
+++ ChangeLog 18 Jun 2012 19:37:01 -0000 1.13
@@ -1,6 +1,10 @@
# ChangeLog for net-wireless/gnuradio
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v 1.12 2012/06/12 22:31:38 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnuradio/ChangeLog,v 1.13 2012/06/18 19:37:01 chithanh Exp $
+
+ 18 Jun 2012; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+ gnuradio-3.6.1-r1.ebuild:
+ Depend on cheetah unconditionally, bug #421823.
*gnuradio-3.6.1-r1 (12 Jun 2012)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-06-18 19:37 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-06-18 19:37 [gentoo-commits] gentoo-x86 commit in net-wireless/gnuradio: gnuradio-3.6.1-r1.ebuild ChangeLog Chi-Thanh Christopher Nguyen (chithanh)
-- strict thread matches above, loose matches on Subject: below --
2012-06-12 22:31 Chi-Thanh Christopher Nguyen (chithanh)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox