* [gentoo-commits] gentoo-x86 commit in sys-boot/grub: grub-2.00_beta2.ebuild ChangeLog
@ 2012-03-11 17:48 Mike Gilbert (floppym)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Gilbert (floppym) @ 2012-03-11 17:48 UTC (permalink / raw
To: gentoo-commits
floppym 12/03/11 17:48:52
Modified: ChangeLog
Added: grub-2.00_beta2.ebuild
Log:
Version bump.
(Portage version: 2.2.0_alpha90/cvs/Linux x86_64)
Revision Changes Path
1.187 sys-boot/grub/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.187&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.187&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?r1=1.186&r2=1.187
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v
retrieving revision 1.186
retrieving revision 1.187
diff -u -r1.186 -r1.187
--- ChangeLog 8 Mar 2012 05:28:57 -0000 1.186
+++ ChangeLog 11 Mar 2012 17:48:52 -0000 1.187
@@ -1,6 +1,11 @@
# ChangeLog for sys-boot/grub
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.186 2012/03/08 05:28:57 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.187 2012/03/11 17:48:52 floppym Exp $
+
+*grub-2.00_beta2 (11 Mar 2012)
+
+ 11 Mar 2012; Mike Gilbert <floppym@gentoo.org> +grub-2.00_beta2.ebuild:
+ Version bump.
08 Mar 2012; Mike Gilbert <floppym@gentoo.org> grub-2.00_beta1.ebuild,
grub-9999.ebuild:
1.1 sys-boot/grub/grub-2.00_beta2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild?rev=1.1&content-type=text/plain
Index: grub-2.00_beta2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild,v 1.1 2012/03/11 17:48:52 floppym Exp $
EAPI=4
if [[ ${PV} == "9999" ]] ; then
EBZR_REPO_URI="http://bzr.savannah.gnu.org/r/grub/trunk/grub/"
LIVE_ECLASS="bzr"
SRC_URI=""
DO_AUTORECONF="true"
else
MY_P=${P/_/\~}
if [[ ${PV} == *_alpha* || ${PV} == *_beta* ]]; then
SRC_URI="mirror://gnu-alpha/${PN}/${MY_P}.tar.xz"
else
SRC_URI="mirror://gnu/${PN}/${MY_P}.tar.xz
mirror://gentoo/${MY_P}.tar.xz"
fi
# Masked until documentation guys consolidate the guide and approve
# it for usage.
#KEYWORDS="~amd64 ~mips ~x86"
S=${WORKDIR}/${MY_P}
fi
inherit eutils flag-o-matic pax-utils toolchain-funcs ${DO_AUTORECONF:+autotools} ${LIVE_ECLASS}
unset LIVE_ECLASS
DESCRIPTION="GNU GRUB boot loader"
HOMEPAGE="http://www.gnu.org/software/grub/"
LICENSE="GPL-3"
SLOT="2"
IUSE="custom-cflags debug device-mapper efiemu mount nls static sdl truetype libzfs"
GRUB_PLATFORMS=(
# everywhere:
emu
# mips only:
qemu-mips yeeloong
# amd64, x86, ppc, ppc64:
ieee1275
# amd64, x86:
coreboot multiboot efi-32 pc qemu
# amd64, ia64:
efi-64
)
IUSE+=" ${GRUB_PLATFORMS[@]/#/grub_platforms_}"
# os-prober: Used on runtime to detect other OSes
# xorriso (dev-libs/libisoburn): Used on runtime for mkrescue
RDEPEND="
dev-libs/libisoburn
dev-libs/lzo
sys-boot/os-prober
>=sys-libs/ncurses-5.2-r5
debug? (
sdl? ( media-libs/libsdl )
)
device-mapper? ( >=sys-fs/lvm2-2.02.45 )
libzfs? ( sys-fs/zfs )
mount? ( sys-fs/fuse )
truetype? ( media-libs/freetype >=media-fonts/unifont-5 )"
DEPEND="${RDEPEND}
>=dev-lang/python-2.5.2
sys-devel/flex
virtual/yacc
sys-apps/texinfo
"
RDEPEND+="
grub_platforms_efi-32? ( sys-boot/efibootmgr )
grub_platforms_efi-64? ( sys-boot/efibootmgr )
"
if [[ -n ${DO_AUTORECONF} ]] ; then
DEPEND+=" >=sys-devel/autogen-5.10 sys-apps/help2man"
else
DEPEND+=" app-arch/xz-utils"
fi
export STRIP_MASK="*/grub/*/*.{mod,img}"
QA_EXECSTACK="
usr/bin/grub*
usr/sbin/grub*
usr/lib*/grub/*/*.mod
usr/lib*/grub/*/kernel.exec
usr/lib*/grub/*/kernel.img
usr/lib*/grub/*/setjmp.module
"
QA_WX_LOAD="
usr/lib*/grub/*/kernel.exec
usr/lib*/grub/*/kernel.img
usr/lib*/grub/*/*.image
"
QA_PRESTRIPPED="
usr/lib.*/grub/.*/kernel.img
"
grub_run_phase() {
local phase=$1
local platform=$2
[[ -z ${phase} || -z ${platform} ]] && die "${FUNCNAME} [phase] [platform]"
[[ -d "${WORKDIR}/build-${platform}" ]] || \
{ mkdir "${WORKDIR}/build-${platform}" || die ; }
pushd "${WORKDIR}/build-${platform}" > /dev/null || die
echo ">>> Running ${phase} for platform \"${platform}\""
echo ">>> Working in: \"${WORKDIR}/build-${platform}\""
grub_${phase} ${platform}
popd > /dev/null || die
}
grub_src_configure() {
local platform=$1
local target=
local with_platform=
[[ -z ${platform} ]] && die "${FUNCNAME} [platform]"
# check if we have to specify the target (EFI)
# or just append correct --with-platform
if [[ ${platform} == efi-32 ]]; then
# Build 32-bit EFI on 64-bit system
target="--target=i386"
fi
case ${platform} in
efi-*) with_platform="--with-platform=${platform%-*}" ;;
guessed) ;;
*) with_platform="--with-platform=${platform}" ;;
esac
ECONF_SOURCE="${S}" \
econf \
--disable-werror \
--program-prefix= \
--program-transform-name="s,grub,grub2," \
--with-grubdir=grub2 \
${target} \
${with_platform} \
$(use_enable debug mm-debug) \
$(use_enable debug grub-emu-usb) \
$(use_enable device-mapper) \
$(use_enable efiemu) \
$(use_enable mount grub-mount) \
$(use_enable nls) \
$(use_enable truetype grub-mkfont) \
$(use_enable libzfs) \
$(use sdl && use_enable debug grub-emu-sdl)
}
grub_src_compile() {
default_src_compile
pax-mark -mpes "${grub_binaries[@]}"
}
grub_src_install() {
default_src_install
}
src_prepare() {
local i j
epatch_user
# autogen.sh does more than just run autotools
if [[ -n ${DO_AUTORECONF} ]] ; then
sed -i -e '/^autoreconf/s:^:set +e; e:' autogen.sh || die
(. ./autogen.sh) || die
fi
# install into the right dir for eselect #372735
sed -i \
-e '/^bashcompletiondir =/s:=.*:= $(datarootdir)/bash-completion:' \
util/bash-completion.d/Makefile.in || die
# get enabled platforms
GRUB_ENABLED_PLATFORMS=""
for i in ${GRUB_PLATFORMS[@]}; do
use grub_platforms_${i} && GRUB_ENABLED_PLATFORMS+=" ${i}"
done
[[ -z ${GRUB_ENABLED_PLATFORMS} ]] && GRUB_ENABLED_PLATFORMS="guessed"
elog "Going to build following platforms: ${GRUB_ENABLED_PLATFORMS}"
}
src_configure() {
local i
use custom-cflags || unset CFLAGS CPPFLAGS LDFLAGS
use libzfs && addpredict /etc/dfs
use static && append-ldflags -static
for i in ${GRUB_ENABLED_PLATFORMS}; do
grub_run_phase ${FUNCNAME} ${i}
done
}
src_compile() {
# Used for pax marking in grub_src_compile
local grub_binaries=(
grub-editenv
grub-fstest
grub-menulst2cfg
grub-mkimage
grub-mklayout
grub-mkpasswd-pbkdf2
grub-mkrelpath
grub-script-check
grub-bios-setup
grub-ofpathname
grub-probe
grub-sparc64-setup
)
use mount && grub_binaries+=( grub-mount )
use truetype && grub_binaries+=( grub-mkfont )
local i
for i in ${GRUB_ENABLED_PLATFORMS}; do
grub_run_phase ${FUNCNAME} ${i}
done
}
src_install() {
local i
for i in ${GRUB_ENABLED_PLATFORMS}; do
grub_run_phase ${FUNCNAME} ${i}
done
mv "${ED}"usr/share/info/grub{,2}.info || die
# can't be in docs array as we use default_src_install in different builddir
dodoc AUTHORS ChangeLog NEWS README THANKS TODO
insinto /etc/default
newins "${FILESDIR}"/grub.default grub
}
pkg_postinst() {
# display the link to guide
elog "For information on how to configure grub-2 please refer to the guide:"
elog " http://wiki.gentoo.org/wiki/GRUB2"
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in sys-boot/grub: grub-2.00_beta2.ebuild ChangeLog
@ 2012-03-17 7:58 Mike Gilbert (floppym)
0 siblings, 0 replies; 2+ messages in thread
From: Mike Gilbert (floppym) @ 2012-03-17 7:58 UTC (permalink / raw
To: gentoo-commits
floppym 12/03/17 07:58:44
Modified: grub-2.00_beta2.ebuild ChangeLog
Log:
Enable building x86_64-efi target on an x86 host. Bug 408545.
(Portage version: 2.2.0_alpha90/cvs/Linux x86_64)
Revision Changes Path
1.2 sys-boot/grub/grub-2.00_beta2.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild?r1=1.1&r2=1.2
Index: grub-2.00_beta2.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- grub-2.00_beta2.ebuild 11 Mar 2012 17:48:52 -0000 1.1
+++ grub-2.00_beta2.ebuild 17 Mar 2012 07:58:43 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild,v 1.1 2012/03/11 17:48:52 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/grub-2.00_beta2.ebuild,v 1.2 2012/03/17 07:58:43 floppym Exp $
EAPI=4
@@ -122,15 +122,27 @@
[[ -z ${platform} ]] && die "${FUNCNAME} [platform]"
- # check if we have to specify the target (EFI)
- # or just append correct --with-platform
- if [[ ${platform} == efi-32 ]]; then
- # Build 32-bit EFI on 64-bit system
- target="--target=i386"
- fi
+ # Used below for efi cross-building
+ tc-export CC NM OBJCOPY STRIP
+ unset TARGET_CC TARGET_CFLAGS TARGET_CPPFLAGS
case ${platform} in
- efi-*) with_platform="--with-platform=${platform%-*}" ;;
+ efi-32)
+ if [[ ${CHOST} == x86_64* ]]; then
+ target="--target=i386"
+ export TARGET_CC="${CC}"
+ fi
+ with_platform="--with-platform=efi"
+ ;;
+ efi-64)
+ if [[ ${CHOST} == i?86* ]]; then
+ target="--target=x86_64"
+ export TARGET_CC="${CC}"
+ export TARGET_CFLAGS="-march=x86-64"
+ export TARGET_CPPFLAGS="-march=x86-64"
+ fi
+ with_platform="--with-platform=efi"
+ ;;
guessed) ;;
*) with_platform="--with-platform=${platform}" ;;
esac
1.188 sys-boot/grub/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.188&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?rev=1.188&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-boot/grub/ChangeLog?r1=1.187&r2=1.188
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v
retrieving revision 1.187
retrieving revision 1.188
diff -u -r1.187 -r1.188
--- ChangeLog 11 Mar 2012 17:48:52 -0000 1.187
+++ ChangeLog 17 Mar 2012 07:58:43 -0000 1.188
@@ -1,6 +1,9 @@
# ChangeLog for sys-boot/grub
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.187 2012/03/11 17:48:52 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-boot/grub/ChangeLog,v 1.188 2012/03/17 07:58:43 floppym Exp $
+
+ 17 Mar 2012; Mike Gilbert <floppym@gentoo.org> grub-2.00_beta2.ebuild:
+ Enable building x86_64-efi target on an x86 host. Bug 408545.
*grub-2.00_beta2 (11 Mar 2012)
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-03-17 7:59 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-03-11 17:48 [gentoo-commits] gentoo-x86 commit in sys-boot/grub: grub-2.00_beta2.ebuild ChangeLog Mike Gilbert (floppym)
-- strict thread matches above, loose matches on Subject: below --
2012-03-17 7:58 Mike Gilbert (floppym)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox