[gentoo-commits] gentoo-x86 commit in media-sound/moc: ChangeLog moc-2.5.0_alpha4_p20120501-r1.ebuild

[gentoo-commits] gentoo-x86 commit in media-sound/moc: ChangeLog moc-2.5.0_alpha4_p20120501-r1.ebuild

[Samuli Suominen (ssuominen)]

ssuominen    12/05/21 04:40:04

  Modified:             ChangeLog
  Added:                moc-2.5.0_alpha4_p20120501-r1.ebuild
  Log:
  Search for libresid-builder.so instead of libresid-builder.la during ./configure wrt #416619 by Stefan Borschtel
  
  (Portage version: 2.2.0_alpha107/cvs/Linux x86_64)

Revision  Changes    Path
1.100                media-sound/moc/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/moc/ChangeLog?rev=1.100&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/moc/ChangeLog?rev=1.100&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/moc/ChangeLog?r1=1.99&r2=1.100

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v
retrieving revision 1.99
retrieving revision 1.100
diff -u -r1.99 -r1.100
--- ChangeLog	5 May 2012 08:39:33 -0000	1.99
+++ ChangeLog	21 May 2012 04:40:03 -0000	1.100
@@ -1,6 +1,14 @@
 # ChangeLog for media-sound/moc
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v 1.99 2012/05/05 08:39:33 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/ChangeLog,v 1.100 2012/05/21 04:40:03 ssuominen Exp $
+
+*moc-2.5.0_alpha4_p20120501-r1 (21 May 2012)
+
+  21 May 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +moc-2.5.0_alpha4_p20120501-r1.ebuild,
+  +files/moc-libresid-builder.so_not_la.patch:
+  Search for libresid-builder.so instead of libresid-builder.la during
+  ./configure wrt #416619 by Stefan Borschtel
 
   05 May 2012; Michał Górny <mgorny@gentoo.org>
   moc-2.5.0_alpha4_p20111211.ebuild, moc-2.5.0_alpha4_p20120501.ebuild:



1.1                  media-sound/moc/moc-2.5.0_alpha4_p20120501-r1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/moc/moc-2.5.0_alpha4_p20120501-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-sound/moc/moc-2.5.0_alpha4_p20120501-r1.ebuild?rev=1.1&content-type=text/plain

Index: moc-2.5.0_alpha4_p20120501-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-sound/moc/moc-2.5.0_alpha4_p20120501-r1.ebuild,v 1.1 2012/05/21 04:40:03 ssuominen Exp $

EAPI=4
inherit autotools eutils

DESCRIPTION="Music On Console - ncurses interface for playing audio files"
HOMEPAGE="http://moc.daper.net"
SRC_URI="http://dev.gentoo.org/~radhermit/distfiles/${P}.tar.xz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~ppc ~ppc64 ~sparc ~x86"
IUSE="aac alsa curl debug ffmpeg flac jack libsamplerate mad modplug musepack
oss sid sndfile speex timidity +unicode vorbis wavpack"

# libltdl from libtool is used at runtime
RDEPEND=">=sys-devel/libtool-2.2.6b
	>=sys-libs/db-4
	sys-libs/ncurses[unicode?]
	aac? ( media-libs/faad2 )
	alsa? ( media-libs/alsa-lib )
	curl? ( net-misc/curl )
	ffmpeg? ( virtual/ffmpeg )
	flac? ( media-libs/flac )
	jack? ( media-sound/jack-audio-connection-kit )
	libsamplerate? ( media-libs/libsamplerate )
	mad? ( media-libs/libmad sys-libs/zlib media-libs/libid3tag )
	modplug? ( media-libs/libmodplug )
	musepack? ( media-sound/musepack-tools media-libs/taglib )
	sid? ( >=media-libs/libsidplay-2 )
	sndfile? ( media-libs/libsndfile )
	speex? ( media-libs/speex )
	timidity? ( media-libs/libtimidity media-sound/timidity++ )
	vorbis? ( media-libs/libogg media-libs/libvorbis )
	wavpack? ( media-sound/wavpack )"
DEPEND="${RDEPEND}
	app-arch/xz-utils
	virtual/pkgconfig"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-libresid-builder.so_not_la.patch #416619
	eautoreconf
}

src_configure() {
	local myconf=(
		--docdir="${EPREFIX}"/usr/share/doc/${PF}
		$(use_enable debug)
		$(use_with oss)
		$(use_with alsa)
		$(use_with jack)
		$(use_with unicode ncursesw)
		$(use_with libsamplerate samplerate)
		$(use_with aac)
		$(use_with ffmpeg)
		$(use_with flac)
		$(use_with modplug)
		$(use_with mad mp3)
		--without-rcc
		$(use_with musepack)
		$(use_with sid sidplay2)
		$(use_with sndfile)
		$(use_with speex)
		$(use_with timidity)
		$(use_with vorbis)
		$(use_with wavpack)
		$(use_with curl)
		)

	econf "${myconf[@]}"
}

src_install() {
	emake DESTDIR="${D}" install
	dodoc AUTHORS NEWS TODO # The rest is installed by doc_DATA from "${S}"/Makefile.am
	find "${ED}" -name '*.la' -exec sed -i -e "/^dependency_libs/s:=.*:='':" {} +
}