[gentoo-commits] gentoo-x86 commit in dev-util/apitrace: metadata.xml ChangeLog apitrace-3.0.ebuild

[gentoo-commits] gentoo-x86 commit in dev-util/apitrace: metadata.xml ChangeLog apitrace-3.0.ebuild

[Tim Harder (radhermit)]

radhermit    12/03/16 22:32:51

  Modified:             metadata.xml ChangeLog
  Added:                apitrace-3.0.ebuild
  Log:
  Version bump. Add egl use flag.
  
  (Portage version: 2.2.0_alpha90/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  dev-util/apitrace/metadata.xml

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/apitrace/metadata.xml?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/apitrace/metadata.xml?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/apitrace/metadata.xml?r1=1.2&r2=1.3

Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/apitrace/metadata.xml,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- metadata.xml	24 Sep 2011 08:55:09 -0000	1.2
+++ metadata.xml	16 Mar 2012 22:32:50 -0000	1.3
@@ -5,4 +5,7 @@
 		<email>radhermit@gentoo.org</email>
 		<name>Tim Harder</name>
 	</maintainer>
+	<use>
+		<flag name="egl">Enable EGL support</flag>
+	</use>
 </pkgmetadata>



1.7                  dev-util/apitrace/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/apitrace/ChangeLog?rev=1.7&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/apitrace/ChangeLog?rev=1.7&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/apitrace/ChangeLog?r1=1.6&r2=1.7

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-util/apitrace/ChangeLog,v
retrieving revision 1.6
retrieving revision 1.7
diff -u -r1.6 -r1.7
--- ChangeLog	15 Dec 2011 07:28:36 -0000	1.6
+++ ChangeLog	16 Mar 2012 22:32:50 -0000	1.7
@@ -1,6 +1,13 @@
 # ChangeLog for dev-util/apitrace
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/apitrace/ChangeLog,v 1.6 2011/12/15 07:28:36 radhermit Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/apitrace/ChangeLog,v 1.7 2012/03/16 22:32:50 radhermit Exp $
+
+*apitrace-3.0 (16 Mar 2012)
+
+  16 Mar 2012; Tim Harder <radhermit@gentoo.org> +apitrace-3.0.ebuild,
+  +files/apitrace-3.0-glxtrace-only.patch,
+  +files/apitrace-3.0-system-libs.patch, metadata.xml:
+  Version bump. Add egl use flag.
 
 *apitrace-2.0-r1 (15 Dec 2011)
 



1.1                  dev-util/apitrace/apitrace-3.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/apitrace/apitrace-3.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-util/apitrace/apitrace-3.0.ebuild?rev=1.1&content-type=text/plain

Index: apitrace-3.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-util/apitrace/apitrace-3.0.ebuild,v 1.1 2012/03/16 22:32:51 radhermit Exp $

EAPI="4"
PYTHON_DEPEND="2:2.6"

inherit cmake-utils eutils python multilib

DESCRIPTION="A tool for tracing, analyzing, and debugging graphics APIs"
HOMEPAGE="https://github.com/apitrace/apitrace"
SRC_URI="https://github.com/${PN}/${PN}/tarball/${PV} -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="egl multilib qt4"

RDEPEND="app-arch/snappy
	media-libs/libpng
	sys-libs/zlib
	media-libs/mesa[egl?]
	egl? ( || (
		>=media-libs/mesa-8.0[gles1,gles2]
		<media-libs/mesa-8.0[gles]
	) )
	x11-libs/libX11
	multilib? ( app-emulation/emul-linux-x86-baselibs )
	qt4? (
		>=x11-libs/qt-core-4.7:4
		>=x11-libs/qt-gui-4.7:4
		>=x11-libs/qt-webkit-4.7:4
		>=dev-libs/qjson-0.5
	)"
DEPEND="${RDEPEND}"

EMULTILIB_PKG="true"

PATCHES=(
	"${FILESDIR}"/${P}-system-libs.patch
	"${FILESDIR}"/${P}-glxtrace-only.patch
)

pkg_setup() {
	python_set_active_version 2
}

src_unpack() {
	unpack ${A}
	mv *-${PN}-* "${S}"
}

src_prepare() {
	base_src_prepare

	# Workaround NULL DT_RPATH issues
	sed -i -e "s/install (TARGETS/#\0/" gui/CMakeLists.txt || die
}

src_configure() {
	for ABI in $(get_install_abis) ; do
		mycmakeargs=(
			$(cmake-utils_use_enable qt4 GUI)
			$(cmake-utils_use_enable egl EGL)
		)

		if use multilib ; then
			if [[ "${ABI}" != "${DEFAULT_ABI}" ]] ; then
				mycmakeargs=( -DBUILD_LIB_ONLY=ON -DENABLE_GUI=OFF )
			fi
			multilib_toolchain_setup ${ABI}
		fi

		CMAKE_BUILD_DIR="${WORKDIR}/${P}_build-${ABI}"
		cmake-utils_src_configure
	done
}

src_compile() {
	for ABI in $(get_install_abis) ; do
		use multilib && multilib_toolchain_setup ${ABI}
		CMAKE_BUILD_DIR="${WORKDIR}/${P}_build-${ABI}"
		cmake-utils_src_compile
	done
}

src_install() {
	dobin "${CMAKE_BUILD_DIR}"/{glretrace,apitrace}
	use qt4 && dobin "${CMAKE_BUILD_DIR}"/qapitrace

	for ABI in $(get_install_abis) ; do
		CMAKE_BUILD_DIR="${WORKDIR}/${P}_build-${ABI}"
		exeinto /usr/$(get_libdir)/${PN}/wrappers
		doexe "${CMAKE_BUILD_DIR}"/wrappers/*.so
		dosym glxtrace.so /usr/$(get_libdir)/${PN}/wrappers/libGL.so
		dosym glxtrace.so /usr/$(get_libdir)/${PN}/wrappers/libGL.so.1
		dosym glxtrace.so /usr/$(get_libdir)/${PN}/wrappers/libGL.so.1.2
	done

	dodoc {BUGS,DEVELOPMENT,NEWS,README,TODO}.markdown

	exeinto /usr/$(get_libdir)/${PN}/scripts
	doexe $(find scripts -type f -executable)
}