* [gentoo-commits] gentoo-x86 commit in dev-lang/mercury-extras: ChangeLog mercury-extras-11.07.1.ebuild
@ 2012-03-09 21:14 Keri Harris (keri)
0 siblings, 0 replies; only message in thread
From: Keri Harris (keri) @ 2012-03-09 21:14 UTC (permalink / raw
To: gentoo-commits
keri 12/03/09 21:14:59
Modified: ChangeLog
Added: mercury-extras-11.07.1.ebuild
Log:
Version bump
(Portage version: 2.1.10.44/cvs/Linux x86_64)
Revision Changes Path
1.101 dev-lang/mercury-extras/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/mercury-extras/ChangeLog?rev=1.101&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/mercury-extras/ChangeLog?rev=1.101&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/mercury-extras/ChangeLog?r1=1.100&r2=1.101
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-lang/mercury-extras/ChangeLog,v
retrieving revision 1.100
retrieving revision 1.101
diff -u -r1.100 -r1.101
--- ChangeLog 9 Jan 2012 08:30:13 -0000 1.100
+++ ChangeLog 9 Mar 2012 21:14:59 -0000 1.101
@@ -1,6 +1,11 @@
# ChangeLog for dev-lang/mercury-extras
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-lang/mercury-extras/ChangeLog,v 1.100 2012/01/09 08:30:13 keri Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-lang/mercury-extras/ChangeLog,v 1.101 2012/03/09 21:14:59 keri Exp $
+
+*mercury-extras-11.07.1 (09 Mar 2012)
+
+ 09 Mar 2012; <keri@gentoo.org> +mercury-extras-11.07.1.ebuild:
+ Version bump
*mercury-extras-11.07 (09 Jan 2012)
1.1 dev-lang/mercury-extras/mercury-extras-11.07.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/mercury-extras/mercury-extras-11.07.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-lang/mercury-extras/mercury-extras-11.07.1.ebuild?rev=1.1&content-type=text/plain
Index: mercury-extras-11.07.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-lang/mercury-extras/mercury-extras-11.07.1.ebuild,v 1.1 2012/03/09 21:14:59 keri Exp $
EAPI=2
inherit eutils
PATCHSET_VER="0"
MY_P=${PN}-${PV}
DESCRIPTION="Additional libraries and tools that are not part of the Mercury standard library"
HOMEPAGE="http://www.cs.mu.oz.au/research/mercury/index.html"
SRC_URI="http://www.mercury.cs.mu.oz.au/download/files/${MY_P}.tar.gz
mirror://gentoo/${P}-gentoo-patchset-${PATCHSET_VER}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X cairo examples glut iodbc ncurses odbc opengl ssl tcl tk xml"
RDEPEND="~dev-lang/mercury-${PV}
cairo? ( >=x11-libs/cairo-1.10.0 )
glut? ( media-libs/freeglut )
odbc? ( dev-db/unixODBC )
iodbc? ( !odbc? ( dev-db/libiodbc ) )
ncurses? ( sys-libs/ncurses )
opengl? ( virtual/opengl )
tcl? ( tk? (
dev-lang/tcl
dev-lang/tk
x11-libs/libX11
x11-libs/libXmu ) )"
DEPEND="${RDEPEND}"
S="${WORKDIR}"/${MY_P}
src_prepare() {
cd "${WORKDIR}"
EPATCH_FORCE=yes
EPATCH_SUFFIX=patch
epatch "${WORKDIR}"/${PV}
if use odbc; then
epatch "${WORKDIR}"/${PV}-odbc/${P}-odbc.patch
elif use iodbc; then
epatch "${WORKDIR}"/${PV}-odbc/${P}-iodbc.patch
fi
cd "${S}"
sed -i -e "s:references:references solver_types/library:" \
-e "s:windows_installer_generator::" \
Mmakefile || die "sed default packages failed"
if use cairo; then
sed -i -e "s:lex[ \t]*\\\\:graphics/mercury_cairo lex \\\\:" Mmakefile \
|| die "sed cairo failed"
fi
if use glut; then
sed -i -e "s:lex[ \t]*\\\\:graphics/mercury_glut lex \\\\:" Mmakefile \
|| die "sed glut failed"
fi
if use opengl; then
sed -i -e "s:lex[ \t]*\\\\:graphics/mercury_opengl lex \\\\:" Mmakefile \
|| die "sed opengl failed"
fi
if use tcl && use tk; then
sed -i -e "s:lex[ \t]*\\\\:graphics/mercury_tcltk lex \\\\:" Mmakefile \
|| die "sed tcltk failed"
fi
if use odbc || use iodbc; then
sed -i -e "s:moose:moose odbc:" Mmakefile \
|| die "sed odbc failed"
fi
if use ncurses; then
sed -i -e "s:complex_numbers:complex_numbers curs curses:" Mmakefile \
|| die "sed ncurses failed"
fi
if ! use xml; then
sed -i -e "s:xml::" Mmakefile \
|| die "sed xml failed"
fi
sed -i -e "s:@libdir@:$(get_libdir):" \
dynamic_linking/Mmakefile posix/Mmakefile \
|| die "sed libdir failed"
# disable broken packages
sed -i -e "s:references::" Mmakefile \
|| die "sed broken packages failed"
}
src_compile() {
# Mercury dependency generation must be run single-threaded
mmake \
-j1 depend || die "mmake depend failed"
mmake \
MMAKEFLAGS="${MAKEOPTS}" \
EXTRA_MLFLAGS=--no-strip \
EXTRA_LDFLAGS="${LDFLAGS}" \
EXTRA_LD_LIBFLAGS="${LDFLAGS}" \
|| die "mmake failed"
}
src_install() {
mmake \
MMAKEFLAGS="${MAKEOPTS}" \
EXTRA_LD_LIBFLAGS="${LDFLAGS}" \
INSTALL_PREFIX="${D}"/usr \
install || die "mmake install failed"
find "${D}"/usr/$(get_libdir)/mercury -type l | xargs rm
cd "${S}"
if use examples; then
insinto /usr/share/doc/${PF}/samples/base64
doins base64/*.m || die
insinto /usr/share/doc/${PF}/samples/complex_numbers
doins complex_numbers/samples/* || die
insinto /usr/share/doc/${PF}/samples/dynamic_linking
doins dynamic_linking/hello.m || die
insinto /usr/share/doc/${PF}/samples/error
doins error/* || die
insinto /usr/share/doc/${PF}/samples/fixed
doins fixed/*.m || die
insinto /usr/share/doc/${PF}/samples/gator
doins -r gator/* || die
insinto /usr/share/doc/${PF}/samples/lex
doins lex/samples/* || die
insinto /usr/share/doc/${PF}/samples/log4m
doins log4m/*.m || die
insinto /usr/share/doc/${PF}/samples/monte
doins monte/*.m || die
insinto /usr/share/doc/${PF}/samples/moose
doins moose/samples/* || die
insinto /usr/share/doc/${PF}/samples/net
doins net/*.m || die
if use ncurses; then
insinto /usr/share/doc/${PF}/samples/curs
doins curs/samples/* || die
insinto /usr/share/doc/${PF}/samples/curses
doins curses/sample/* || die
fi
if use X; then
insinto /usr/share/doc/${PF}/samples/graphics
doins graphics/easyx/samples/*.m || die
fi
if use glut && use opengl; then
insinto /usr/share/doc/${PF}/samples/graphics
doins graphics/samples/calc/* || die
doins graphics/samples/gears/* || die
doins graphics/samples/maze/* || die
doins graphics/samples/pent/* || die
fi
if use opengl && use tcl && use tk; then
insinto /usr/share/doc/${PF}/samples/graphics
doins graphics/samples/pent/*.m || die
fi
if use ssl; then
insinto /usr/share/doc/${PF}/samples/mopenssl
doins mopenssl/*.m || die
fi
rm -rf $(find "${D}"/usr/share/doc/${PF}/samples -name CVS)
fi
dodoc README || die
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-03-09 21:15 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-03-09 21:14 [gentoo-commits] gentoo-x86 commit in dev-lang/mercury-extras: ChangeLog mercury-extras-11.07.1.ebuild Keri Harris (keri)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox