[gentoo-commits] gentoo-x86 commit in dev-python/python-ldap: python-ldap-2.4.9.ebuild python-ldap-2.3.13.ebuild ChangeLog python-ldap-2.4.8.ebuild

[gentoo-commits] gentoo-x86 commit in dev-python/python-ldap: python-ldap-2.4.9.ebuild python-ldap-2.3.13.ebuild ChangeLog python-ldap-2.4.8.ebuild

[Kacper Kowalik (xarthisius)]

xarthisius    12/05/17 18:57:16

  Modified:             python-ldap-2.3.13.ebuild ChangeLog
  Added:                python-ldap-2.4.9.ebuild
  Removed:              python-ldap-2.4.8.ebuild
  Log:
  Mirror docs for 2.3.13 (built by me) wrt #416343, build docs using sphinx instead of relying on upstream in latest version. Drop old. Add missing dependencies, fix building without SASL, version bump.
  
  (Portage version: 2.2.0_alpha104/cvs/Linux x86_64)

Revision  Changes    Path
1.12                 dev-python/python-ldap/python-ldap-2.3.13.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-ldap/python-ldap-2.3.13.ebuild?rev=1.12&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-ldap/python-ldap-2.3.13.ebuild?rev=1.12&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-ldap/python-ldap-2.3.13.ebuild?r1=1.11&r2=1.12

Index: python-ldap-2.3.13.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/python-ldap/python-ldap-2.3.13.ebuild,v
retrieving revision 1.11
retrieving revision 1.12
diff -u -r1.11 -r1.12
--- python-ldap-2.3.13.ebuild	4 Sep 2011 17:00:38 -0000	1.11
+++ python-ldap-2.3.13.ebuild	17 May 2012 18:57:16 -0000	1.12
@@ -1,6 +1,6 @@
-# Copyright 1999-2011 Gentoo Foundation
+# Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/python-ldap/python-ldap-2.3.13.ebuild,v 1.11 2011/09/04 17:00:38 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-ldap/python-ldap-2.3.13.ebuild,v 1.12 2012/05/17 18:57:16 xarthisius Exp $
 
 EAPI="3"
 PYTHON_DEPEND="2"
@@ -9,12 +9,12 @@
 
 inherit distutils multilib
 
-DOC_P="${PN}-docs-html-2.3.11"
+DOC_P="${PN}-docs-html-${PV}"
 
 DESCRIPTION="Various LDAP-related Python modules"
 HOMEPAGE="http://python-ldap.sourceforge.net/ http://pypi.python.org/pypi/python-ldap"
 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
-	doc? ( http://www.python-ldap.org/doc/${DOC_P}.tar.gz )"
+	doc? ( http://dev.gentoo.org/~xarthisius/distfiles/${DOC_P}.tar.gz )"
 
 LICENSE="PSF-2"
 SLOT="0"



1.108                dev-python/python-ldap/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-ldap/ChangeLog?rev=1.108&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-ldap/ChangeLog?rev=1.108&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-ldap/ChangeLog?r1=1.107&r2=1.108

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/python-ldap/ChangeLog,v
retrieving revision 1.107
retrieving revision 1.108
diff -u -r1.107 -r1.108
--- ChangeLog	9 Mar 2012 09:25:39 -0000	1.107
+++ ChangeLog	17 May 2012 18:57:16 -0000	1.108
@@ -1,6 +1,14 @@
 # ChangeLog for dev-python/python-ldap
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/python-ldap/ChangeLog,v 1.107 2012/03/09 09:25:39 patrick Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/python-ldap/ChangeLog,v 1.108 2012/05/17 18:57:16 xarthisius Exp $
+
+*python-ldap-2.4.9 (17 May 2012)
+
+  17 May 2012; Kacper Kowalik <xarthisius@gentoo.org> +python-ldap-2.4.9.ebuild,
+  -python-ldap-2.4.8.ebuild, python-ldap-2.3.13.ebuild:
+  Mirror docs for 2.3.13 (built by me) wrt #416343, build docs using sphinx
+  instead of relying on upstream in latest version. Drop old. Add missing
+  dependencies, fix building without SASL, version bump.
 
 *python-ldap-2.4.8 (09 Mar 2012)
 



1.1                  dev-python/python-ldap/python-ldap-2.4.9.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-ldap/python-ldap-2.4.9.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/python-ldap/python-ldap-2.4.9.ebuild?rev=1.1&content-type=text/plain

Index: python-ldap-2.4.9.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/python-ldap/python-ldap-2.4.9.ebuild,v 1.1 2012/05/17 18:57:16 xarthisius Exp $

EAPI=4

SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="3.* *-jython"

inherit distutils multilib

DESCRIPTION="Various LDAP-related Python modules"
HOMEPAGE="http://python-ldap.sourceforge.net/ http://pypi.python.org/pypi/python-ldap"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"

LICENSE="PSF-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-solaris"
IUSE="doc examples sasl ssl"

# If you need support for openldap-2.3.x, please use python-ldap-2.3.9.
# python team: Please do not remove python-ldap-2.3.9 from the tree.
RDEPEND=">=net-nds/openldap-2.4
	dev-python/pyasn1
	sasl? ( dev-libs/cyrus-sasl )"
DEPEND="${RDEPEND}
	dev-python/setuptools
	doc? ( dev-python/sphinx )"

DOCS="CHANGES README"
PYTHON_MODNAME="dsml.py ldapurl.py ldif.py ldap"

src_prepare() {
	local rpath=
	# sloppy logic, maybe better check if compiler links with GNU-ld
	[[ ${CHOST} != *-darwin* ]] && rpath="-Wl,-rpath=${EPREFIX}/usr/$(get_libdir)/sasl2"
	# Note: we can't add /usr/lib and /usr/lib/sasl2 to library_dirs due to a bug in py2.4
	sed -e "s:^library_dirs =.*:library_dirs =:" \
		-e "s:^include_dirs =.*:include_dirs = ${EPREFIX}/usr/include ${EPREFIX}/usr/include/sasl:" \
		-e "s:\(extra_compile_args =\).*:\1\nextra_link_args = ${rpath}:" \
		-i setup.cfg || die "error fixing setup.cfg"

	local mylibs="ldap"
	if use sasl; then
		use ssl && mylibs="ldap_r"
		mylibs="${mylibs} sasl2"
	else
		sed -e 's/HAVE_SASL//g' -i setup.cfg || die
	fi
	use ssl && mylibs="${mylibs} ssl crypto"

	sed -e "s:^libs = .*:libs = lber resolv ${mylibs}:" \
		-e "s:^compile.*:compile = 0:" \
		-e "s:^optimize.*:optimize = 0:" \
		-i setup.cfg || die "error setting up libs in setup.cfg"
}

src_compile() {
	distutils_src_compile
	if use doc; then
		pushd Doc &> /dev/null
		PYTHONPATH="$(ls -d ../build-$(PYTHON -f --ABI)/lib*)" \
			sphinx-build -b html -d	_build/doctrees . _build/html
		popd Doc &> /dev/null
	fi
}

src_install() {
	distutils_src_install

	if use examples; then
		insinto /usr/share/doc/${PF}
		doins -r Demo
	fi

	if use doc; then
		dohtml -r Doc/_build/html/
	fi
}