[gentoo-commits] gentoo-x86 commit in games-util/pyfa: ChangeLog pyfa-1.1.ebuild

[gentoo-commits] gentoo-x86 commit in games-util/pyfa: ChangeLog pyfa-1.1.ebuild

[Alexandre Rostovtsev (tetromino)]

tetromino    11/11/30 18:33:25

  Modified:             ChangeLog
  Added:                pyfa-1.1.ebuild
  Log:
  Bump. Adds support for Crucible expansion, fleet boosting, wormhole effects.
  
  (Portage version: 2.2.0_alpha79/cvs/Linux x86_64)

Revision  Changes    Path
1.2                  games-util/pyfa/ChangeLog

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?rev=1.2&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?rev=1.2&content-type=text/plain
diff : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/ChangeLog?r1=1.1&r2=1.2

Index: ChangeLog
===================================================================
RCS file: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v
retrieving revision 1.1
retrieving revision 1.2
diff -u -r1.1 -r1.2
--- ChangeLog	2 Nov 2011 23:59:34 -0000	1.1
+++ ChangeLog	30 Nov 2011 18:33:25 -0000	1.2
@@ -1,6 +1,12 @@
 # ChangeLog for games-util/pyfa
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v 1.1 2011/11/02 23:59:34 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/ChangeLog,v 1.2 2011/11/30 18:33:25 tetromino Exp $
+
+*pyfa-1.1 (30 Nov 2011)
+
+  30 Nov 2011; Alexandre Rostovtsev <tetromino@gentoo.org> +pyfa-1.1.ebuild,
+  +files/pyfa-1.1-staticPath.patch:
+  Bump. Adds support for Crucible expansion, fleet boosting, wormhole effects.
 
 *pyfa-1.0.6 (02 Nov 2011)
 



1.1                  games-util/pyfa/pyfa-1.1.ebuild

file : http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-1.1.ebuild?rev=1.1&view=markup
plain: http://sources.gentoo.org/viewvc.cgi/gentoo-x86/games-util/pyfa/pyfa-1.1.ebuild?rev=1.1&content-type=text/plain

Index: pyfa-1.1.ebuild
===================================================================
# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/games-util/pyfa/pyfa-1.1.ebuild,v 1.1 2011/11/30 18:33:25 tetromino Exp $

EAPI="4"
PYTHON_DEPEND="2:2.6"
PYTHON_USE_WITH="sqlite threads"

inherit eutils python

if [[ ${PV/_rc*/} == ${PV} ]] ; then
	MY_PV=${PV}-crucible-src
	FOLDER=stable/${PV}
else
	MY_PV=${PV/_rc/-stable-RC}-src
	FOLDER=stable/${PV/*_rc/RC}
fi

DESCRIPTION="Python Fitting Assistant - a ship fitting application for EVE Online"
HOMEPAGE="http://www.evefit.org/Pyfa"
SRC_URI="http://dl.evefit.org/${FOLDER}/${PN}-${MY_PV}.tar.bz2"

LICENSE="GPL-3 LGPL-2.1 CCPL-Attribution-2.5 free-noncomm"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="+graph"

RDEPEND="dev-python/sqlalchemy
	>=dev-python/wxpython-2.8
	graph? ( dev-python/matplotlib[wxwidgets] dev-python/numpy )"
DEPEND=""

S=${WORKDIR}/${PN}

pkg_setup() {
	python_set_active_version 2
	python_pkg_setup
}

src_prepare() {
	# make staticPath settable from configforced again
	epatch "${FILESDIR}/${PN}-1.1-staticPath.patch"

	python_convert_shebangs -r -x 2 .
	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
		-e "s:%%EPREFIX%%:${EPREFIX}:" \
		"${FILESDIR}/configforced.py" > configforced.py
}

src_install() {
	local packagedir=$(python_get_sitedir)/${PN}
	insinto "${packagedir}"
	doins -r eos gui icons service config*.py info.py gpl.txt
	exeinto "${packagedir}"
	doexe ${PN}.py
	dosym "${packagedir}/${PN}.py" /usr/bin/${PN}
	insinto /usr/share/${PN}
	doins -r staticdata
	dodoc readme.txt
	doicon icons/${PN}.png
	domenu "${FILESDIR}/${PN}.desktop"
}

pkg_postinst() {
	python_mod_optimize ${PN}
}

pkg_postrm() {
	python_mod_cleanup ${PN}
}