* [gentoo-commits] gentoo-x86 commit in mail-client/evolution: ChangeLog evolution-3.4.1.ebuild
@ 2012-05-07 5:58 Alexandre Rostovtsev (tetromino)
0 siblings, 0 replies; only message in thread
From: Alexandre Rostovtsev (tetromino) @ 2012-05-07 5:58 UTC (permalink / raw
To: gentoo-commits
tetromino 12/05/07 05:58:20
Modified: ChangeLog
Added: evolution-3.4.1.ebuild
Log:
Version bump for gnome-3.4.
(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)
Revision Changes Path
1.363 mail-client/evolution/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?rev=1.363&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?rev=1.363&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/ChangeLog?r1=1.362&r2=1.363
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v
retrieving revision 1.362
retrieving revision 1.363
diff -u -r1.362 -r1.363
--- ChangeLog 4 May 2012 08:42:21 -0000 1.362
+++ ChangeLog 7 May 2012 05:58:19 -0000 1.363
@@ -1,6 +1,12 @@
# ChangeLog for mail-client/evolution
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.362 2012/05/04 08:42:21 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/ChangeLog,v 1.363 2012/05/07 05:58:19 tetromino Exp $
+
+*evolution-3.4.1 (07 May 2012)
+
+ 07 May 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+ +files/evolution-3.3.91-spamassassin-paths.patch, +evolution-3.4.1.ebuild:
+ Version bump for gnome-3.4.
04 May 2012; Jeff Horelick <jdhore@gentoo.org> evolution-2.32.2-r3.ebuild,
evolution-2.32.3.ebuild, evolution-2.32.3-r1.ebuild, evolution-3.2.3.ebuild,
1.1 mail-client/evolution/evolution-3.4.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-3.4.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/mail-client/evolution/evolution-3.4.1.ebuild?rev=1.1&content-type=text/plain
Index: evolution-3.4.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/mail-client/evolution/evolution-3.4.1.ebuild,v 1.1 2012/05/07 05:58:19 tetromino Exp $
EAPI="4"
GCONF_DEBUG="no"
GNOME2_LA_PUNT="yes"
PYTHON_DEPEND="python? 2:2.5"
inherit eutils flag-o-matic gnome2 python
DESCRIPTION="Integrated mail, addressbook and calendaring functionality"
HOMEPAGE="http://www.gnome.org/projects/evolution/"
LICENSE="GPL-2 LGPL-2 OPENLDAP"
SLOT="2.0"
KEYWORDS="~amd64 ~x86 ~x86-fbsd"
IUSE="clutter connman crypt doc +gnome-online-accounts gstreamer kerberos ldap map networkmanager python ssl"
# We need a graphical pinentry frontend to be able to ask for the GPG
# password from inside evolution, bug 160302
PINENTRY_DEPEND="|| ( app-crypt/pinentry[gtk] app-crypt/pinentry-qt app-crypt/pinentry[qt4] )"
# glade-3 support is for maintainers only per configure.ac
# mono plugin disabled as it's incompatible with 2.8 and lacks maintainance (see bgo#634571)
# pst is not mature enough and changes API/ABI frequently
COMMON_DEPEND=">=dev-libs/glib-2.30:2
>=x11-libs/cairo-1.9.15[glib]
>=x11-libs/gtk+-3.2.0:3
>=gnome-base/gnome-desktop-2.91.3:3
>=gnome-base/gsettings-desktop-schemas-2.91.92
>=dev-libs/libgweather-2.90.0:2
>=media-libs/libcanberra-0.25[gtk3]
>=x11-libs/libnotify-0.7
>=gnome-extra/evolution-data-server-${PV}[gnome-online-accounts?,weather]
>=gnome-extra/gtkhtml-4.1.2:4.0
>=gnome-base/gconf-2:2
dev-libs/atk
>=dev-libs/dbus-glib-0.6
>=dev-libs/libxml2-2.7.3:2
>=net-libs/libsoup-gnome-2.31.2:2.4
>=x11-misc/shared-mime-info-0.22
>=x11-themes/gnome-icon-theme-2.30.2.1
>=dev-libs/libgdata-0.10
x11-libs/libSM
x11-libs/libICE
clutter? (
>=media-libs/clutter-1.0.0:1.0
>=media-libs/clutter-gtk-0.90:1.0
x11-libs/mx:1.0 )
connman? ( net-misc/connman )
crypt? ( || (
( >=app-crypt/gnupg-2.0.1-r2 ${PINENTRY_DEPEND} )
=app-crypt/gnupg-1.4* ) )
gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.1.1 )
gstreamer? (
>=media-libs/gstreamer-0.10:0.10
>=media-libs/gst-plugins-base-0.10:0.10 )
kerberos? ( virtual/krb5 )
ldap? ( >=net-nds/openldap-2 )
map? (
>=app-misc/geoclue-0.12.0
>=media-libs/libchamplain-0.12:0.12 )
networkmanager? ( >=net-misc/networkmanager-0.7 )
ssl? (
>=dev-libs/nspr-4.6.1
>=dev-libs/nss-3.11 )"
DEPEND="${COMMON_DEPEND}
app-text/docbook-xml-dtd:4.1.2
>=app-text/gnome-doc-utils-0.20.10
app-text/scrollkeeper
>=dev-util/intltool-0.40.0
sys-devel/bison
>=sys-devel/gettext-0.17
virtual/pkgconfig
doc? ( >=dev-util/gtk-doc-1.14 )"
# eautoreconf needs:
# >=gnome-base/gnome-common-2.12
# >=dev-util/gtk-doc-am-1.9
RDEPEND="${COMMON_DEPEND}
!<gnome-extra/evolution-exchange-2.32"
# contact maps require clutter
# NM and connman support cannot coexist
REQUIRED_USE="map? ( clutter )
connman? ( !networkmanager )
networkmanager? ( !connman )"
pkg_setup() {
ELTCONF="--reverse-deps"
DOCS="AUTHORS ChangeLog* HACKING MAINTAINERS NEWS* README"
# image-inline plugin needs a gtk+:3 gtkimageview, which does not exist yet
G2CONF="${G2CONF}
--disable-schemas-compile
--without-glade-catalog
--without-kde-applnk-path
--enable-plugins=experimental
--disable-image-inline
--disable-mono
--disable-pst-import
--enable-canberra
--enable-weather
$(use_enable ssl nss)
$(use_enable ssl smime)
$(use_enable networkmanager nm)
$(use_enable connman)
$(use_enable gnome-online-accounts goa)
$(use_enable gstreamer audio-inline)
$(use_enable map contact-maps)
$(use_enable python)
$(use_with clutter)
$(use_with ldap openldap)
$(use_with kerberos krb5 ${EPREFIX}/usr)"
# dang - I've changed this to do --enable-plugins=experimental. This will
# autodetect new-mail-notify and exchange, but that cannot be helped for the
# moment. They should be changed to depend on a --enable-<foo> like mono
# is. This cleans up a ton of crap from this ebuild.
# Use NSS/NSPR only if 'ssl' is enabled.
if use ssl ; then
G2CONF="${G2CONF} --enable-nss=yes"
else
G2CONF="${G2CONF}
--without-nspr-libs
--without-nspr-includes
--without-nss-libs
--without-nss-includes"
fi
python_set_active_version 2
python_pkg_setup
}
src_prepare() {
# Fix paths for Gentoo spamassassin executables
epatch "${FILESDIR}/${PN}-3.3.91-spamassassin-paths.patch"
sed -e "s:@EPREFIX@:${EPREFIX}:g" \
-i data/org.gnome.evolution.spamassassin.gschema.xml.in \
-i modules/spamassassin/evolution-spamassassin.c || die "sed failed"
gnome2_src_prepare
# Fix compilation flags crazyness
sed -e 's/\(AM_CPPFLAGS="\)$WARNING_FLAGS/\1/' \
-i configure || die "CPPFLAGS sed failed"
}
pkg_postinst() {
gnome2_pkg_postinst
elog "To change the default browser if you are not using GNOME, edit"
elog "~/.local/share/applications/mimeapps.list so it includes the"
elog "following content:"
elog ""
elog "[Default Applications]"
elog "x-scheme-handler/http=firefox.desktop"
elog "x-scheme-handler/https=firefox.desktop"
elog ""
elog "(replace firefox.desktop with the name of the appropriate .desktop"
elog "file from /usr/share/applications if you use a different browser)."
elog ""
elog "Junk filters are now a run-time choice. You will get a choice of"
elog "bogofilter or spamassassin based on which you have installed"
elog ""
elog "You have to install one of these for the spam filtering to actually work"
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-05-07 5:58 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-05-07 5:58 [gentoo-commits] gentoo-x86 commit in mail-client/evolution: ChangeLog evolution-3.4.1.ebuild Alexandre Rostovtsev (tetromino)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox