[gentoo-commits] gentoo-x86 commit in media-gfx/graphite2: graphite2-1.1.3.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in media-gfx/graphite2: graphite2-1.1.3.ebuild ChangeLog

[Tomas Chvatal (scarabeus)]

scarabeus    12/06/14 08:32:51

  Modified:             ChangeLog
  Added:                graphite2-1.1.3.ebuild
  Log:
  Bumpy.
  
  (Portage version: 2.2.0_alpha110/cvs/Linux x86_64)

Revision  Changes    Path
1.30                 media-gfx/graphite2/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/ChangeLog?rev=1.30&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/ChangeLog?rev=1.30&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/ChangeLog?r1=1.29&r2=1.30

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-gfx/graphite2/ChangeLog,v
retrieving revision 1.29
retrieving revision 1.30
diff -u -r1.29 -r1.30
--- ChangeLog	23 May 2012 08:49:11 -0000	1.29
+++ ChangeLog	14 Jun 2012 08:32:51 -0000	1.30
@@ -1,6 +1,11 @@
 # ChangeLog for media-gfx/graphite2
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphite2/ChangeLog,v 1.29 2012/05/23 08:49:11 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphite2/ChangeLog,v 1.30 2012/06/14 08:32:51 scarabeus Exp $
+
+*graphite2-1.1.3 (14 Jun 2012)
+
+  14 Jun 2012; Tomáš Chvátal <scarabeus@gentoo.org> +graphite2-1.1.3.ebuild:
+  Bumpy.
 
   23 May 2012; Tomáš Chvátal <scarabeus@gentoo.org> -graphite2-1.1.1.ebuild,
   graphite2-1.1.2.ebuild:



1.1                  media-gfx/graphite2/graphite2-1.1.3.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/graphite2-1.1.3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-gfx/graphite2/graphite2-1.1.3.ebuild?rev=1.1&content-type=text/plain

Index: graphite2-1.1.3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/graphite2/graphite2-1.1.3.ebuild,v 1.1 2012/06/14 08:32:51 scarabeus Exp $

EAPI=4

PYTHON_DEPEND="test? 2"
inherit base cmake-utils perl-module python

DESCRIPTION="Library providing rendering capabilities for complex non-Roman writing systems"
HOMEPAGE="http://graphite.sil.org/"
SRC_URI="mirror://sourceforge/silgraphite/${PN}/${P}.tgz"

LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
IUSE="perl test"

RDEPEND="
	perl? ( dev-lang/perl )
"
DEPEND="${RDEPEND}
	perl? ( virtual/perl-Module-Build )
	test? (
		dev-libs/glib:2
		media-libs/fontconfig
		media-libs/silgraphite
	)
"

PATCHES=(
	"${FILESDIR}/${PN}-1.1.0-includes-libs-perl.patch"
	"${FILESDIR}/${PN}-fix_wrong_linker_opts.patch"
	"${FILESDIR}/${PN}-1.0.2-no_harfbuzz_tests.patch"
	"${FILESDIR}/${PN}-1.0.3-no-test-binaries.patch"
)

pkg_setup() {
	use perl && perl-module_pkg_setup
	if use test; then
		python_set_active_version 2
		python_pkg_setup
	fi
}

src_prepare() {
	base_src_prepare

	# fix perl linking
	if use perl; then
		_check_build_dir init
		sed -i \
			-e "s:@BUILD_DIR@:\"${CMAKE_BUILD_DIR}/src\":" \
			contrib/perl/Build.PL || die
	fi

	# make tests optional
	if ! use test; then
		sed -i \
			-e '/tests/d' \
			CMakeLists.txt || die
	fi
}

src_configure() {
	local mycmakeargs=(
		"-DVM_MACHINE_TYPE=direct"
	)

	cmake-utils_src_configure
}

src_compile() {
	cmake-utils_src_compile
	if use perl; then
		cd contrib/perl
		perl-module_src_prep
		perl-module_src_compile
	fi
}

src_test() {
	cmake-utils_src_test
	if use perl; then
		cd contrib/perl
		perl-module_src_test
	fi
}

src_install() {
	cmake-utils_src_install
	if use perl; then
		cd contrib/perl
		perl-module_src_install
		fixlocalpod
	fi

	find "${ED}" -name '*.la' -exec rm -f {} +

}