[gentoo-commits] gentoo-x86 commit in dev-vcs/rabbitvcs: rabbitvcs-0.15.0.5-r2.ebuild ChangeLog rabbitvcs-0.15.0.5.ebuild rabbitvcs-0.14.2.1.ebuild

[gentoo-commits] gentoo-x86 commit in dev-vcs/rabbitvcs: rabbitvcs-0.15.0.5-r2.ebuild ChangeLog rabbitvcs-0.15.0.5.ebuild rabbitvcs-0.14.2.1.ebuild

[Michael Weber (xmw)]

xmw         12/06/04 20:24:23

  Modified:             ChangeLog
  Added:                rabbitvcs-0.15.0.5-r2.ebuild
  Removed:              rabbitvcs-0.15.0.5.ebuild rabbitvcs-0.14.2.1.ebuild
  Log:
  Revbump to include gedit3 patch (thanks pacho, bug 419647)
  
  (Portage version: 2.1.10.63/cvs/Linux x86_64)

Revision  Changes    Path
1.9                  dev-vcs/rabbitvcs/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/rabbitvcs/ChangeLog?rev=1.9&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/rabbitvcs/ChangeLog?rev=1.9&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/rabbitvcs/ChangeLog?r1=1.8&r2=1.9

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/rabbitvcs/ChangeLog,v
retrieving revision 1.8
retrieving revision 1.9
diff -u -r1.8 -r1.9
--- ChangeLog	7 Mar 2012 23:11:43 -0000	1.8
+++ ChangeLog	4 Jun 2012 20:24:23 -0000	1.9
@@ -1,6 +1,13 @@
 # ChangeLog for dev-vcs/rabbitvcs
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/rabbitvcs/ChangeLog,v 1.8 2012/03/07 23:11:43 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/rabbitvcs/ChangeLog,v 1.9 2012/06/04 20:24:23 xmw Exp $
+
+*rabbitvcs-0.15.0.5-r2 (04 Jun 2012)
+
+  04 Jun 2012; Michael Weber <xmw@gentoo.org> +files/50_fix_gedit3_plugin.patch,
+  +rabbitvcs-0.15.0.5-r2.ebuild, -rabbitvcs-0.14.2.1.ebuild,
+  -rabbitvcs-0.15.0.5.ebuild:
+  Revbump to include gedit3 patch (thanks pacho, bug 419647)
 
 *rabbitvcs-0.15.0.5-r1 (07 Mar 2012)
 



1.1                  dev-vcs/rabbitvcs/rabbitvcs-0.15.0.5-r2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/rabbitvcs/rabbitvcs-0.15.0.5-r2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/rabbitvcs/rabbitvcs-0.15.0.5-r2.ebuild?rev=1.1&content-type=text/plain

Index: rabbitvcs-0.15.0.5-r2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/rabbitvcs/rabbitvcs-0.15.0.5-r2.ebuild,v 1.1 2012/06/04 20:24:23 xmw Exp $

EAPI=4

PYTHON_DEPEND="2:2.5"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="2.4 3.*"

inherit eutils gnome2-utils multilib distutils

DESCRIPTION="Integrated version control support for your desktop"
HOMEPAGE="http://rabbitvcs.org"
SRC_URI="http://rabbitvcs.googlecode.com/files/${P}.tar.bz2"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="cli diff gedit git nautilus spell thunar"

RDEPEND="dev-python/configobj
	dev-python/pygobject:2
	dev-python/pygtk
	dev-python/pysvn
	dev-python/simplejson
	diff? ( dev-util/meld )
	gedit? ( app-editors/gedit )
	git? ( dev-python/dulwich )
	nautilus? ( >=dev-python/nautilus-python-0.7.0
		dev-python/dbus-python
		dev-python/gnome-vfs-python )
	spell? ( dev-python/gtkspell-python )
	thunar? ( dev-python/thunarx-python
		dev-python/dbus-python )"

src_prepare() {
	python_convert_shebangs -r 2 .

	distutils_src_prepare

	# we should not do gtk-update-icon-cache from setup script
	# we prefer portage for that
	sed -e 's/"install"/"fakeinstall"/' -i "${S}/setup.py" || die

	epatch "${FILESDIR}"/50_fix_gedit3_plugin.patch #bug 419647
}

src_install() {
	distutils_src_install

	if use cli ; then
		dobin clients/cli/${PN}
	fi
	if use gedit ; then
		insinto /usr/$(get_libdir)/gedit-2/plugins
		doins clients/gedit/${PN}-plugin.py
		doins clients/gedit/${PN}-gedit2.gedit-plugin
		insinto /usr/$(get_libdir)/gedit/plugins
		doins clients/gedit/${PN}-plugin.py
		doins clients/gedit/${PN}-gedit3.plugin
	fi
	if use nautilus ; then
		insinto /usr/$(get_libdir)/nautilus/extensions-2.0/python
		doins clients/nautilus/RabbitVCS.py
		insinto /usr/share/nautilus-python/extensions
		doins clients/nautilus-3.0/RabbitVCS.py
	fi
	if use thunar ; then
		insinto "/usr/$(get_libdir)/thunarx-2/python"
		doins clients/thunar/RabbitVCS.py
		insinto "/usr/$(get_libdir)/thunarx-1/python"
		doins clients/thunar/RabbitVCS.py
	fi
}

pkg_preinst() {
	gnome2_icon_savelist
}

pkg_postinst() {
	distutils_pkg_postinst
	gnome2_icon_cache_update

	elog "You should restart file manager to changes take effect:"
	use nautilus && elog "\$ nautilus -q"
	use thunar && elog "\$ thunar -q && thunar &"
	elog ""
	elog "Also you should really look at known issues page:"
	elog "http://wiki.rabbitvcs.org/wiki/support/known-issues"
}

pkg_postrm() {
	distutils_pkg_postrm
	gnome2_icon_cache_update
}