[gentoo-commits] gentoo-x86 commit in net-misc/tor: ChangeLog tor-0.2.3.11_alpha.ebuild

[gentoo-commits] gentoo-x86 commit in net-misc/tor: ChangeLog tor-0.2.3.11_alpha.ebuild

[Anthony G. Basile (blueness)]

blueness    12/01/24 13:06:55

  Modified:             ChangeLog
  Added:                tor-0.2.3.11_alpha.ebuild
  Log:
  Version bump alpha
  
  (Portage version: 2.1.10.41/cvs/Linux x86_64)

Revision  Changes    Path
1.316                net-misc/tor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.316&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.316&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?r1=1.315&r2=1.316

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v
retrieving revision 1.315
retrieving revision 1.316
diff -u -r1.315 -r1.316
--- ChangeLog	24 Jan 2012 11:23:54 -0000	1.315
+++ ChangeLog	24 Jan 2012 13:06:55 -0000	1.316
@@ -1,6 +1,13 @@
 # ChangeLog for net-misc/tor
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.315 2012/01/24 11:23:54 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.316 2012/01/24 13:06:55 blueness Exp $
+
+*tor-0.2.3.11_alpha (24 Jan 2012)
+
+  24 Jan 2012; Anthony G. Basile <blueness@gentoo.org>
+  +tor-0.2.3.11_alpha.ebuild,
+  +files/tor-0.2.3.11_alpha-fix-tor-fw-helper-natpmp.patch:
+  Version bump alpha
 
   24 Jan 2012; Anthony G. Basile <blueness@gentoo.org> -tor-0.2.2.34.ebuild:
   Removed old vulnerable stable version



1.1                  net-misc/tor/tor-0.2.3.11_alpha.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.3.11_alpha.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/tor-0.2.3.11_alpha.ebuild?rev=1.1&content-type=text/plain

Index: tor-0.2.3.11_alpha.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/tor-0.2.3.11_alpha.ebuild,v 1.1 2012/01/24 13:06:55 blueness Exp $

EAPI="4"

inherit eutils flag-o-matic versionator

MY_PV="$(replace_version_separator 4 -)"
MY_PF="${PN}-${MY_PV}"
DESCRIPTION="Anonymizing overlay network for TCP"
HOMEPAGE="http://www.torproject.org/"
SRC_URI="http://www.torproject.org/dist/${MY_PF}.tar.gz"
S="${WORKDIR}/${MY_PF}"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
IUSE="+bufferevents doc nat-pmp tor-hardening transparent-proxy threads upnp"

DEPEND="dev-libs/openssl
	>=dev-libs/libevent-2.0.14
	nat-pmp? ( net-libs/libnatpmp )
	upnp? ( <net-libs/miniupnpc-1.6 )"
RDEPEND="${DEPEND}"

pkg_setup() {
	enewgroup tor
	enewuser tor -1 -1 /var/lib/tor tor
}

src_prepare() {
	epatch "${FILESDIR}"/torrc.sample.patch
	epatch "${FILESDIR}"/${P}-fix-tor-fw-helper-natpmp.patch
}

src_configure() {
	# Upstream isn't sure of all the user provided CFLAGS that
	# will break tor, but does recommend against -fstrict-aliasing.
	# We'll filter-flags them here as we encounter them.
	filter-flags -fstrict-aliasing
	econf --docdir=/usr/share/doc/${PF} \
		$(use_enable bufferevents) \
		$(use_enable doc asciidoc) \
		$(use_enable nat-pmp) \
		$(use_enable tor-hardening gcc-hardening) \
		$(use_enable tor-hardening linker-hardening) \
		$(use_enable transparent-proxy transparent) \
		$(use_enable threads) \
		$(use_enable upnp)
}

src_install() {
	newconfd "${FILESDIR}"/tor.confd tor
	newinitd "${FILESDIR}"/tor.initd-r6 tor
	emake DESTDIR="${D}" install
	keepdir /var/lib/tor

	dodoc README ChangeLog ReleaseNotes \
		doc/{HACKING,TODO} \
		doc/spec/README

	fperms 750 /var/lib/tor
	fowners tor:tor /var/lib/tor

	insinto /etc/tor/
	newins "${FILESDIR}"/torrc-r1 torrc
}

pkg_postinst() {
	elog
	elog "We created a configuration file for tor, /etc/tor/torrc, but you can"
	elog "change it according to your needs.  Use the torrc.sample that is in"
	elog "that directory as a guide.  Also, to have privoxy work with tor"
	elog "just add the following line"
	elog
	elog "forward-socks4a / localhost:9050 ."
	elog
	elog "to /etc/privoxy/config.  Notice the . at the end!"
	elog
}

[gentoo-commits] gentoo-x86 commit in net-misc/tor: ChangeLog tor-0.2.3.11_alpha.ebuild

[Anthony G. Basile (blueness)]

blueness    12/03/08 14:50:38

  Modified:             ChangeLog
  Removed:              tor-0.2.3.11_alpha.ebuild
  Log:
  Remove old alpha version
  
  (Portage version: 2.1.10.44/cvs/Linux x86_64)

Revision  Changes    Path
1.321                net-misc/tor/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.321&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?rev=1.321&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-misc/tor/ChangeLog?r1=1.320&r2=1.321

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v
retrieving revision 1.320
retrieving revision 1.321
diff -u -r1.320 -r1.321
--- ChangeLog	14 Feb 2012 22:32:37 -0000	1.320
+++ ChangeLog	8 Mar 2012 14:50:38 -0000	1.321
@@ -1,6 +1,10 @@
 # ChangeLog for net-misc/tor
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.320 2012/02/14 22:32:37 blueness Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-misc/tor/ChangeLog,v 1.321 2012/03/08 14:50:38 blueness Exp $
+
+  08 Mar 2012; Anthony G. Basile <blueness@gentoo.org>
+  -tor-0.2.3.11_alpha.ebuild:
+  Remove old alpha version
 
 *tor-0.2.3.12_alpha-r1 (14 Feb 2012)