[gentoo-commits] gentoo-x86 commit in sys-apps/pcsc-lite: pcsc-lite-1.8.2.ebuild ChangeLog pcsc-lite-1.7.4-r2.ebuild pcsc-lite-1.8.1.ebuild

[gentoo-commits] gentoo-x86 commit in sys-apps/pcsc-lite: pcsc-lite-1.8.2.ebuild ChangeLog pcsc-lite-1.7.4-r2.ebuild pcsc-lite-1.8.1.ebuild

[Diego Petteno (flameeyes)]

flameeyes    12/01/18 19:16:34

  Modified:             ChangeLog
  Added:                pcsc-lite-1.8.2.ebuild
  Removed:              pcsc-lite-1.7.4-r2.ebuild pcsc-lite-1.8.1.ebuild
  Log:
  Version bump; remove old.
  
  (Portage version: 2.2.0_alpha84/cvs/Linux x86_64)

Revision  Changes    Path
1.126                sys-apps/pcsc-lite/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?rev=1.126&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?rev=1.126&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/ChangeLog?r1=1.125&r2=1.126

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v
retrieving revision 1.125
retrieving revision 1.126
diff -u -r1.125 -r1.126
--- ChangeLog	25 Nov 2011 14:32:46 -0000	1.125
+++ ChangeLog	18 Jan 2012 19:16:34 -0000	1.126
@@ -1,6 +1,12 @@
 # ChangeLog for sys-apps/pcsc-lite
-# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v 1.125 2011/11/25 14:32:46 flameeyes Exp $
+# Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/ChangeLog,v 1.126 2012/01/18 19:16:34 flameeyes Exp $
+
+*pcsc-lite-1.8.2 (18 Jan 2012)
+
+  18 Jan 2012; Diego E. Pettenò <flameeyes@gentoo.org> +pcsc-lite-1.8.2.ebuild,
+  -pcsc-lite-1.7.4-r2.ebuild, -pcsc-lite-1.8.1.ebuild:
+  Version bump; remove old.
 
 *pcsc-lite-1.8.1 (25 Nov 2011)
 



1.1                  sys-apps/pcsc-lite/pcsc-lite-1.8.2.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.8.2.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.8.2.ebuild?rev=1.1&content-type=text/plain

Index: pcsc-lite-1.8.2.ebuild
===================================================================
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-apps/pcsc-lite/pcsc-lite-1.8.2.ebuild,v 1.1 2012/01/18 19:16:34 flameeyes Exp $

EAPI="4"

inherit multilib eutils

DESCRIPTION="PC/SC Architecture smartcard middleware library"
HOMEPAGE="http://pcsclite.alioth.debian.org/"

STUPID_NUM="3695"
MY_P="${PN}-${PV/_/-}"
SRC_URI="http://alioth.debian.org/download.php/${STUPID_NUM}/${MY_P}.tar.bz2"
S="${WORKDIR}/${MY_P}"

LICENSE="as-is"
SLOT="0"
KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~m68k ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"

# This is called libusb so that it doesn't fool people in thinking that
# it is _required_ for USB support. Otherwise they'll disable udev and
# that's going to be worse.
IUSE="libusb +udev"

REQUIRED_USE="^^ ( udev libusb )"

CDEPEND="libusb? ( virtual/libusb:1 )
	udev? ( sys-fs/udev )"
DEPEND="${CDEPEND}
	dev-util/pkgconfig"
RDEPEND="${CDEPEND}
	!<app-crypt/ccid-1.4.1-r1"

pkg_setup() {
	enewgroup openct # make sure it exists
	enewgroup pcscd
	enewuser pcscd -1 -1 /var/run/pcscd pcscd,openct
}

src_configure() {
	econf \
		--disable-maintainer-mode \
		--disable-dependency-tracking \
		--docdir="${EPREFIX}/usr/share/doc/${PF}" \
		--enable-usbdropdir="${EPREFIX}/usr/$(get_libdir)/readers/usb" \
		--without-systemdsystemunitdir \
		$(use_enable udev libudev) \
		$(use_enable libusb) \
		${myconf}
}

DOCS=( AUTHORS DRIVERS HELP README SECURITY ChangeLog )

src_install() {
	default
	find "${D}" -name '*.la' -delete

	newinitd "${FILESDIR}/pcscd-init.5" pcscd

	if use udev; then
		insinto /lib/udev/rules.d
		doins "${FILESDIR}"/99-pcscd-hotplug.rules
	fi
}

pkg_postinst() {
	elog "Starting from version 1.6.5, pcsc-lite will start as user nobody in"
	elog "the pcscd group, to avoid running as root."
	elog ""
	elog "This also means you need the newest drivers available so that the"
	elog "devices get the proper owner."
	elog ""
	elog "Furthermore, a conf.d file is no longer installed by default, as"
	elog "the default configuration does not require one. If you need to"
	elog "pass further options to pcscd, create a file and set the"
	elog "EXTRA_OPTS variable."
	elog ""
	if use udev; then
		elog "Hotplug support is provided by udev rules; you only need to tell"
		elog "the init system to hotplug it, by setting this variable in"
		elog "/etc/rc.conf:"
		elog ""
		elog "    rc_hotplug=\"pcscd\""
	fi
}