[gentoo-commits] gentoo-x86 commit in net-misc/tor: ChangeLog tor-0.2.2.37.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/tor: ChangeLog tor-0.2.2.37.ebuild

[Anthony G. Basile (blueness)]

blueness    12/06/13 15:00:27

  Modified:             ChangeLog
  Added:                tor-0.2.2.37.ebuild
  Log:
  Version bump
  
  (Portage version: 2.1.10.49/cvs/Linux x86_64)

Revision  Changes    Path
1.334                net-misc/tor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.334&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.334&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?r1=1.333&r2=1.334

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v
retrieving revision 1.333
retrieving revision 1.334
diff -u -r1.333 -r1.334
--- ChangeLog	6 Jun 2012 19:01:33 -0000	1.333
+++ ChangeLog	13 Jun 2012 15:00:27 -0000	1.334
@@ -1,6 +1,11 @@
 # ChangeLog for net-misc/tor
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.333 2012/06/06 19:01:33 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.334 2012/06/13 15:00:27 blueness Exp $
+
+*tor-0.2.2.37 (13 Jun 2012)
+
+  13 Jun 2012; Anthony G. Basile <blueness@gentoo.org> +tor-0.2.2.37.ebuild:
+  Version bump
 
 *tor-0.2.3.16_alpha (06 Jun 2012)
 



1.1                  net-misc/tor/tor-0.2.2.37.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.2.37.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.2.37.ebuild?rev=1.1&content-type=text/plain

Index: tor-0.2.2.37.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/tor-0.2.2.37.ebuild,v 1.1 2012/06/13 15:00:27 blueness Exp $

EAPI="4"

inherit autotools eutils flag-o-matic

DESCRIPTION="Anonymizing overlay network for TCP"
HOMEPAGE="http://www.torproject.org/"
SRC_URI="https://archive.torproject.org/tor-package-archive/${PN}-${PV}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="tor-hardening +transparent-proxy threads selinux"

DEPEND="dev-libs/openssl
	>=dev-libs/libevent-2.0
	selinux? ( sec-policy/selinux-tor )"
RDEPEND="${DEPEND}"

pkg_setup() {
	enewgroup tor
	enewuser tor -1 -1 /var/lib/tor tor
}

src_prepare() {
	epatch "${FILESDIR}"/torrc.sample.patch

	einfo "Regenerating autotools files ..."
	epatch "${FILESDIR}"/${PN}-0.2.2.24_alpha-respect-CFLAGS.patch
	eautoreconf
}

src_configure() {
	# Upstream isn't sure of all the user provided CFLAGS that
	# will break tor, but does recommend against -fstrict-aliasing.
	# We'll filter-flags them here as we encounter them.
	filter-flags -fstrict-aliasing
	econf \
		--enable-asciidoc \
		--docdir=/usr/share/doc/${PF} \
		$(use_enable tor-hardening gcc-hardening)	\
		$(use_enable tor-hardening linker-hardening)\
		$(use_enable transparent-proxy transparent)	\
		$(use_enable threads)
}

src_install() {
	newconfd "${FILESDIR}"/tor.confd tor
	newinitd "${FILESDIR}"/tor.initd-r6 tor
	emake DESTDIR="${D}" install
	keepdir /var/lib/tor

	dodoc README ChangeLog ReleaseNotes \
		doc/{HACKING,TODO} \
		doc/spec/README

	fperms 750 /var/lib/tor
	fowners tor:tor /var/lib/tor

	insinto /etc/tor/
	newins "${FILESDIR}"/torrc-r1 torrc
}

pkg_postinst() {
	elog
	elog "We created a configuration file for tor, /etc/tor/torrc, but you can"
	elog "change it according to your needs.  Use the torrc.sample that is in"
	elog "that directory as a guide.  Also, to have privoxy work with tor"
	elog "just add the following line"
	elog
	elog "forward-socks4a / localhost:9050 ."
	elog
	elog "to /etc/privoxy/config.  Notice the . at the end!"
	elog
}