* [gentoo-commits] gentoo-x86 commit in app-emulation/qemu-kvm: metadata.xml ChangeLog qemu-kvm-1.0-r3.ebuild
@ 2012-02-19 23:19 Doug Goldstein (cardoe)
0 siblings, 0 replies; 2+ messages in thread
From: Doug Goldstein (cardoe) @ 2012-02-19 23:19 UTC (permalink / raw
To: gentoo-commits
cardoe 12/02/19 23:19:22
Modified: metadata.xml ChangeLog
Added: qemu-kvm-1.0-r3.ebuild
Log:
Major overhaul to the qemu-kvm ebuild to clean up depends, messages, and support for missing features.
(Portage version: 2.1.10.44/cvs/Linux x86_64)
Revision Changes Path
1.14 app-emulation/qemu-kvm/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/metadata.xml?rev=1.14&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/metadata.xml?rev=1.14&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/metadata.xml?r1=1.13&r2=1.14
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/metadata.xml,v
retrieving revision 1.13
retrieving revision 1.14
diff -u -r1.13 -r1.14
--- metadata.xml 23 Jan 2012 22:10:14 -0000 1.13
+++ metadata.xml 19 Feb 2012 23:19:22 -0000 1.14
@@ -19,6 +19,7 @@
<flag name='sdl'>Enable the SDL-based console</flag>
<flag name='spice'>Enable Spice protocol support via <pkg>app-emulation/spice</pkg></flag>
<flag name='ssl'>Enable TLS support for the VNC console server</flag>
+ <flag name='tls'>Enable TLS support for the VNC console server</flag>
<flag name="usbredir">Use <pkg>sys-apps/usbredir</pkg> to redirect USB
devices to another machine over TCP</flag>
<flag name='vde'>Enable VDE-based networking</flag>
1.99 app-emulation/qemu-kvm/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/ChangeLog?rev=1.99&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/ChangeLog?rev=1.99&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/ChangeLog?r1=1.98&r2=1.99
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/ChangeLog,v
retrieving revision 1.98
retrieving revision 1.99
diff -u -r1.98 -r1.99
--- ChangeLog 16 Feb 2012 19:09:18 -0000 1.98
+++ ChangeLog 19 Feb 2012 23:19:22 -0000 1.99
@@ -1,6 +1,13 @@
# ChangeLog for app-emulation/qemu-kvm
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/ChangeLog,v 1.98 2012/02/16 19:09:18 phajdan.jr Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/ChangeLog,v 1.99 2012/02/19 23:19:22 cardoe Exp $
+
+*qemu-kvm-1.0-r3 (19 Feb 2012)
+
+ 19 Feb 2012; Doug Goldstein <cardoe@gentoo.org> +qemu-kvm-1.0-r3.ebuild,
+ metadata.xml:
+ Major overhaul to the qemu-kvm ebuild to clean up depends, messages, and
+ support for missing features.
16 Feb 2012; Pawel Hajdan jr <phajdan.jr@gentoo.org>
qemu-kvm-0.15.1-r1.ebuild:
1.1 app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild?rev=1.1&content-type=text/plain
Index: qemu-kvm-1.0-r3.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild,v 1.1 2012/02/19 23:19:22 cardoe Exp $
#BACKPORTS=1
EAPI="3"
if [[ ${PV} = *9999* ]]; then
EGIT_REPO_URI="git://git.kernel.org/pub/scm/virt/kvm/qemu-kvm.git"
GIT_ECLASS="git-2"
fi
inherit eutils flag-o-matic ${GIT_ECLASS} linux-info toolchain-funcs multilib python
if [[ ${PV} = *9999* ]]; then
SRC_URI=""
KEYWORDS=""
else
SRC_URI="mirror://sourceforge/kvm/${PN}/${P}.tar.gz
${BACKPORTS:+
http://dev.gentoo.org/~flameeyes/${PN}/${P}-backports-${BACKPORTS}.tar.bz2
http://dev.gentoo.org/~cardoe/distfiles/${P}-backports-${BACKPORTS}.tar.bz2}"
KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
fi
DESCRIPTION="QEMU + Kernel-based Virtual Machine userland tools"
HOMEPAGE="http://www.linux-kvm.org"
LICENSE="GPL-2"
SLOT="0"
# xen is disabled until the deps are fixed
IUSE="+aio alsa bluetooth brltty curl debug esd fdt ncurses \
opengl pulseaudio qemu-ifup rbd sasl sdl smartcard spice +threads tls \
usbredir vde +vhost-net xattr xen"
# static, depends on libsdl being built with USE=static-libs, which can not
# be expressed in current EAPI's
COMMON_TARGETS="i386 x86_64 arm cris m68k microblaze mips mipsel ppc ppc64 sh4 sh4eb sparc sparc64"
IUSE_SOFTMMU_TARGETS="${COMMON_TARGETS} mips64 mips64el ppcemb"
IUSE_USER_TARGETS="${COMMON_TARGETS} alpha armeb ppc64abi32 sparc32plus"
# Setup the default SoftMMU targets, while using the loops
# below to setup the other targets. x86_64 should be the only
# defaults on for qemu-kvm
IUSE="${IUSE} +qemu_softmmu_targets_x86_64"
for target in ${IUSE_SOFTMMU_TARGETS}; do
if [ "x${target}" = "xx86_64" ]; then
continue
fi
IUSE="${IUSE} qemu_softmmu_targets_${target}"
done
for target in ${IUSE_USER_TARGETS}; do
IUSE="${IUSE} qemu_user_targets_${target}"
done
RDEPEND="
!app-emulation/kqemu
!app-emulation/qemu
!app-emulation/qemu-user
>=dev-libs/glib-2.0
media-libs/libpng
sys-apps/pciutils
>=sys-apps/util-linux-2.16.0
sys-libs/zlib
virtual/jpeg
amd64? ( sys-apps/seabios
sys-apps/vgabios )
x86? ( sys-apps/seabios
sys-apps/vgabios )
aio? ( dev-libs/libaio )
alsa? ( >=media-libs/alsa-lib-1.0.13 )
bluetooth? ( net-wireless/bluez )
brltty? ( app-accessibility/brltty )
curl? ( >=net-misc/curl-7.15.4 )
esd? ( media-sound/esound )
fdt? ( >=sys-apps/dtc-1.2.0 )
ncurses? ( sys-libs/ncurses )
opengl? ( virtual/opengl )
pulseaudio? ( media-sound/pulseaudio )
qemu-ifup? ( sys-apps/iproute2 net-misc/bridge-utils )
rbd? ( sys-cluster/ceph )
sasl? ( dev-libs/cyrus-sasl )
sdl? ( >=media-libs/libsdl-1.2.11[X] )
smartcard? ( dev-libs/nss )
spice? ( >=app-emulation/spice-0.9.0
>=app-emulation/spice-protocol-0.8.1 )
tls? ( net-libs/gnutls )
usbredir? ( sys-apps/usbredir )
vde? ( net-misc/vde )
xattr? ( sys-apps/attr )
xen? ( app-emulation/xen-tools )
"
DEPEND="${RDEPEND}
app-text/texi2html
dev-util/pkgconfig
>=sys-kernel/linux-headers-2.6.35
test? ( dev-libs/check )"
STRIP_MASK="/usr/share/qemu/palcode-clipper"
QA_PRESTRIPPED="
usr/share/qemu/openbios-ppc
usr/share/qemu/openbios-sparc64
usr/share/qemu/openbios-sparc32
usr/share/qemu/palcode-clipper"
QA_WX_LOAD="${QA_PRESTRIPPED}
usr/bin/qemu-i386
usr/bin/qemu-x86_64
usr/bin/qemu-alpha
usr/bin/qemu-arm
usr/bin/qemu-cris
usr/bin/qemu-m68k
usr/bin/qemu-microblaze
usr/bin/qemu-mips
usr/bin/qemu-mipsel
usr/bin/qemu-ppc
usr/bin/qemu-ppc64
usr/bin/qemu-ppc64abi32
usr/bin/qemu-sh4
usr/bin/qemu-sh4eb
usr/bin/qemu-sparc
usr/bin/qemu-sparc64
usr/bin/qemu-armeb
usr/bin/qemu-sparc32plus"
pkg_pretend() {
if ! use qemu_softmmu_targets_x86_64 && use amd64 ; then
eerror "You disabled default target QEMU_SOFTMMU_TARGETS=x86_64"
fi
if ! use qemu_softmmu_targets_x86_64 && use x86 ; then
eerror "You disabled default target QEMU_SOFTMMU_TARGETS=x86_64"
fi
if kernel_is lt 2 6 25; then
eerror "This version of KVM requres a host kernel of 2.6.25 or higher."
eerror "Either upgrade your kernel"
else
if ! linux_config_exists; then
eerror "Unable to check your kernel for KVM support"
else
CONFIG_CHECK="KVM KVM_AMD KVM_INTEL ~TUN ~BRIDGE"
ERROR_KVM="You must enable KVM in your kernel to continue"
ERROR_KVM_AMD="If you have an AMD CPU, you must enable KVM_AMD in \
your kernel configuration."
ERROR_KVM_INTEL="If you have an Intel CPU, you must enable \
KVM_INTEL in your kernel configuration."
ERROR_TUN="You will need the Universal TUN/TAP driver compiled \
into your kernel or loaded as a module to use the virtual \
network device if using -net tap."
ERROR_BRIDGE="You will also need support for 802.1d \
Ethernet Bridging for some network configurations."
use vhost-net && CHECK_CHECK+="~VHOST_NET"
ERROR_VHOST_NET="You must enable VHOST_NET to have vhost-net \
support"
# Now do the actual checks setup above
check_extra_config
fi
fi
}
pkg_setup() {
python_set_active_version 2
enewgroup kvm
}
src_prepare() {
# prevent docs to get automatically installed
sed -i '/$(DESTDIR)$(docdir)/d' Makefile || die
# Alter target makefiles to accept CFLAGS set via flag-o
sed -i 's/^\(C\|OP_C\|HELPER_C\)FLAGS=/\1FLAGS+=/' \
Makefile Makefile.target || die
# append CFLAGS while linking
sed -i 's/$(LDFLAGS)/$(QEMU_CFLAGS) $(CFLAGS) $(LDFLAGS)/' rules.mak || die
# remove part to make udev happy
sed -e 's~NAME="%k", ~~' -i kvm/scripts/65-kvm.rules || die
# ${PN}-guest-hang-on-usb-add.patch was sent by Timothy Jones
# to the qemu-devel ml - bug 337988
epatch "${FILESDIR}/qemu-0.11.0-mips64-user-fix.patch"
# drop '-g' by default as it tends to eat
# A LOT (~2GB) of ram for each job #355861
sed -e 's/CFLAGS="-g $CFLAGS"/CFLAGS="$CFLAGS"/g' \
-i configure || die
epatch "${FILESDIR}"/${PN}-1.0-per-target-i8259.patch #400597
epatch "${FILESDIR}"/${PN}-1.0-fix-nonkvm-arches.patch
epatch "${FILESDIR}"/${PN}-1.0-fix-qemu-system-ppc.patch
# bug #400595 / CVE-2012-0029
epatch "${FILESDIR}"/${P}-e1000-bounds-packet-size-against-buffer-size.patch
[[ -n ${BACKPORTS} ]] && \
EPATCH_FORCE=yes EPATCH_SUFFIX="patch" EPATCH_SOURCE="${S}/patches" \
epatch
}
src_configure() {
local conf_opts audio_opts user_targets
for target in ${IUSE_SOFTMMU_TARGETS} ; do
use "qemu_softmmu_targets_${target}" && \
softmmu_targets="${softmmu_targets} ${target}-softmmu"
done
for target in ${IUSE_USER_TARGETS} ; do
use "qemu_user_targets_${target}" && \
user_targets="${user_targets} ${target}-linux-user"
done
if [[ -z ${softmmu_targets} ]]; then
eerror "All SoftMMU targets are disabled. This is invalid for qemu-kvm"
die "At least 1 SoftMMU target must be enabled"
else
einfo "Building the following softmmu targets: ${softmmu_targets}"
fi
if [[ -n ${user_targets} ]]; then
einfo "Building the following user targets: ${user_targets}"
conf_opts="${conf_opts} --enable-linux-user"
else
conf_opts="${conf_opts} --disable-linux-user"
fi
# Fix QA issues. QEMU needs executable heaps and we need to mark it as such
conf_opts="${conf_opts} --extra-ldflags=-Wl,-z,execheap"
# Add support for static builds
#use static && conf_opts="${conf_opts} --static"
# Support debug USE flag
use debug && conf_opts="${conf_opts} --enable-debug"
# audio options
audio_opts="oss"
use alsa && audio_opts="alsa ${audio_opts}"
use esd && audio_opts="esd ${audio_opts}"
use pulseaudio && audio_opts="pa ${audio_opts}"
use sdl && audio_opts="sdl ${audio_opts}"
./configure --prefix=/usr \
--sysconfdir=/etc \
--disable-darwin-user \
--disable-bsd-user \
--disable-libiscsi \
--disable-strip \
--disable-werror \
--enable-kvm \
--enable-kvm-device-assignment \
--enable-kvm-pit \
--enable-pie \
--enable-nptl \
--enable-tcg-interpreter \
--enable-uuid \
--enable-vnc-jpeg \
--enable-vnc-png \
--python=python2 \
$(use_enable aio linux-aio) \
$(use_enable bluetooth bluez) \
$(use_enable brltty brlapi) \
$(use_enable curl) \
$(use_enable fdt) \
$(use_enable ncurses curses) \
$(use_enable opengl) \
$(use_enable rbd) \
$(use_enable sasl vnc-sasl) \
$(use_enable sdl) \
$(use_enable smartcard smartcard) \
$(use_enable smartcard smartcard-nss) \
$(use_enable spice) \
$(use_enable test check-utests) \
$(use_enable tls vnc-tls) \
$(use_enable threads vnc-thread) \
$(use_enable usbredir usb-redir) \
$(use_enable vde) \
$(use_enable vhost-net) \
$(use_enable xen) \
$(use_enable xattr attr) \
--audio-drv-list="${audio_opts}" \
--target-list="${softmmu_targets} ${user_targets}" \
--cc="$(tc-getCC)" \
--host-cc="$(tc-getBUILD_CC)" \
|| die "configure failed"
# this is for qemu upstream's threaded support which is
# in development and broken
# the kvm project has its own support for threaded IO
# which is always on and works
# --enable-io-thread \
}
src_install() {
emake DESTDIR="${D}" install || die "make install failed"
if [[ -n ${softmmu_targets} ]]; then
insinto /lib/udev/rules.d/
doins kvm/scripts/65-kvm.rules || die
if use qemu-ifup; then
insinto /etc/qemu/
insopts -m0755
doins kvm/scripts/qemu-ifup || die
fi
if use qemu_softmmu_targets_x86_64 ; then
dobin "${FILESDIR}"/qemu-kvm
ewarn "The depreciated '/usr/bin/kvm' symlink is no longer installed"
ewarn "You should use '/usr/bin/qemu-kvm', you may need to edit"
ewarn "your libvirt configs or other wrappers for ${PN}"
else
elog "You disabled QEMU_SOFTMMU_TARGETS=x86_64, this disables install"
elog "of /usr/bin/qemu-kvm and /usr/bin/kvm"
fi
fi
dodoc Changelog MAINTAINERS TODO pci-ids.txt || die
newdoc pc-bios/README README.pc-bios || die
dohtml qemu-doc.html qemu-tech.html || die
# FIXME: Need to come up with a solution for non-x86 based systems
if use x86 || use amd64; then
# Remove SeaBIOS since we're using the SeaBIOS packaged one
rm "${D}/usr/share/qemu/bios.bin"
dosym ../seabios/bios.bin /usr/share/qemu/bios.bin
# Remove vgabios since we're using the vgabios packaged one
rm "${D}/usr/share/qemu/vgabios.bin"
rm "${D}/usr/share/qemu/vgabios-cirrus.bin"
rm "${D}/usr/share/qemu/vgabios-qxl.bin"
rm "${D}/usr/share/qemu/vgabios-stdvga.bin"
rm "${D}/usr/share/qemu/vgabios-vmware.bin"
dosym ../vgabios/vgabios.bin /usr/share/qemu/vgabios.bin
dosym ../vgabios/vgabios-cirrus.bin /usr/share/qemu/vgabios-cirrus.bin
dosym ../vgabios/vgabios-qxl.bin /usr/share/qemu/vgabios-qxl.bin
dosym ../vgabios/vgabios-stdvga.bin /usr/share/qemu/vgabios-stdvga.bin
dosym ../vgabios/vgabios-vmware.bin /usr/share/qemu/vgabios-vmware.bin
fi
}
pkg_postinst() {
if [[ -n ${softmmu_targets} ]]; then
elog "If you don't have kvm compiled into the kernel, make sure you have"
elog "the kernel module loaded before running kvm. The easiest way to"
elog "ensure that the kernel module is loaded is to load it on boot."
elog "For AMD CPUs the module is called 'kvm-amd'"
elog "For Intel CPUs the module is called 'kvm-intel'"
elog "Please review /etc/conf.d/modules for how to load these"
elog
elog "Make sure your user is in the 'kvm' group"
elog "Just run 'gpasswd -a <USER> kvm', then have <USER> re-login."
elog
elog "The ssl USE flag was renamed to tls, so adjust your USE flags."
elog "The nss USE flag was renamed to smartcard, so adjust your USE flags."
fi
use qemu-ifup && \
ewarn "qemu-ifup is deprecated, be prepared for it to disappear next release"
}
^ permalink raw reply [flat|nested] 2+ messages in thread
* [gentoo-commits] gentoo-x86 commit in app-emulation/qemu-kvm: metadata.xml ChangeLog qemu-kvm-1.0-r3.ebuild
@ 2012-03-06 6:19 Doug Goldstein (cardoe)
0 siblings, 0 replies; 2+ messages in thread
From: Doug Goldstein (cardoe) @ 2012-03-06 6:19 UTC (permalink / raw
To: gentoo-commits
cardoe 12/03/06 06:19:28
Modified: metadata.xml ChangeLog qemu-kvm-1.0-r3.ebuild
Log:
Enable curl USE flag by default since HTTP/HTTPS ISOs are a feature people are often confused why it doesn't just work and there is poor docs behind how to enable it since all distros ship with it on by default.
(Portage version: 2.1.10.44/cvs/Linux x86_64)
Revision Changes Path
1.15 app-emulation/qemu-kvm/metadata.xml
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/metadata.xml?rev=1.15&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/metadata.xml?rev=1.15&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/metadata.xml?r1=1.14&r2=1.15
Index: metadata.xml
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/metadata.xml,v
retrieving revision 1.14
retrieving revision 1.15
diff -u -r1.14 -r1.15
--- metadata.xml 19 Feb 2012 23:19:22 -0000 1.14
+++ metadata.xml 6 Mar 2012 06:19:28 -0000 1.15
@@ -6,6 +6,7 @@
<flag name='aio'>Enables support for Linux's Async IO</flag>
<flag name='alsa'>Enable alsa output for sound emulation</flag>
<flag name='brltty'>Adds support for braille displays using brltty</flag>
+ <flag name='curl'>Support ISOs / -cdrom directives vis HTTP or HTTPS.</flag>
<flag name='esd'>Enable esound output for sound emulation</flag>
<flag name='fdt'>Enables firmware device tree support</flag>
<flag name='jpeg'>Enable JPEG compression for the VNC console server</flag>
1.103 app-emulation/qemu-kvm/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/ChangeLog?rev=1.103&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/ChangeLog?rev=1.103&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/ChangeLog?r1=1.102&r2=1.103
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/ChangeLog,v
retrieving revision 1.102
retrieving revision 1.103
diff -u -r1.102 -r1.103
--- ChangeLog 25 Feb 2012 23:12:17 -0000 1.102
+++ ChangeLog 6 Mar 2012 06:19:28 -0000 1.103
@@ -1,6 +1,12 @@
# ChangeLog for app-emulation/qemu-kvm
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/ChangeLog,v 1.102 2012/02/25 23:12:17 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/ChangeLog,v 1.103 2012/03/06 06:19:28 cardoe Exp $
+
+ 06 Mar 2012; Doug Goldstein <cardoe@gentoo.org> qemu-kvm-1.0-r3.ebuild,
+ metadata.xml:
+ Enable curl USE flag by default since HTTP/HTTPS ISOs are a feature people
+ are often confused why it doesn't just work and there is poor docs behind how
+ to enable it since all distros ship with it on by default.
25 Feb 2012; Mike Gilbert <floppym@gentoo.org> qemu-kvm-1.0-r3.ebuild:
Fix zlib dep.
1.5 app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild?rev=1.5&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild?rev=1.5&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild?r1=1.4&r2=1.5
Index: qemu-kvm-1.0-r3.ebuild
===================================================================
RCS file: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild,v
retrieving revision 1.4
retrieving revision 1.5
diff -u -r1.4 -r1.5
--- qemu-kvm-1.0-r3.ebuild 25 Feb 2012 23:12:17 -0000 1.4
+++ qemu-kvm-1.0-r3.ebuild 6 Mar 2012 06:19:28 -0000 1.5
@@ -1,6 +1,6 @@
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild,v 1.4 2012/02/25 23:12:17 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/qemu-kvm/qemu-kvm-1.0-r3.ebuild,v 1.5 2012/03/06 06:19:28 cardoe Exp $
#BACKPORTS=1
@@ -30,7 +30,7 @@
LICENSE="GPL-2"
SLOT="0"
# xen is disabled until the deps are fixed
-IUSE="+aio alsa bluetooth brltty curl debug esd fdt ncurses \
+IUSE="+aio alsa bluetooth brltty +curl debug esd fdt ncurses \
opengl pulseaudio qemu-ifup rbd sasl sdl smartcard spice static test
+threads tls usbredir vde +vhost-net xattr xen"
^ permalink raw reply [flat|nested] 2+ messages in thread
end of thread, other threads:[~2012-03-06 6:19 UTC | newest]
Thread overview: 2+ messages (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-03-06 6:19 [gentoo-commits] gentoo-x86 commit in app-emulation/qemu-kvm: metadata.xml ChangeLog qemu-kvm-1.0-r3.ebuild Doug Goldstein (cardoe)
-- strict thread matches above, loose matches on Subject: below --
2012-02-19 23:19 Doug Goldstein (cardoe)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox