* [gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: ChangeLog e2fsprogs-libs-1.42.4.ebuild
@ 2012-06-14 0:59 Mike Frysinger (vapier)
0 siblings, 0 replies; only message in thread
From: Mike Frysinger (vapier) @ 2012-06-14 0:59 UTC (permalink / raw
To: gentoo-commits
vapier 12/06/14 00:59:04
Modified: ChangeLog
Added: e2fsprogs-libs-1.42.4.ebuild
Log:
Version bump #420925 by Sergei Trofimovich.
(Portage version: 2.2.0_alpha110/cvs/Linux x86_64)
Revision Changes Path
1.89 sys-libs/e2fsprogs-libs/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.89&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?rev=1.89&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog?r1=1.88&r2=1.89
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v
retrieving revision 1.88
retrieving revision 1.89
diff -u -r1.88 -r1.89
--- ChangeLog 11 Jun 2012 19:40:39 -0000 1.88
+++ ChangeLog 14 Jun 2012 00:59:04 -0000 1.89
@@ -1,6 +1,6 @@
-# ChangeLog for sys-libs/e2fsprogs-libs
+# ChangeLog for sys-fs/e2fsprogs
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.88 2012/06/11 19:40:39 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/ChangeLog,v 1.89 2012/06/14 00:59:04 vapier Exp $
11 Jun 2012; Mike Frysinger <vapier@gentoo.org> e2fsprogs-libs-1.41.7.ebuild:
Inherit multilib for get_libdir.
1.1 sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42.4.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42.4.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42.4.ebuild?rev=1.1&content-type=text/plain
Index: e2fsprogs-libs-1.42.4.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/e2fsprogs-libs/e2fsprogs-libs-1.42.4.ebuild,v 1.1 2012/06/14 00:59:04 vapier Exp $
EAPI="2"
case ${PV} in
*_pre*) UP_PV="${PV%_pre*}-WIP-${PV#*_pre}" ;;
*) UP_PV=${PV} ;;
esac
inherit toolchain-funcs
DESCRIPTION="e2fsprogs libraries (common error and subsystem)"
HOMEPAGE="http://e2fsprogs.sourceforge.net/"
SRC_URI="mirror://sourceforge/e2fsprogs/${PN}-${UP_PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd"
IUSE="nls static-libs"
RDEPEND="!sys-libs/com_err
!sys-libs/ss
!<sys-fs/e2fsprogs-1.41.8"
DEPEND="nls? ( sys-devel/gettext )
virtual/pkgconfig"
S=${WORKDIR}/${P%_pre*}
src_prepare() {
printf 'all:\n%%:;@:\n' > doc/Makefile.in # don't bother with docs #305613
}
src_configure() {
# We want to use the "bsd" libraries while building on Darwin, but while
# building on other Gentoo/*BSD we prefer elf-naming scheme.
local libtype
case ${CHOST} in
*-darwin*) libtype=bsd;;
*) libtype=elf;;
esac
# we use blkid/uuid from util-linux now
ac_cv_lib_uuid_uuid_generate=yes \
ac_cv_lib_blkid_blkid_get_cache=yes \
ac_cv_path_LDCONFIG=: \
QUOTA_CMT='#' \
econf \
--disable-lib{blkid,uuid} \
--disable-quota \
--enable-${libtype}-shlibs \
$(tc-has-tls || echo --disable-tls) \
$(use_enable nls)
}
src_install() {
emake STRIP=: DESTDIR="${D}" install || die
gen_usr_ldscript -a com_err ss
# configure doesn't have an option to disable static libs :/
use static-libs || find "${D}" -name '*.a' -delete
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-06-14 0:59 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-06-14 0:59 [gentoo-commits] gentoo-x86 commit in sys-libs/e2fsprogs-libs: ChangeLog e2fsprogs-libs-1.42.4.ebuild Mike Frysinger (vapier)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox