[gentoo-commits] gentoo-x86 commit in dev-vcs/gitolite: metadata.xml ChangeLog gitolite-3.02.ebuild

[gentoo-commits] gentoo-x86 commit in dev-vcs/gitolite: metadata.xml ChangeLog gitolite-3.02.ebuild

[Christian Ruppert (idl0r)]

idl0r       12/05/20 15:57:42

  Modified:             metadata.xml ChangeLog
  Added:                gitolite-3.02.ebuild
  Log:
  Version bump to 3.x, bug 413335
  
  (Portage version: 2.2.0_alpha107/cvs/Linux x86_64)

Revision  Changes    Path
1.5                  dev-vcs/gitolite/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite/metadata.xml?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite/metadata.xml?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite/metadata.xml?r1=1.4&r2=1.5

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/gitolite/metadata.xml,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- metadata.xml	24 Sep 2011 09:00:07 -0000	1.4
+++ metadata.xml	20 May 2012 15:57:42 -0000	1.5
@@ -16,6 +16,8 @@
 	</longdescription>
 	<use>
 		<flag name="contrib">Install user-contributed files</flag>
+		<flag name="tools">Install tools to e.g. convert a Gitosis config to
+			gitolite or one to check if your setup is gitolite >= 3.x compatible</flag>
 	</use>
 </pkgmetadata>
 



1.17                 dev-vcs/gitolite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite/ChangeLog?rev=1.17&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite/ChangeLog?rev=1.17&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite/ChangeLog?r1=1.16&r2=1.17

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-vcs/gitolite/ChangeLog,v
retrieving revision 1.16
retrieving revision 1.17
diff -u -r1.16 -r1.17
--- ChangeLog	19 May 2012 15:14:44 -0000	1.16
+++ ChangeLog	20 May 2012 15:57:42 -0000	1.17
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/gitolite
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite/ChangeLog,v 1.16 2012/05/19 15:14:44 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite/ChangeLog,v 1.17 2012/05/20 15:57:42 idl0r Exp $
+
+*gitolite-3.02 (20 May 2012)
+
+  20 May 2012; Christian Ruppert <idl0r@gentoo.org> +gitolite-3.02.ebuild,
+  metadata.xml:
+  Version bump to 3.x, bug 413335
 
   19 May 2012; Agostino Sarubbo <ago@gentoo.org> gitolite-2.3.ebuild:
   Stable for amd64, wrt bug #416569



1.1                  dev-vcs/gitolite/gitolite-3.02.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite/gitolite-3.02.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-vcs/gitolite/gitolite-3.02.ebuild?rev=1.1&content-type=text/plain

Index: gitolite-3.02.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-vcs/gitolite/gitolite-3.02.ebuild,v 1.1 2012/05/20 15:57:42 idl0r Exp $

EAPI=4

inherit eutils perl-module

DESCRIPTION="Highly flexible server for git directory version tracker"
HOMEPAGE="http://github.com/sitaramc/gitolite"
SRC_URI="http://milki.github.com/${PN}/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc tools vim-syntax"

DEPEND="dev-lang/perl
	virtual/perl-File-Path
	virtual/perl-File-Temp
	>=dev-vcs/git-1.6.6"
RDEPEND="${DEPEND}
	!dev-vcs/gitolite-gentoo
	vim-syntax? ( app-vim/gitolite-syntax )"

pkg_setup() {
	enewgroup git
	enewuser git -1 /bin/sh /var/lib/gitolite git
}

src_prepare() {
	echo $PF > src/VERSION
}

src_install() {
	local uexec=/usr/libexec/${PN}

	rm -rf src/lib/Gitolite/Test{,.pm}
	insinto $VENDOR_LIB
	doins -r src/lib/Gitolite

	dodoc README.mkd doc/CHANGELOG

	insopts -m0755
	insinto $uexec
	doins -r src/{commands,syntactic-sugar,triggers,VREF}/

	insopts -m0644
	doins src/VERSION

	exeinto $uexec
	doexe src/gitolite{,-shell}

	dodir /usr/bin
	for bin in gitolite{,-shell}; do
		dosym /usr/libexec/${PN}/${bin} /usr/bin/${bin}
	done

	if use doc; then
		dodoc doc/*.mkd

		docinto extras
		dodoc doc/extras/*.mkd
	fi

	if use tools; then
		dobin check-g2-compat convert-gitosis-conf
	fi

	keepdir /var/lib/gitolite
	fowners git:git /var/lib/gitolite
	fperms 750 /var/lib/gitolite

	fperms 0644 ${uexec}/VREF/MERGE-CHECK # It's meant as example only
}

pkg_postinst() {
	if has_version "=dev-vcs/gitolite-2*"; then
		ewarn
		elog "***NOTE** This is a major upgrade and will likely break your existing gitolite-2.x setup!"
		elog "Please read http://sitaramc.github.com/gitolite/install.html#migr first!"
		elog "Alternatively there's a local and probably older copy in /usr/share/doc/${PF}"
		elog "in case you have the \"doc\" useflag set."
	fi
	# bug 352291
	ewarn
	elog "Please make sure that your 'git' user has the correct homedir (/var/lib/gitolite)."
	elog "Especially if you're migrating from gitosis."
	ewarn
}