* [gentoo-commits] gentoo-x86 commit in app-emulation/qemu: qemu-1.0.1.ebuild ChangeLog
@ 2012-03-03 17:19 Luca Barbato (lu_zero)
0 siblings, 0 replies; 3+ messages in thread
From: Luca Barbato (lu_zero) @ 2012-03-03 17:19 UTC (permalink / raw
To: gentoo-commits
lu_zero 12/03/03 17:19:52
Modified: ChangeLog
Added: qemu-1.0.1.ebuild
Log:
New version
(Portage version: 2.2.0_alpha89/cvs/Linux x86_64)
Revision Changes Path
1.107 app-emulation/qemu/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?rev=1.107&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?rev=1.107&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?r1=1.106&r2=1.107
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v
retrieving revision 1.106
retrieving revision 1.107
diff -u -r1.106 -r1.107
--- ChangeLog 1 Mar 2012 23:38:13 -0000 1.106
+++ ChangeLog 3 Mar 2012 17:19:52 -0000 1.107
@@ -1,6 +1,11 @@
# ChangeLog for app-emulation/qemu
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.106 2012/03/01 23:38:13 ranger Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.107 2012/03/03 17:19:52 lu_zero Exp $
+
+*qemu-1.0.1 (03 Mar 2012)
+
+ 03 Mar 2012; Luca Barbato <lu_zero@gentoo.org> +qemu-1.0.1.ebuild:
+ New version
01 Mar 2012; Brent Baude <ranger@gentoo.org> qemu-0.11.1.ebuild:
Marking qemu-0.11.1 ppc for bug 356685
1.1 app-emulation/qemu/qemu-1.0.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild?rev=1.1&content-type=text/plain
Index: qemu-1.0.1.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild,v 1.1 2012/03/03 17:19:52 lu_zero Exp $
EAPI=4
if [[ ${PV} = *9999* ]]; then
EGIT_REPO_URI="git://git.qemu.org/qemu.git
http://git.qemu.org/git/qemu.git"
GIT_ECLASS="git-2"
fi
inherit eutils flag-o-matic ${GIT_ECLASS} linux-info toolchain-funcs
if [[ ${PV} != *9999* ]]; then
SRC_URI="http://wiki.qemu.org/download/${P}.tar.gz
http://dev.gentoo.org/~lu_zero/distfiles/${PN}-1.0-patches.tar.xz"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
fi
DESCRIPTION="QEMU emulator and ABI wrapper"
HOMEPAGE="http://www.qemu.org"
LICENSE="GPL-2"
SLOT="0"
IUSE="+aio alsa bluetooth brltty curl esd fdt hardened jpeg kvm ncurses nss
opengl png pulseaudio qemu-ifup rbd sasl sdl spice ssl static threads usbredir vde
+vhost-net xattr xen xfs"
COMMON_TARGETS="i386 x86_64 alpha arm cris m68k microblaze microblazeel mips mipsel ppc ppc64 sh4 sh4eb sparc sparc64 s390x"
IUSE_SOFTMMU_TARGETS="${COMMON_TARGETS} lm32 mips64 mips64el ppcemb xtensa xtensaeb"
IUSE_USER_TARGETS="${COMMON_TARGETS} armeb ppc64abi32 sparc32plus unicore32"
for target in ${IUSE_SOFTMMU_TARGETS}; do
IUSE="${IUSE} +qemu_softmmu_targets_${target}"
done
for target in ${IUSE_USER_TARGETS}; do
IUSE="${IUSE} +qemu_user_targets_${target}"
done
RESTRICT="test"
RDEPEND="
!app-emulation/qemu-kvm
!app-emulation/qemu-user
>=dev-libs/glib-2.0
sys-apps/pciutils
>=sys-apps/util-linux-2.16.0
sys-libs/zlib
aio? ( dev-libs/libaio )
alsa? ( >=media-libs/alsa-lib-1.0.13 )
bluetooth? ( net-wireless/bluez )
brltty? ( app-accessibility/brltty )
curl? ( net-misc/curl )
esd? ( media-sound/esound )
fdt? ( >=sys-apps/dtc-1.2.0 )
jpeg? ( virtual/jpeg )
ncurses? ( sys-libs/ncurses )
nss? ( dev-libs/nss )
opengl? (
virtual/opengl
x11-libs/libX11
)
png? ( media-libs/libpng )
pulseaudio? ( media-sound/pulseaudio )
qemu-ifup? (
sys-apps/iproute2
net-misc/bridge-utils
)
rbd? ( sys-cluster/ceph )
sasl? ( dev-libs/cyrus-sasl )
sdl? ( >=media-libs/libsdl-1.2.11[X] )
spice? (
>=app-emulation/spice-0.9.0
>=app-emulation/spice-protocol-0.8.1
)
ssl? ( net-libs/gnutls )
usbredir? ( sys-apps/usbredir )
vde? ( net-misc/vde )
xattr? ( sys-apps/attr )
xen? ( app-emulation/xen-tools )
xfs? ( sys-fs/xfsprogs )
"
DEPEND="${RDEPEND}
app-text/texi2html
dev-util/pkgconfig
>=sys-kernel/linux-headers-2.6.35
"
# alpha ELF binary. don't let portage mess with it
STRIP_MASK="usr/share/qemu/palcode-clipper"
QA_PRESTRIPPED="
usr/share/qemu/openbios-ppc
usr/share/qemu/openbios-sparc64
usr/share/qemu/openbios-sparc32
usr/share/qemu/palcode-clipper
"
# keep sorted
QA_WX_LOAD="${QA_PRESTRIPPED}
usr/bin/qemu-alpha
usr/bin/qemu-arm
usr/bin/qemu-armeb
usr/bin/qemu-cris
usr/bin/qemu-i386
usr/bin/qemu-m68k
usr/bin/qemu-microblaze
usr/bin/qemu-microblazeel
usr/bin/qemu-mips
usr/bin/qemu-mipsel
usr/bin/qemu-ppc
usr/bin/qemu-ppc64
usr/bin/qemu-ppc64abi32
usr/bin/qemu-sh4
usr/bin/qemu-sh4eb
usr/bin/qemu-sparc
usr/bin/qemu-sparc32plus
usr/bin/qemu-sparc64
usr/bin/qemu-s390x
usr/bin/qemu-unicore32
usr/bin/qemu-x86_64
"
pkg_setup() {
use qemu_softmmu_targets_x86_64 || ewarn "You disabled default target QEMU_SOFTMMU_TARGETS=x86_64"
use kvm && ewarn "You have enabled USE=kvm feature. Please consider using app-emulation/qemu-kvm"
}
src_prepare() {
EPATCH_SOURCE="${WORKDIR}/patches" EPATCH_SUFFIX="patch" \
EPATCH_EXCLUDE="0033-PPC-Fix-linker-scripts-on-ppc-hosts.patch" \
EPATCH_FORCE="yes" epatch
# prevent docs to get automatically installed
sed -i '/$(DESTDIR)$(docdir)/d' Makefile || die
# Fix underlinking.
# Fault reproducer: USE=nss QEMU_SOFTMMU_TARGETS=lm32 QEMU_USER_TARGETS=
sed -i 's/opengl_libs="-lGL"/opengl_libs="-lGL -lX11"/' configure || die
}
src_configure() {
local conf_opts audio_opts user_targets
for target in ${IUSE_SOFTMMU_TARGETS} ; do
use "qemu_softmmu_targets_${target}" && \
softmmu_targets="${softmmu_targets} ${target}-softmmu"
done
for target in ${IUSE_USER_TARGETS} ; do
use "qemu_user_targets_${target}" && \
user_targets="${user_targets} ${target}-linux-user"
done
if [[ -z ${softmmu_targets} ]]; then
conf_opts="${conf_opts} --disable-system"
else
einfo "Building the following softmmu targets: ${softmmu_targets}"
fi
if [[ -n ${user_targets} ]]; then
einfo "Building the following user targets: ${user_targets}"
conf_opts="${conf_opts} --enable-linux-user"
else
conf_opts="${conf_opts} --disable-linux-user"
fi
# Fix QA issues. QEMU needs executable heaps and we need to mark it as such
conf_opts="${conf_opts} --extra-ldflags=-Wl,-z,execheap"
# drop '-g' by default as it tends to eat
# A LOT (~2GB) of ram for each job #355861
conf_opts="${conf_opts} --disable-debug-info"
# Add support for static builds
use static && conf_opts="${conf_opts} --static"
#config options
conf_opts="${conf_opts}
$(use_enable aio linux-aio)
$(use_enable bluetooth bluez)
$(use_enable brltty brlapi)
$(use_enable curl)
$(use_enable fdt)
$(use_enable hardened pie)
$(use_enable jpeg vnc-jpeg)
$(use_enable ncurses curses)
$(use_enable nss smartcard-nss)
$(use_enable opengl)
$(use_enable png vnc-png)
$(use_enable rbd)
$(use_enable sasl vnc-sasl)
$(use_enable sdl)
$(use_enable spice)
$(use_enable ssl vnc-tls)
$(use_enable threads vnc-thread)
$(use_enable vde)
$(use_enable vhost-net)
$(use_enable xen)
$(use_enable xattr attr)
$(use_enable xfs xfsctl)
--disable-darwin-user --disable-bsd-user
"
# audio options
audio_opts="oss"
use alsa && audio_opts="alsa ${audio_opts}"
use esd && audio_opts="esd ${audio_opts}"
use pulseaudio && audio_opts="pa ${audio_opts}"
use sdl && audio_opts="sdl ${audio_opts}"
set -- --prefix="${EPREFIX}"/usr \
--sysconfdir="${EPREFIX}"/etc \
--disable-strip \
--disable-werror \
$(use_enable kvm) \
--disable-libiscsi \
--enable-nptl \
--enable-uuid \
${conf_opts} \
--audio-card-list="ac97 es1370 sb16 cs4231a adlib gus hda" \
--audio-drv-list="${audio_opts}" \
--target-list="${softmmu_targets} ${user_targets}" \
--cc="$(tc-getCC)" \
--host-cc="$(tc-getBUILD_CC)"
echo ./configure "$@" # show actual options
./configure "$@" || die "configure failed"
}
src_install() {
emake DESTDIR="${D}" install || die "make install failed"
if [[ -n ${softmmu_targets} ]]; then
if use qemu-ifup; then
exeinto /etc/qemu
doexe "${FILESDIR}"/qemu-if{up,down}
fi
fi
dodoc Changelog MAINTAINERS TODO pci-ids.txt
newdoc pc-bios/README README.pc-bios
dohtml qemu-doc.html qemu-tech.html
}
pkg_postinst() {
use qemu-ifup || return
elog "You will need the Universal TUN/TAP driver compiled into your"
elog "kernel or loaded as a module to use the virtual network device"
elog "if using -net tap. You will also need support for 802.1d"
elog "Ethernet Bridging and a configured bridge if using the provided"
elog "qemu-ifup script from /etc/qemu."
echo
}
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/qemu: qemu-1.0.1.ebuild ChangeLog
@ 2012-03-07 17:10 Sergei Trofimovich (slyfox)
0 siblings, 0 replies; 3+ messages in thread
From: Sergei Trofimovich (slyfox) @ 2012-03-07 17:10 UTC (permalink / raw
To: gentoo-commits
slyfox 12/03/07 17:10:57
Modified: qemu-1.0.1.ebuild ChangeLog
Log:
Added patces from upstream for '--disable-debug-info' and '--enable-xfsctl'. Fixes configure failure (bug #406851 by Markus Peloquin and others).
(Portage version: 2.2.0_alpha90/cvs/Linux x86_64)
Revision Changes Path
1.2 app-emulation/qemu/qemu-1.0.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild?r1=1.1&r2=1.2
Index: qemu-1.0.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- qemu-1.0.1.ebuild 3 Mar 2012 17:19:52 -0000 1.1
+++ qemu-1.0.1.ebuild 7 Mar 2012 17:10:57 -0000 1.2
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild,v 1.1 2012/03/03 17:19:52 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild,v 1.2 2012/03/07 17:10:57 slyfox Exp $
EAPI=4
@@ -135,6 +135,9 @@
EPATCH_EXCLUDE="0033-PPC-Fix-linker-scripts-on-ppc-hosts.patch" \
EPATCH_FORCE="yes" epatch
+ epatch "${FILESDIR}"/${PN}-1.0-unmagic-debug.patch
+ epatch "${FILESDIR}"/${PN}-1.0-unmagic-xfsctl.patch
+
# prevent docs to get automatically installed
sed -i '/$(DESTDIR)$(docdir)/d' Makefile || die
1.108 app-emulation/qemu/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?rev=1.108&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?rev=1.108&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?r1=1.107&r2=1.108
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v
retrieving revision 1.107
retrieving revision 1.108
diff -u -r1.107 -r1.108
--- ChangeLog 3 Mar 2012 17:19:52 -0000 1.107
+++ ChangeLog 7 Mar 2012 17:10:57 -0000 1.108
@@ -1,6 +1,12 @@
# ChangeLog for app-emulation/qemu
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.107 2012/03/03 17:19:52 lu_zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.108 2012/03/07 17:10:57 slyfox Exp $
+
+ 07 Mar 2012; Sergei Trofimovich <slyfox@gentoo.org>
+ +files/qemu-1.0-unmagic-debug.patch, +files/qemu-1.0-unmagic-xfsctl.patch,
+ qemu-1.0.1.ebuild:
+ Added patces from upstream for '--disable-debug-info' and '--enable-xfsctl'.
+ Fixes configure failure (bug #406851 by Markus Peloquin and others).
*qemu-1.0.1 (03 Mar 2012)
^ permalink raw reply [flat|nested] 3+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/qemu: qemu-1.0.1.ebuild ChangeLog
@ 2012-08-18 17:24 Mike Frysinger (vapier)
0 siblings, 0 replies; 3+ messages in thread
From: Mike Frysinger (vapier) @ 2012-08-18 17:24 UTC (permalink / raw
To: gentoo-commits
vapier 12/08/18 17:24:16
Modified: qemu-1.0.1.ebuild ChangeLog
Log:
Add fix from upstream for building with newer kernel headers.
(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)
Revision Changes Path
1.6 app-emulation/qemu/qemu-1.0.1.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild?rev=1.6&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild?rev=1.6&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild?r1=1.5&r2=1.6
Index: qemu-1.0.1.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild,v
retrieving revision 1.5
retrieving revision 1.6
diff -u -r1.5 -r1.6
--- qemu-1.0.1.ebuild 3 May 2012 18:49:05 -0000 1.5
+++ qemu-1.0.1.ebuild 18 Aug 2012 17:24:16 -0000 1.6
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild,v 1.5 2012/05/03 18:49:05 jdhore Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/qemu-1.0.1.ebuild,v 1.6 2012/08/18 17:24:16 vapier Exp $
EAPI=4
@@ -138,6 +138,7 @@
epatch "${FILESDIR}"/${PN}-1.0-unmagic-debug.patch
epatch "${FILESDIR}"/${PN}-1.0-unmagic-xfsctl.patch
+ epatch "${FILESDIR}"/${P}-siginfo.patch
# prevent docs to get automatically installed
sed -i '/$(DESTDIR)$(docdir)/d' Makefile || die
1.114 app-emulation/qemu/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?rev=1.114&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?rev=1.114&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu/ChangeLog?r1=1.113&r2=1.114
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v
retrieving revision 1.113
retrieving revision 1.114
diff -u -r1.113 -r1.114
--- ChangeLog 10 Jun 2012 20:15:57 -0000 1.113
+++ ChangeLog 18 Aug 2012 17:24:16 -0000 1.114
@@ -1,6 +1,10 @@
# ChangeLog for app-emulation/qemu
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.113 2012/06/10 20:15:57 slyfox Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu/ChangeLog,v 1.114 2012/08/18 17:24:16 vapier Exp $
+
+ 18 Aug 2012; Mike Frysinger <vapier@gentoo.org>
+ +files/qemu-1.0.1-siginfo.patch, qemu-1.0.1.ebuild:
+ Add fix from upstream for building with newer kernel headers.
10 Jun 2012; Sergei Trofimovich <slyfox@gentoo.org> qemu-9999.ebuild:
Drop '--disable-darwin-user' from configure params. Upstream does not export
@@ -480,4 +484,3 @@
03 Jan 2004; Chuck Short <zul@gentoo.org> qemu-0.5.1.ebuild:
Initial version, ebuild submitted by Jocelyn Mayer <l_indien -at- magic.fr>
Ebuild modified by me. Closes #37047.
-
^ permalink raw reply [flat|nested] 3+ messages in thread
end of thread, other threads:[~2012-08-18 17:24 UTC | newest]
Thread overview: 3+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-03-07 17:10 [gentoo-commits] gentoo-x86 commit in app-emulation/qemu: qemu-1.0.1.ebuild ChangeLog Sergei Trofimovich (slyfox)
-- strict thread matches above, loose matches on Subject: below --
2012-08-18 17:24 Mike Frysinger (vapier)
2012-03-03 17:19 Luca Barbato (lu_zero)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox