[gentoo-commits] gentoo-x86 commit in sys-devel/bison: ChangeLog bison-2.5.1.ebuild

[gentoo-commits] gentoo-x86 commit in sys-devel/bison: ChangeLog bison-2.5.1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/06/06 14:34:23

  Modified:             ChangeLog
  Added:                bison-2.5.1.ebuild
  Log:
  Version bump.
  
  (Portage version: 2.2.0_alpha109/cvs/Linux x86_64)

Revision  Changes    Path
1.111                sys-devel/bison/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/bison/ChangeLog?rev=1.111&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/bison/ChangeLog?rev=1.111&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/bison/ChangeLog?r1=1.110&r2=1.111

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-devel/bison/ChangeLog,v
retrieving revision 1.110
retrieving revision 1.111
diff -u -r1.110 -r1.111
--- ChangeLog	24 May 2012 02:40:38 -0000	1.110
+++ ChangeLog	6 Jun 2012 14:34:23 -0000	1.111
@@ -1,6 +1,11 @@
 # ChangeLog for sys-devel/bison
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-devel/bison/ChangeLog,v 1.110 2012/05/24 02:40:38 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-devel/bison/ChangeLog,v 1.111 2012/06/06 14:34:23 ssuominen Exp $
+
+*bison-2.5.1 (06 Jun 2012)
+
+  06 Jun 2012; Samuli Suominen <ssuominen@gentoo.org> +bison-2.5.1.ebuild:
+  Version bump.
 
   24 May 2012; Mike Frysinger <vapier@gentoo.org> bison-2.4.2.ebuild,
   bison-2.5.ebuild:



1.1                  sys-devel/bison/bison-2.5.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/bison/bison-2.5.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-devel/bison/bison-2.5.1.ebuild?rev=1.1&content-type=text/plain

Index: bison-2.5.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-devel/bison/bison-2.5.1.ebuild,v 1.1 2012/06/06 14:34:23 ssuominen Exp $

EAPI=4

inherit flag-o-matic

DESCRIPTION="A general-purpose (yacc-compatible) parser generator"
HOMEPAGE="http://www.gnu.org/software/bison/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd"
IUSE="nls static"

RDEPEND=">=sys-devel/m4-1.4.16"
DEPEND="${RDEPEND}
	sys-devel/flex
	nls? ( sys-devel/gettext )"

DOCS="AUTHORS ChangeLog-2012 NEWS README THANKS TODO" # ChangeLog-1998 PACKAGING README-alpha README-release

src_configure() {
	use static && append-ldflags -static

	econf \
		--disable-silent-rules \
		$(use_enable nls)
}

src_install() {
	default

	# This one is installed by dev-util/yacc
	mv -v "${ED}"/usr/bin/yacc{,.bison} || die
	mv -v "${ED}"/usr/share/man/man1/yacc{,.bison}.1 || die

	# We do not need liby.a
	rm -r "${ED}"/usr/lib* || die

	# Move to documentation directory and leave compressing for EAPI>=4
	mv -v "${ED}"/usr/share/${PN}/README "${ED}"/usr/share/doc/${PF}/README.data
}

pkg_postinst() {
	local f="${EROOT}/usr/bin/yacc"
	if [[ ! -e ${f} ]]; then
		ln -s yacc.bison "${f}"
	fi
}

pkg_postrm() {
	# clean up the dead symlink when we get unmerged #377469
	local f="${EROOT}/usr/bin/yacc"
	if [[ -L ${f} && ! -e ${f} ]]; then
		rm -f "${f}"
	fi
}