[gentoo-commits] gentoo-x86 commit in media-libs/oyranos: ChangeLog oyranos-0.4.0.ebuild

[gentoo-commits] gentoo-x86 commit in media-libs/oyranos: ChangeLog oyranos-0.4.0.ebuild

[Michael Weber (xmw)]

xmw         12/03/09 19:26:45

  Modified:             ChangeLog
  Added:                oyranos-0.4.0.ebuild
  Log:
  Version bump (thanks Andreas Sturmlechner, bug 407485)
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.3                  media-libs/oyranos/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/oyranos/ChangeLog?rev=1.3&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/oyranos/ChangeLog?rev=1.3&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/oyranos/ChangeLog?r1=1.2&r2=1.3

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/media-libs/oyranos/ChangeLog,v
retrieving revision 1.2
retrieving revision 1.3
diff -u -r1.2 -r1.3
--- ChangeLog	8 Feb 2012 05:49:19 -0000	1.2
+++ ChangeLog	9 Mar 2012 19:26:45 -0000	1.3
@@ -1,6 +1,12 @@
 # ChangeLog for media-libs/oyranos
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/oyranos/ChangeLog,v 1.2 2012/02/08 05:49:19 xmw Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/oyranos/ChangeLog,v 1.3 2012/03/09 19:26:45 xmw Exp $
+
+*oyranos-0.4.0 (09 Mar 2012)
+
+  09 Mar 2012; Michael Weber <xmw@gentoo.org> +oyranos-0.4.0.ebuild,
+  +files/oyranos-0.4.0-buildsystem.patch:
+  Version bump (thanks Andreas Sturmlechner, bug 407485)
 
   08 Feb 2012; Michael Weber <xmw@gentoo.org> oyranos-0.3.2.ebuild,
   +files/oyranos-0.3.2-test.patch:



1.1                  media-libs/oyranos/oyranos-0.4.0.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/oyranos/oyranos-0.4.0.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/media-libs/oyranos/oyranos-0.4.0.ebuild?rev=1.1&content-type=text/plain

Index: oyranos-0.4.0.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-libs/oyranos/oyranos-0.4.0.ebuild,v 1.1 2012/03/09 19:26:45 xmw Exp $

EAPI=4

inherit eutils toolchain-funcs

DESCRIPTION="colour management system allowing to share various settings across applications and services"
HOMEPAGE="http://www.oyranos.org/"
SRC_URI="mirror://sourceforge/oyranos/Oyranos/Oyranos%200.4/${P}.tar.bz2"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="X doc static-libs test xinerama"

RDEPEND="app-admin/elektra
	dev-libs/libxml2
	dev-libs/yajl
	media-gfx/exiv2
	media-libs/lcms:0
	media-libs/libpng:0
	media-libs/libraw
	>=media-libs/libXcm-0.5.0
	X? ( x11-libs/fltk:1
		x11-libs/libXfixes
		x11-libs/libXrandr
		x11-libs/libXxf86vm
		xinerama? ( x11-libs/libXinerama ) )"
DEPEND="${RDEPEND}
	app-doc/doxygen
	test? ( media-libs/icc-profiles-basiccolor-printing2009
		media-libs/icc-profiles-openicc )"

RESTRICT="test"

src_prepare() {
	einfo remove bundled elektra yajl
	rm -rf elektra* yajl || die
	#keep bundled libXNVCtrl

	epatch "${FILESDIR}"/${P}-buildsystem.patch \
		"${FILESDIR}"/${PN}-0.3.2-test.patch

	if ! use X ; then
		sed -e '/FLTK_GUI =/s:=.*:=:' \
			-i makefile.in || die
	fi

	sed -e '/#include/s:alpha/oyranos_alpha.h:oyranos_alpha.h:' \
		-i examples/libraw/oyranos_file.cpp || die
}

src_configure() {
	tc-export CC CXX
	econf --prefix=/usr \
		--enable-verbose \
		$(use_with X x) \
		$(use_enable X libX11) \
		$(use_enable X libXext) \
		$(use_enable X libXrandr) \
		$(use_enable X libXxf86vm) \
		$(use_enable X fltk) \
		$(use_enable static-libs static) \
		$(use_enable xinerama libXinerama)
}

src_compile() {
	emake all
	use X && emake oforms
	emake docu
}

src_install() {
	emake DESTDIR="${D}" docdir=${EPREFIX}/usr/share/doc/${P} install-main

	if ! use doc ; then
		rm -rf "${ED}/usr/share/doc/${P}/html" || die
	fi
}