[gentoo-commits] gentoo-x86 commit in app-text/poppler: ChangeLog poppler-0.20.1.ebuild poppler-0.20.0.ebuild poppler-0.18.4.ebuild

[gentoo-commits] gentoo-x86 commit in app-text/poppler: ChangeLog poppler-0.20.1.ebuild poppler-0.20.0.ebuild poppler-0.18.4.ebuild

[Tomas Chvatal (scarabeus)]

scarabeus    12/06/14 11:46:29

  Modified:             ChangeLog
  Added:                poppler-0.20.1.ebuild
  Removed:              poppler-0.20.0.ebuild poppler-0.18.4.ebuild
  Log:
  Bump to 0.20.1 wrt bug#420911.
  
  (Portage version: 2.2.0_alpha110/cvs/Linux x86_64, RepoMan options: --force)

Revision  Changes    Path
1.323                app-text/poppler/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?rev=1.323&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?rev=1.323&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/ChangeLog?r1=1.322&r2=1.323

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v
retrieving revision 1.322
retrieving revision 1.323
diff -u -r1.322 -r1.323
--- ChangeLog	13 Jun 2012 23:21:49 -0000	1.322
+++ ChangeLog	14 Jun 2012 11:46:29 -0000	1.323
@@ -1,6 +1,13 @@
 # ChangeLog for app-text/poppler
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.322 2012/06/13 23:21:49 reavertm Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/ChangeLog,v 1.323 2012/06/14 11:46:29 scarabeus Exp $
+
+*poppler-0.20.1 (14 Jun 2012)
+
+  14 Jun 2012; Tomáš Chvátal <scarabeus@gentoo.org> -poppler-0.18.4.ebuild,
+  -poppler-0.20.0.ebuild, -files/poppler-0.20.0-lcms-automagic.patch,
+  +poppler-0.20.1.ebuild, +files/poppler-0.20.1-lcms-automagic.patch:
+  Bump to 0.20.1 wrt bug#420911.
 
   13 Jun 2012; Maciej Mrozowski <reavertm@gentoo.org> -files/rpath.cmake,
   poppler-0.18.4-r1.ebuild:



1.1                  app-text/poppler/poppler-0.20.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.20.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-text/poppler/poppler-0.20.1.ebuild?rev=1.1&content-type=text/plain

Index: poppler-0.20.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-text/poppler/poppler-0.20.1.ebuild,v 1.1 2012/06/14 11:46:29 scarabeus Exp $

EAPI="4"

inherit cmake-utils

DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
HOMEPAGE="http://poppler.freedesktop.org/"
SRC_URI="http://poppler.freedesktop.org/${P}.tar.gz"

LICENSE="GPL-2"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
SLOT="0"
IUSE="cairo cjk curl cxx debug doc +introspection jpeg jpeg2k +lcms png qt4 tiff +utils +xpdf-headers"

# No test data provided
RESTRICT="test"

COMMON_DEPEND="
	>=media-libs/fontconfig-2.6.0
	>=media-libs/freetype-2.3.9
	sys-libs/zlib
	cairo? (
		dev-libs/glib:2
		>=x11-libs/cairo-1.10.0
		introspection? ( >=dev-libs/gobject-introspection-0.9.12 )
	)
	curl? ( net-misc/curl )
	jpeg? ( virtual/jpeg )
	jpeg2k? ( media-libs/openjpeg )
	lcms? ( media-libs/lcms:2 )
	png? ( >=media-libs/libpng-1.4:0 )
	qt4? (
		x11-libs/qt-core:4
		x11-libs/qt-gui:4
	)
	tiff? ( media-libs/tiff:0 )
"
DEPEND="${COMMON_DEPEND}
	virtual/pkgconfig
"
RDEPEND="${COMMON_DEPEND}
	!dev-libs/poppler
	!dev-libs/poppler-glib
	!dev-libs/poppler-qt3
	!dev-libs/poppler-qt4
	!app-text/poppler-utils
	cjk? ( >=app-text/poppler-data-0.4.4 )
"

DOCS=(AUTHORS ChangeLog NEWS README README-XPDF TODO)

PATCHES=(
	"${FILESDIR}/${PN}-0.20.1-lcms-automagic.patch"
)

src_configure() {
	mycmakeargs=(
		-DBUILD_GTK_TESTS=OFF
		-DBUILD_QT4_TESTS=OFF
		-DBUILD_CPP_TESTS=OFF
		-DENABLE_LCMS=OFF
		-DENABLE_SPLASH=ON
		-DENABLE_ZLIB=ON
		$(cmake-utils_use_enable curl LIBCURL)
		$(cmake-utils_use_enable cxx CPP)
		$(cmake-utils_use_enable jpeg2k LIBOPENJPEG)
		$(cmake-utils_use_enable lcms LCMS2)
		$(cmake-utils_use_enable utils)
		$(cmake-utils_use_enable xpdf-headers XPDF_HEADERS)
		$(cmake-utils_use_with cairo)
		$(cmake-utils_use_with introspection GObjectIntrospection)
		$(cmake-utils_use_with jpeg)
		$(cmake-utils_use_with png)
		$(cmake-utils_use_with qt4)
		$(cmake-utils_use_with tiff)
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install

	if use cairo && use doc; then
		# For now install gtk-doc there
		insinto /usr/share/gtk-doc/html/poppler
		doins -r "${S}"/glib/reference/html/* || die 'failed to install API documentation'
	fi
}

pkg_postinst() {
	ewarn "After upgrading app-text/poppler you may need to reinstall packages"
	ewarn "linking to it. If you're not a portage-2.2_rc user, you're advised"
	ewarn "to run revdep-rebuild"
}