* [gentoo-commits] gentoo-x86 commit in net-libs/webkit-gtk: webkit-gtk-1.6.3-r300.ebuild webkit-gtk-1.6.3-r200.ebuild ChangeLog webkit-gtk-1.6.1-r300.ebuild webkit-gtk-1.6.1-r200.ebuild
@ 2012-02-04 10:04 Pacho Ramos (pacho)
0 siblings, 0 replies; only message in thread
From: Pacho Ramos (pacho) @ 2012-02-04 10:04 UTC (permalink / raw
To: gentoo-commits
pacho 12/02/04 10:04:42
Modified: ChangeLog
Added: webkit-gtk-1.6.3-r300.ebuild
webkit-gtk-1.6.3-r200.ebuild
Removed: webkit-gtk-1.6.1-r300.ebuild
webkit-gtk-1.6.1-r200.ebuild
Log:
Version bump, remove old.
(Portage version: 2.1.10.44/cvs/Linux x86_64)
Revision Changes Path
1.139 net-libs/webkit-gtk/ChangeLog
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/webkit-gtk/ChangeLog?rev=1.139&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/webkit-gtk/ChangeLog?rev=1.139&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/webkit-gtk/ChangeLog?r1=1.138&r2=1.139
Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v
retrieving revision 1.138
retrieving revision 1.139
diff -u -r1.138 -r1.139
--- ChangeLog 18 Jan 2012 21:06:58 -0000 1.138
+++ ChangeLog 4 Feb 2012 10:04:42 -0000 1.139
@@ -1,6 +1,14 @@
# ChangeLog for net-libs/webkit-gtk
# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v 1.138 2012/01/18 21:06:58 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/ChangeLog,v 1.139 2012/02/04 10:04:42 pacho Exp $
+
+*webkit-gtk-1.6.3-r200 (04 Feb 2012)
+*webkit-gtk-1.6.3-r300 (04 Feb 2012)
+
+ 04 Feb 2012; Pacho Ramos <pacho@gentoo.org> +webkit-gtk-1.6.3-r200.ebuild,
+ +webkit-gtk-1.6.3-r300.ebuild, -webkit-gtk-1.6.1-r200.ebuild,
+ -webkit-gtk-1.6.1-r300.ebuild:
+ Version bump, remove old.
18 Jan 2012; Markus Meier <maekke@gentoo.org> webkit-gtk-1.6.1-r301.ebuild:
arm stable, bug #393007
1.1 net-libs/webkit-gtk/webkit-gtk-1.6.3-r300.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.6.3-r300.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.6.3-r300.ebuild?rev=1.1&content-type=text/plain
Index: webkit-gtk-1.6.3-r300.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.6.3-r300.ebuild,v 1.1 2012/02/04 10:04:42 pacho Exp $
EAPI="4"
inherit autotools eutils flag-o-matic eutils virtualx gnome2-utils
MY_P="webkit-${PV}"
DESCRIPTION="Open source web browser engine"
HOMEPAGE="http://www.webkitgtk.org/"
SRC_URI="http://www.webkitgtk.org/${MY_P}.tar.xz"
LICENSE="LGPL-2 LGPL-2.1 BSD"
SLOT="3"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-macos"
# geoclue
IUSE="aqua coverage debug doc +gstreamer +introspection +jit spell webgl"
# bug 372493
REQUIRED_USE="introspection? ( gstreamer )"
# use sqlite, svg by default
# dependency on >=x11-libs/gtk+-2.13:2 for gail
# Aqua support in gtk3 is untested
# gtk2 is needed for plugin process support
RDEPEND="
dev-libs/libxml2:2
dev-libs/libxslt
virtual/jpeg
>=media-libs/libpng-1.4:0
>=x11-libs/cairo-1.10
>=dev-libs/glib-2.27.90:2
>=x11-libs/gtk+-3.0:3[aqua=,introspection?]
>=dev-libs/icu-3.8.1-r1
>=net-libs/libsoup-2.33.6:2.4[introspection?]
dev-db/sqlite:3
>=x11-libs/pango-1.12
x11-libs/libXrender
gstreamer? (
media-libs/gstreamer:0.10
>=media-libs/gst-plugins-base-0.10.30:0.10 )
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
spell? ( >=app-text/enchant-0.22 )
webgl? ( virtual/opengl )
"
DEPEND="${RDEPEND}
>=sys-devel/flex-2.5.33
sys-devel/gettext
virtual/yacc
dev-util/gperf
dev-util/pkgconfig
dev-util/gtk-doc-am
doc? ( >=dev-util/gtk-doc-1.10 )
test? ( x11-themes/hicolor-icon-theme )
"
S="${WORKDIR}/${MY_P}"
src_prepare() {
DOCS="ChangeLog NEWS" # other ChangeLog files handled by src_install
# Fix arches that use 64-bit double type
# https://bugs.webkit.org/show_bug.cgi?id=69940
epatch "${FILESDIR}/${PN}-1.6.1-double-conversion.patch"
# FIXME: Fix unaligned accesses on ARM, IA64 and SPARC
# https://bugs.webkit.org/show_bug.cgi?id=19775
# TODO: FAILS TO APPLY!
#use sparc && epatch "${FILESDIR}"/${PN}-1.2.3-fix-pool-sparc.patch
# intermediate MacPorts hack while upstream bug is not fixed properly
# https://bugs.webkit.org/show_bug.cgi?id=28727
use aqua && epatch "${FILESDIR}"/${PN}-1.6.1-darwin-quartz.patch
# Drop DEPRECATED flags
sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' GNUmakefile.am || die
# Don't force -O2
sed -i 's/-O2//g' "${S}"/configure.ac || die
# Required for webgl; https://bugs.webkit.org/show_bug.cgi?id=69085
mkdir -p DerivedSources/ANGLE
# We need to reset some variables to prevent permissions problems and failures
# like https://bugs.webkit.org/show_bug.cgi?id=35471 and bug #323669
gnome2_environment_reset
# Respect CC, otherwise fails on prefix #395875
tc-export CC
# Prevent maintainer mode from being triggered during make
AT_M4DIR=Source/autotools eautoreconf
}
src_configure() {
# It doesn't compile on alpha without this in LDFLAGS
use alpha && append-ldflags "-Wl,--no-relax"
# Sigbuses on SPARC with mcpu and co.
use sparc && filter-flags "-mcpu=*" "-mvis" "-mtune=*"
# https://bugs.webkit.org/show_bug.cgi?id=42070 , #301634
use ppc64 && append-flags "-mminimal-toc"
local myconf
# XXX: Check Web Audio support
# XXX: files for generating DerivedSources/WebKit2/* are missing, see
# https://bugs.webkit.org/show_bug.cgi?id=66527
myconf="
$(use_enable coverage)
$(use_enable debug)
$(use_enable debug debug-features)
$(use_enable doc gtk-doc)
$(use_enable spell spellcheck)
$(use_enable introspection)
$(use_enable gstreamer video)
$(use_enable jit)
$(use_enable webgl)
--enable-web-sockets
--with-gtk=3.0
--disable-webkit2
$(use aqua && echo "--with-font-backend=pango --with-target=quartz")"
# Aqua support in gtk3 is untested
econf ${myconf}
}
src_compile() {
default
# ${PN} neither ships, nor builds documentation on its own
if use doc; then
emake -C "${S}/Source/WebKit/gtk/docs"
fi
}
src_test() {
unset DISPLAY
# Tests need virtualx, bug #294691, bug #310695
# Parallel tests sometimes fail
Xemake -j1 check
}
src_install() {
default
# ${PN} doesn't install documentation on its own
if use doc; then
emake DESTDIR=${D} -C "${S}/Source/WebKit/gtk/docs" install
fi
newdoc Source/WebKit/gtk/ChangeLog ChangeLog.gtk
newdoc Source/WebKit/gtk/po/ChangeLog ChangeLog.gtk-po
newdoc Source/JavaScriptCore/ChangeLog ChangeLog.JavaScriptCore
newdoc Source/WebCore/ChangeLog ChangeLog.WebCore
# Remove .la files
find "${D}" -name '*.la' -exec rm -f '{}' +
}
1.1 net-libs/webkit-gtk/webkit-gtk-1.6.3-r200.ebuild
file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.6.3-r200.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.6.3-r200.ebuild?rev=1.1&content-type=text/plain
Index: webkit-gtk-1.6.3-r200.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/webkit-gtk/webkit-gtk-1.6.3-r200.ebuild,v 1.1 2012/02/04 10:04:42 pacho Exp $
EAPI="4"
inherit autotools eutils flag-o-matic eutils virtualx gnome2-utils toolchain-funcs
MY_P="webkit-${PV}"
DESCRIPTION="Open source web browser engine"
HOMEPAGE="http://www.webkitgtk.org/"
SRC_URI="http://www.webkitgtk.org/${MY_P}.tar.xz"
LICENSE="LGPL-2 LGPL-2.1 BSD"
SLOT="2"
KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~ia64-linux ~x86-linux ~x86-macos"
# geoclue
IUSE="aqua coverage debug +gstreamer +introspection +jit spell webgl"
# bug 372493
REQUIRED_USE="introspection? ( gstreamer )"
# use sqlite, svg by default
# dependency on >=x11-libs/gtk+-2.13:2 for gail
RDEPEND="
dev-libs/libxml2:2
dev-libs/libxslt
virtual/jpeg
>=media-libs/libpng-1.4:0
>=x11-libs/cairo-1.10
>=dev-libs/glib-2.27.90:2
>=x11-libs/gtk+-2.13:2[aqua=,introspection?]
>=dev-libs/icu-3.8.1-r1
>=net-libs/libsoup-2.33.6:2.4[introspection?]
dev-db/sqlite:3
>=x11-libs/pango-1.12
x11-libs/libXrender
gstreamer? (
media-libs/gstreamer:0.10
>=media-libs/gst-plugins-base-0.10.30:0.10 )
introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
spell? ( >=app-text/enchant-0.22 )
webgl? ( virtual/opengl )
"
DEPEND="${RDEPEND}
>=sys-devel/flex-2.5.33
sys-devel/gettext
virtual/yacc
dev-util/gperf
dev-util/pkgconfig
dev-util/gtk-doc-am
test? ( x11-themes/hicolor-icon-theme )
"
S="${WORKDIR}/${MY_P}"
src_prepare() {
DOCS="ChangeLog NEWS" # other ChangeLog files handled by src_install
# Fix arches that use 64-bit double type
# https://bugs.webkit.org/show_bug.cgi?id=69940
epatch "${FILESDIR}/${PN}-1.6.1-double-conversion.patch"
# FIXME: Fix unaligned accesses on ARM, IA64 and SPARC
# https://bugs.webkit.org/show_bug.cgi?id=19775
# TODO: FAILS TO APPLY!
#use sparc && epatch "${FILESDIR}"/${PN}-1.2.3-fix-pool-sparc.patch
# intermediate MacPorts hack while upstream bug is not fixed properly
# https://bugs.webkit.org/show_bug.cgi?id=28727
use aqua && epatch "${FILESDIR}"/${PN}-1.6.1-darwin-quartz.patch
# Skip tests phase: here we will place tests we need to skip, any
# skipped test needs to have an upstream report and needs to be
# rechecked on every major bump.
#
# adjustments test is flacky, https://bugs.webkit.org/show_bug.cgi?id=68647
sed -i -e '/\/webkit\/webview\/adjustments/d' Source/WebKit/gtk/tests/testwebview.c || die
# the same for icon-uri one, https://bugs.webkit.org/show_bug.cgi?id=69228
sed -i -e '/\/webkit\/webview\/icon-uri/d' Source/WebKit/gtk/tests/testwebview.c || die
# Drop DEPRECATED flags
sed -i -e 's:-D[A-Z_]*DISABLE_DEPRECATED:$(NULL):g' GNUmakefile.am || die
# Don't force -O2
sed -i 's/-O2//g' "${S}"/configure.ac || die
# Required for webgl; https://bugs.webkit.org/show_bug.cgi?id=69085
mkdir -p DerivedSources/ANGLE
# We need to reset some variables to prevent permissions problems and failures
# like https://bugs.webkit.org/show_bug.cgi?id=35471 and bug #323669
gnome2_environment_reset
# Respect CC, otherwise fails on prefix #395875
tc-export CC
# Prevent maintainer mode from being triggered during make
AT_M4DIR=Source/autotools eautoreconf
}
src_configure() {
# It doesn't compile on alpha without this in LDFLAGS
use alpha && append-ldflags "-Wl,--no-relax"
# Sigbuses on SPARC with mcpu and co.
use sparc && filter-flags "-mcpu=*" "-mvis" "-mtune=*"
# https://bugs.webkit.org/show_bug.cgi?id=42070 , #301634
use ppc64 && append-flags "-mminimal-toc"
local myconf
# XXX: Check Web Audio support
# WebKit2 can only be built with gtk3
# API documentation (gtk-doc) is built in webkit-gtk:3, always disable here
myconf="
$(use_enable coverage)
$(use_enable debug)
$(use_enable debug debug-features)
$(use_enable spell spellcheck)
$(use_enable introspection)
$(use_enable gstreamer video)
$(use_enable jit)
$(use_enable webgl)
--enable-web-sockets
--with-gtk=2.0
--disable-gtk-doc
--disable-webkit2
$(use aqua && echo "--with-font-backend=pango --with-target=quartz")"
econf ${myconf}
}
src_test() {
unset DISPLAY
# Tests need virtualx, bug #294691, bug #310695
# Parallel tests sometimes fail
Xemake -j1 check
}
src_install() {
default
newdoc Source/WebKit/gtk/ChangeLog ChangeLog.gtk
newdoc Source/WebKit/gtk/po/ChangeLog ChangeLog.gtk-po
newdoc Source/JavaScriptCore/ChangeLog ChangeLog.JavaScriptCore
newdoc Source/WebCore/ChangeLog ChangeLog.WebCore
# Remove .la files
find "${D}" -name '*.la' -exec rm -f '{}' +
}
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2012-02-04 10:04 UTC | newest]
Thread overview: (only message) (download: mbox.gz follow: Atom feed
-- links below jump to the message on this page --
2012-02-04 10:04 [gentoo-commits] gentoo-x86 commit in net-libs/webkit-gtk: webkit-gtk-1.6.3-r300.ebuild webkit-gtk-1.6.3-r200.ebuild ChangeLog webkit-gtk-1.6.1-r300.ebuild webkit-gtk-1.6.1-r200.ebuild Pacho Ramos (pacho)
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox