[gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: freeipmi-1.0.10.ebuild ChangeLog freeipmi-0.8.9.ebuild

[gentoo-commits] gentoo-x86 commit in sys-libs/freeipmi: freeipmi-1.0.10.ebuild ChangeLog freeipmi-0.8.9.ebuild

[Diego Petteno (flameeyes)]

flameeyes    11/12/14 03:58:02

  Modified:             ChangeLog
  Added:                freeipmi-1.0.10.ebuild
  Removed:              freeipmi-0.8.9.ebuild
  Log:
  Version bump and remove old.
  
  (Portage version: 2.2.0_alpha80/cvs/Linux x86_64)

Revision  Changes    Path
1.45                 sys-libs/freeipmi/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.45&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?rev=1.45&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/ChangeLog?r1=1.44&r2=1.45

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v
retrieving revision 1.44
retrieving revision 1.45
diff -u -r1.44 -r1.45
--- ChangeLog	9 Dec 2011 21:26:09 -0000	1.44
+++ ChangeLog	14 Dec 2011 03:58:02 -0000	1.45
@@ -1,6 +1,12 @@
 # ChangeLog for sys-libs/freeipmi
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.44 2011/12/09 21:26:09 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/ChangeLog,v 1.45 2011/12/14 03:58:02 flameeyes Exp $
+
+*freeipmi-1.0.10 (14 Dec 2011)
+
+  14 Dec 2011; Diego E. Pettenò <flameeyes@gentoo.org> +freeipmi-1.0.10.ebuild,
+  -files/bmc-watchdog.initd, -files/ipmidetectd.initd, -freeipmi-0.8.9.ebuild:
+  Version bump and remove old.
 
   09 Dec 2011; Markos Chandras <hwoarang@gentoo.org> freeipmi-1.0.8.ebuild:
   Stable on amd64 wrt bug #364485



1.1                  sys-libs/freeipmi/freeipmi-1.0.10.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.0.10.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/sys-libs/freeipmi/freeipmi-1.0.10.ebuild?rev=1.1&content-type=text/plain

Index: freeipmi-1.0.10.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/sys-libs/freeipmi/freeipmi-1.0.10.ebuild,v 1.1 2011/12/14 03:58:02 flameeyes Exp $

EAPI=4

inherit autotools eutils

DESCRIPTION="Provides Remote-Console and System Management Software as per IPMI v1.5/2.0"
HOMEPAGE="http://www.gnu.org/software/freeipmi/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz
	http://ftp.gluster.com/pub/${PN}/${PV}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

RDEPEND="dev-libs/libgcrypt"
DEPEND="${RDEPEND}
		virtual/os-headers"
RDEPEND="${RDEPEND}
	sys-apps/openrc"

src_prepare() {
	epatch "${FILESDIR}"/${PN}-1.0.5-strictaliasing.patch

	AT_M4DIR="config" eautoreconf
}

src_configure() {
	econf \
		$(use_enable debug) \
		--disable-dependency-tracking \
		--enable-fast-install \
		--disable-static \
		--disable-init-scripts \
		--enable-logrotate-config \
		--localstatedir=/var
}

# There are no tests
src_test() { :; }

src_install() {
	emake DESTDIR="${D}" docdir="/usr/share/doc/${PF}" install || die "emake install failed"
	find "${D}" -name '*.la' -delete

	# freeipmi by defaults install _all_ commands to /usr/sbin, but
	# quite a few can be run remotely as standard user, so move them
	# in /usr/bin afterwards.
	dodir /usr/bin
	for file in ipmi{detect,ping,power,console}; do
		mv "${D}"/usr/{s,}bin/${file} || die

		# The default install symlinks these commands to add a dash
		# after the ipmi prefix; we repeat those after move for
		# consistency.
		rm "${D}"/usr/sbin/${file/ipmi/ipmi-}
		dosym ${file} /usr/bin/${file/ipmi/ipmi-}
	done

	dodoc AUTHORS ChangeLog* DISCLAIMER* NEWS README* TODO doc/*.txt

	keepdir \
		/var/cache/ipmimonitoringsdrcache \
		/var/lib/freeipmi \
		/var/log/{freeipmi,ipmiconsole}

	newinitd "${FILESDIR}"/ipmidetectd.initd.3 ipmidetectd

	newinitd "${FILESDIR}"/bmc-watchdog.initd.3 bmc-watchdog
	newconfd "${FILESDIR}"/bmc-watchdog.confd bmc-watchdog
}