* [gentoo-commits] gentoo-x86 commit in dev-java/java-gnome: java-gnome-4.1.1.ebuild ChangeLog java-gnome-4.0.19-r1.ebuild
@ 2012-05-04 16:09 Ralph Sennhauser (sera)
0 siblings, 0 replies; only message in thread
From: Ralph Sennhauser (sera) @ 2012-05-04 16:09 UTC (permalink / raw
To: gentoo-commits
sera 12/05/04 16:09:26
Modified: ChangeLog
Added: java-gnome-4.1.1.ebuild java-gnome-4.0.19-r1.ebuild
Log:
Version bump.
Require python2 for building. #390103
(Portage version: 2.1.10.57/cvs/Linux x86_64)
Revision Changes Path
1.115 dev-java/java-gnome/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/java-gnome/ChangeLog?rev=1.115&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/java-gnome/ChangeLog?rev=1.115&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/java-gnome/ChangeLog?r1=1.114&r2=1.115
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-java/java-gnome/ChangeLog,v
retrieving revision 1.114
retrieving revision 1.115
diff -u -r1.114 -r1.115
--- ChangeLog 3 May 2012 07:42:51 -0000 1.114
+++ ChangeLog 4 May 2012 16:09:26 -0000 1.115
@@ -1,6 +1,14 @@
# ChangeLog for dev-java/java-gnome
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-java/java-gnome/ChangeLog,v 1.114 2012/05/03 07:42:51 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-java/java-gnome/ChangeLog,v 1.115 2012/05/04 16:09:26 sera Exp $
+
+*java-gnome-4.1.1 (04 May 2012)
+*java-gnome-4.0.19-r1 (04 May 2012)
+
+ 04 May 2012; Ralph Sennhauser <sera@gentoo.org> +java-gnome-4.0.19-r1.ebuild,
+ +java-gnome-4.1.1.ebuild:
+ Version bump.
+ Require python2 for building. #390103
03 May 2012; Jeff Horelick <jdhore@gentoo.org> java-gnome-4.0.18-r2.ebuild,
java-gnome-4.0.19.ebuild:
1.1 dev-java/java-gnome/java-gnome-4.1.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/java-gnome/java-gnome-4.1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/java-gnome/java-gnome-4.1.1.ebuild?rev=1.1&content-type=text/plain
Index: java-gnome-4.1.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/java-gnome/java-gnome-4.1.1.ebuild,v 1.1 2012/05/04 16:09:26 sera Exp $
EAPI=4
JAVA_PKG_IUSE="doc examples source"
PYTHON_DEPEND="2:2.7"
inherit eutils versionator java-pkg-2 multilib python virtualx
MY_PV="${PV/_/-}"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Java bindings for GTK and GNOME"
HOMEPAGE="http://java-gnome.sourceforge.net/"
SRC_URI="mirror://gnome/sources/${PN}/$(get_version_component_range 1-2)/${MY_P}.tar.bz2"
LICENSE="GPL-2-with-linking-exception"
SLOT="4.1"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""
COMMON_DEP="
app-text/enchant:0
dev-libs/atk:0
>=dev-libs/glib-2.28:2
dev-libs/libunique:3
gnome-base/librsvg:2
>=x11-libs/cairo-1.10.0[svg]
x11-libs/gdk-pixbuf:2
x11-libs/gtk+:3
x11-libs/gtksourceview:3.0
>=x11-libs/libnotify-0.7.0
x11-libs/pango:0"
RDEPEND="${COMMON_DEP}
>=virtual/jre-1.5"
DEPEND="${COMMON_DEP}
dev-java/junit:0
dev-lang/perl
>=virtual/jdk-1.5
virtual/pkgconfig"
S="${WORKDIR}/${MY_P}"
pkg_setup() {
python_set_active_version 2 #390103
python_pkg_setup
java-pkg-2_pkg_setup
}
src_configure() {
# Handwritten in perl so not using econf
./configure prefix=/usr libdir=/usr/$(get_libdir)/${PN}-${SLOT} jardir=/usr/share/${PN}-${SLOT}/lib || die
}
src_compile() {
emake
use doc && DISPLAY= emake doc
}
# Needs X11, fails even then
RESTRICT="test"
src_test() {
Xemake test
}
src_install(){
emake -j1 DESTDIR="${D}" install || die
java-pkg_regjar /usr/share/${PN}-${SLOT}/lib/gtk-${SLOT}.jar
java-pkg_regjar /usr/share/${PN}-${SLOT}/lib/gtk.jar
dodoc AUTHORS HACKING NEWS README || die
use doc && java-pkg_dojavadoc doc/api
use examples && java-pkg_doexamples doc/examples
use source && java-pkg_dosrc src/bindings/org
}
1.1 dev-java/java-gnome/java-gnome-4.0.19-r1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/java-gnome/java-gnome-4.0.19-r1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-java/java-gnome/java-gnome-4.0.19-r1.ebuild?rev=1.1&content-type=text/plain
Index: java-gnome-4.0.19-r1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-java/java-gnome/java-gnome-4.0.19-r1.ebuild,v 1.1 2012/05/04 16:09:26 sera Exp $
EAPI=4
JAVA_PKG_IUSE="doc examples source"
PYTHON_DEPEND="2:2.7"
inherit eutils versionator java-pkg-2 multilib python
MY_PV="${PV/_/-}"
MY_P="${PN}-${MY_PV}"
DESCRIPTION="Java bindings for GTK and GNOME"
HOMEPAGE="http://java-gnome.sourceforge.net/"
SRC_URI="mirror://gnome/sources/${PN}/$(get_version_component_range 1-2)/${MY_P}.tar.bz2"
LICENSE="GPL-2-with-linking-exception"
SLOT="4.0"
KEYWORDS="~amd64 ~ppc ~x86"
IUSE=""
RDEPEND=">=dev-libs/glib-2.22
>=x11-libs/gtk+-2.22.0:2
>=gnome-base/libglade-2.6.4
>=gnome-base/libgnome-2.22.0
>=gnome-base/gnome-desktop-2.22.0:2
>=x11-libs/cairo-1.10.0[svg]
>=x11-libs/gtksourceview-2.6.2:2.0
>=app-text/gtkspell-2.0.15-r1:2
>=x11-libs/libnotify-0.4.5
>=dev-libs/libunique-1.0.8:1
>=gnome-base/librsvg-2.32.1
dev-libs/atk
>=virtual/jre-1.5"
DEPEND="${RDEPEND}
dev-java/junit:0
dev-lang/perl
virtual/pkgconfig
>=virtual/jdk-1.5"
# Needs X11
RESTRICT="test"
S="${WORKDIR}/${MY_P}"
pkg_setup() {
python_set_active_version 2 #390103
python_pkg_setup
java-pkg-2_pkg_setup
}
java_prepare() {
if has_version ">=x11-libs/libnotify-0.7"; then
epatch "${FILESDIR}"/${P}-libnotify-0.7.patch
fi
}
src_configure() {
# Handwritten in perl so not using econf
./configure prefix=/usr libdir=/usr/$(get_libdir)/${PN}-${SLOT} jardir=/usr/share/${PN}-${SLOT}/lib || die
}
src_compile() {
# Fails parallel build in case GCJ is detected
# See https://bugs.gentoo.org/show_bug.cgi?id=200550
emake -j1 || die "Compilation of java-gnome failed"
if use doc; then
DISPLAY= emake -j1 doc || die "Making documentation failed"
fi
}
src_install(){
emake -j1 DESTDIR="${D}" install || die
java-pkg_regjar /usr/share/${PN}-${SLOT}/lib/gtk-${SLOT}.jar
java-pkg_regjar /usr/share/${PN}-${SLOT}/lib/gtk.jar
dodoc AUTHORS HACKING NEWS README || die
use doc && java-pkg_dojavadoc doc/api
use examples && java-pkg_doexamples doc/examples
use source && java-pkg_dosrc src/bindings/org
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-05-04 16:09 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-05-04 16:09 [gentoo-commits] gentoo-x86 commit in dev-java/java-gnome: java-gnome-4.1.1.ebuild ChangeLog java-gnome-4.0.19-r1.ebuild Ralph Sennhauser (sera)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox