[gentoo-commits] gentoo-x86 commit in dev-python/sip: sip-4.13.1.ebuild ChangeLog

[gentoo-commits] gentoo-x86 commit in dev-python/sip: sip-4.13.1.ebuild ChangeLog

[Markos Chandras (hwoarang)]

hwoarang    11/12/24 08:35:16

  Modified:             ChangeLog
  Added:                sip-4.13.1.ebuild
  Log:
  version bump
  
  (Portage version: 2.2.0_alpha71/cvs/Linux x86_64)

Revision  Changes    Path
1.205                dev-python/sip/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/ChangeLog?rev=1.205&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/ChangeLog?rev=1.205&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/ChangeLog?r1=1.204&r2=1.205

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/dev-python/sip/ChangeLog,v
retrieving revision 1.204
retrieving revision 1.205
diff -u -r1.204 -r1.205
--- ChangeLog	14 Dec 2011 22:33:24 -0000	1.204
+++ ChangeLog	24 Dec 2011 08:35:16 -0000	1.205
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/sip
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/sip/ChangeLog,v 1.204 2011/12/14 22:33:24 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/sip/ChangeLog,v 1.205 2011/12/24 08:35:16 hwoarang Exp $
+
+*sip-4.13.1 (24 Dec 2011)
+
+  24 Dec 2011; Markos Chandras <hwoarang@gentoo.org> +sip-4.13.1.ebuild:
+  version bump
 
   14 Dec 2011; Mike Gilbert <floppym@gentoo.org> sip-4.13.ebuild:
   Remove -O2 from build specs. Resolves bug 360771.



1.1                  dev-python/sip/sip-4.13.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/sip-4.13.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/dev-python/sip/sip-4.13.1.ebuild?rev=1.1&content-type=text/plain

Index: sip-4.13.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/sip/sip-4.13.1.ebuild,v 1.1 2011/12/24 08:35:16 hwoarang Exp $

EAPI="3"
PYTHON_DEPEND="*"
PYTHON_EXPORT_PHASE_FUNCTIONS="1"
SUPPORT_PYTHON_ABIS="1"
RESTRICT_PYTHON_ABIS="*-jython"

inherit eutils python toolchain-funcs

MY_P="${P/_pre/-snapshot-}"

DESCRIPTION="Python extension module generator for C and C++ libraries"
HOMEPAGE="http://www.riverbankcomputing.co.uk/software/sip/intro http://pypi.python.org/pypi/SIP"
SRC_URI="http://www.riverbankcomputing.com/static/Downloads/${PN}${PV%%.*}/${MY_P}.tar.gz"

LICENSE="|| ( GPL-2 GPL-3 sip )"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
IUSE="debug doc"

S="${WORKDIR}/${MY_P}"

DEPEND=""
RDEPEND=""

src_prepare() {
	epatch "${FILESDIR}/${PN}-4.9.3-darwin.patch"
	sed -i 's/-O2//g' specs/* || die
	python_copy_sources
}

src_configure() {
	configuration() {
		local myconf=("$(PYTHON)"
			configure.py
			--bindir="${EPREFIX}/usr/bin"
			--incdir="${EPREFIX}$(python_get_includedir)"
			--destdir="${EPREFIX}$(python_get_sitedir)"
			--sipdir="${EPREFIX}/usr/share/sip"
			$(use debug && echo --debug)
			CC="$(tc-getCC)"
			CXX="$(tc-getCXX)"
			LINK="$(tc-getCXX)"
			LINK_SHLIB="$(tc-getCXX)"
			CFLAGS="${CFLAGS}"
			CXXFLAGS="${CXXFLAGS}"
			LFLAGS="${LDFLAGS}"
			STRIP=":")
		echo "${myconf[@]}"
		"${myconf[@]}"
	}
	python_execute_function -s configuration
}

src_install() {
	python_src_install

	dodoc NEWS || die "dodoc failed"

	if use doc; then
		dohtml -r doc/html/* || die "dohtml failed"
	fi
}

pkg_postinst() {
	python_mod_optimize sipconfig.py sipdistutils.py

	ewarn "When updating dev-python/sip, you usually need to rebuild packages, which depend on dev-python/sip,"
	ewarn "such as dev-python/PyQt4 and dev-python/qscintilla-python. If you have app-portage/gentoolkit"
	ewarn "installed, you can find these packages with \`equery d dev-python/sip dev-python/PyQt4\`."
}

pkg_postrm() {
	python_mod_cleanup sipconfig.py sipdistutils.py
}